media-libs/libopenshot: bump to 0.1.7, add Python 3.6, #618408

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libopenshot/Manifest b/media-libs/libopenshot/Manifest
index d41156c23dd9..b5be669e0ef2 100644
--- a/media-libs/libopenshot/Manifest
+++ b/media-libs/libopenshot/Manifest
@@ -1,2 +1,3 @@
 DIST libopenshot-0.1.2.tar.gz 11012039 SHA256 f5b37250aaa4f7ca29727966b818d73d6a100d92dbb7bc5270ee332f820a3657 SHA512 a713b24c5925ea99f5b749e178a635dd30d1ed666d8a1195beaabd44fd4d8b4e5282ee0fda2fef58dc5db3e1a481f535902496128142c445082130a08841540e WHIRLPOOL 7902060db5e5d4ff4136057f33f0c6149827cfa9000bae70f7271ddabe608b5672caaa3dececb68517f4419b36ecd89fb718caa9823e214203fcfc1c648d5536
 DIST libopenshot-0.1.3.tar.gz 11019740 SHA256 4a35318af4fbeeb0c658963275e8ec1edb985497ab9674d76eb02a1d72cbb64d SHA512 d59817505812868db408a88dc1d30b5b1833910f45dd0df03937110b7d4cbd85a270773008e75a1501f4b3b89a09ea798ed9b580755adf3ae79ac24d403f6982 WHIRLPOOL 31e7b7fe98e2709d1d88c6e2c39ceaa0b81c4f9a624ea9853ffd9b86771148e1bec808ec67192cede3578bc30860f8f5a878f67745d2d2ac9838ea93f01b628c
+DIST libopenshot-0.1.7.tar.gz 11022594 SHA256 71cf5c18c76c36bec40c775cb98ab1ed672aa48d2de63a26c33c5cc5d6f0875a SHA512 4c8871ff30c03a14766e35a64052695768311afd81ecc55598720ad146f53c122ef3b1293467670f7dd48da77bf6cb4f4f14a18c298a649b8827f901ed653709 WHIRLPOOL 1730155af6b22ead4655e69c47df395566eb97dc66e5ec683ac2025130eded9060b515fd637b58de0254c4673adfbea1620a3253064f150fcb9bf9dfd492eb88
diff --git a/media-libs/libopenshot/libopenshot-0.1.7.ebuild b/media-libs/libopenshot/libopenshot-0.1.7.ebuild
new file mode 100644
index 000000000000..4f9643afa9b0
--- /dev/null
+++ b/media-libs/libopenshot/libopenshot-0.1.7.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit cmake-utils python-single-r1 toolchain-funcs versionator
+
+DESCRIPTION="Video editing library used by OpenShot"
+HOMEPAGE="http://www.openshotvideo.com/"
+SRC_URI="https://github.com/OpenShot/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+imagemagick libav +python test"
+# https://github.com/OpenShot/libopenshot/issues/43
+RESTRICT="test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	net-libs/cppzmq
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	media-libs/libopenshot-audio
+	imagemagick? ( <media-gfx/imagemagick-7:0=[cxx] )
+	libav? ( media-video/libav:=[encode,x264,xvid,vpx,mp3,theora] )
+	!libav? ( media-video/ffmpeg:0=[encode,x264,xvid,vpx,mp3,theora] )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${RDEPEND}
+	python? ( dev-lang/swig )
+	test? ( dev-libs/unittest++ )
+"
+
+# https://github.com/OpenShot/libopenshot/pull/45
+PATCHES=( ${FILESDIR}/${PN}-0.1.3-fix-tests.patch )
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && ! tc-has-openmp; then
+		eerror "${P} requires a compiler with OpenMP support. Your current"
+		eerror "compiler does not support it. If you use gcc, you can"
+		eerror "re-emerge it with the 'openmp' use flag enabled."
+		die "The current compiler does not support OpenMP"
+	fi
+}
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# https://github.com/OpenShot/libopenshot/issues/17
+	use test || cmake_comment_add_subdirectory tests
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RUBY=OFF # TODO: add ruby support
+		-DENABLE_PYTHON=$(usex python)
+		-DCMAKE_DISABLE_FIND_PACKAGE_ImageMagick=$(usex !imagemagick)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+		-DPYTHON_LIBRARY="$(python_get_library_path)"
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cmake-utils_src_make test
+}
+
+src_install() {
+	cmake-utils_src_install
+	python_optimize
+}