gnome-base/gsettings-desktop-schemas: Version bump to 44.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-44.0.ebuild b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-44.0.ebuild
new file mode 100644
index 000000000000..44b5f0366aff
--- /dev/null
+++ b/gnome-base/gsettings-desktop-schemas/gsettings-desktop-schemas-44.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Collection of GSettings schemas for GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gsettings-desktop-schemas"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~x86-solaris"
+
+BDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Revert change to 'Source Code Pro 10' and 'Cantarell 11' fonts back to generic sans and monospace aliases
+	"${FILESDIR}"/3.32.0-default-fonts.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}