games-board/gnubg: Remove old

Package-Manager: Portage-2.3.85, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 0 insertions, 109 deletions

diff --git a/games-board/gnubg/Manifest b/games-board/gnubg/Manifest
index e892648669cb..20598b9b688e 100644
--- a/games-board/gnubg/Manifest
+++ b/games-board/gnubg/Manifest
@@ -1,2 +1 @@
-DIST gnubg-release-1.05.000-sources.tar.gz 15030177 BLAKE2B a53c7d1d242083631a18f8c3eaa4d006fbbda8b6aef8240c1cc27a98b284cebd31ad2787ddd6e360a96bb365851c611971d47f686b2d8a42dfa35ff6a240eb02 SHA512 1d8080c362cb32a3828b6913823d0eb42b0befac7a9fbd6d5ee3346e7515f6150876ac3b8bd59d5fd0c0de2a03187441165bb82eff0ffa1fb84e385dcea58590
 DIST gnubg-release-1.06.002-sources.tar.gz 13163681 BLAKE2B 1b631af8b268c722624012f86318844376bb21158f231d807cbfbb101ecef03ed90f7f253121844dd4221dc8026af5619fe9f62aff64e20d6c2b84450f9705d0 SHA512 77594209032a0d81deb802da249d7f40812127dd1e080413eda75015f324fec9592b1b51772403f501b21e39d3dd371931d82b43c24f614a7d16c5234d271948
diff --git a/games-board/gnubg/gnubg-1.05.000-r1.ebuild b/games-board/gnubg/gnubg-1.05.000-r1.ebuild
deleted file mode 100644
index 4e45b81db530..000000000000
--- a/games-board/gnubg/gnubg-1.05.000-r1.ebuild
+++ /dev/null
@@ -1,108 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python2_7 )
-inherit eutils python-single-r1 gnome2-utils
-
-DESCRIPTION="GNU BackGammon"
-HOMEPAGE="http://www.gnubg.org/"
-SRC_URI="http://gnubg.org/media/sources/${PN}-release-${PV}-sources.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
-IUSE="cpu_flags_x86_avx gtk opengl python sqlite cpu_flags_x86_sse cpu_flags_x86_sse2 threads"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="
-	dev-db/sqlite:3
-	dev-libs/glib:2
-	dev-libs/gmp:0
-	dev-libs/libxml2
-	media-fonts/dejavu
-	media-libs/freetype:2
-	media-libs/libcanberra
-	media-libs/libpng:0
-	sys-libs/readline:0
-	x11-libs/cairo
-	x11-libs/pango
-	gtk? ( x11-libs/gtk+:2 )
-	opengl? (
-		x11-libs/gtk+:2
-		x11-libs/gtkglext
-		virtual/glu
-	)
-	python? ( ${PYTHON_DEPS} )
-	virtual/libintl"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# use ${T} instead of /tmp for constructing credits (bug #298275)
-	sed -i -e 's:/tmp:${T}:' credits.sh || die
-	sed -i -e 's/fonts //' Makefile.in || die # handle font install ourself to fix bug #335774
-	sed -i \
-		-e '/^localedir / s#=.*$#= @localedir@#' \
-		-e '/^gnulocaledir / s#=.*$#= @localedir@#' \
-		po/Makefile.in.in || die
-	sed -i \
-		-e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
-		-e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
-		pixmaps/Makefile.in || die
-	sed -i \
-		-e '1i#include <config.h>' \
-		copying.c || die #551896
-}
-
-src_configure() {
-	local simd=no
-	local gtk_arg=--without-gtk
-
-	if use gtk || use opengl ; then
-		gtk_arg=--with-gtk
-	fi
-	use cpu_flags_x86_sse  && simd=sse
-	use cpu_flags_x86_sse2 && simd=sse2
-	use cpu_flags_x86_avx  && simd=avx
-	econf \
-		--localedir=/usr/share/locale \
-		--docdir=/usr/share/doc/${PF}/html \
-		--disable-cputest \
-		--enable-simd=${simd} \
-		${gtk_arg} \
-		$(use_enable threads) \
-		$(use_with python) \
-		$(use_with sqlite sqlite) \
-		$(use_with opengl board3d)
-}
-
-src_install() {
-	default
-	insinto /usr/share/${PN}
-	doins ${PN}.weights *bd
-	dodir /usr/share/${PN}/fonts
-	dosym /usr/share/fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/fonts/Vera.ttf
-	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf /usr/share/${PN}/fonts/VeraBd.ttf
-	dosym /usr/share/fonts/dejavu/DejaVuSerif-Bold.ttf /usr/share/${PN}/fonts/VeraSeBd.ttf
-	make_desktop_entry "gnubg -w" "GNU Backgammon"
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}