x11-libs/libva: Bump to version 2.6.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/x11-libs/libva/Manifest b/x11-libs/libva/Manifest
index 7ba0f46a84e8..31955e7518db 100644
--- a/x11-libs/libva/Manifest
+++ b/x11-libs/libva/Manifest
@@ -1 +1,2 @@
 DIST libva-2.5.0.tar.bz2 459677 BLAKE2B d6e5bf94bcbda0a724634164bd8cf91efbdbe36120e62e7e7eefcd749afffec1950d8904318b472c81ae07490c559c68b0853725c654a08592457118cd5d6a83 SHA512 ffaeb9cf8ed1f93073c1cb3e58f5b3d3612e81622d02f8e428c089f625d4370b496b7681ac2fc2823c48670c9fd3da50893b1db51de768cf0f5d866e2ee78106
+DIST libva-2.6.0.tar.bz2 466431 BLAKE2B 67baed8db9306c0e967f869f18bef304cd300f5a52e50b3f01757254fb72e3793737dc399ae1af99cdd1f2c42efabcf71fc328122f8385776bf504ed0dcccb95 SHA512 0cc8d0599a1ed437fb1deb7b05e6d6da5eca70e4d04fd3d52c82d74702b339e61af3d0ef824b6ae9fdec1bf81cad65dd1a6b9e26f2af2b6d860dce26047000b1
diff --git a/x11-libs/libva/libva-2.6.0.ebuild b/x11-libs/libva/libva-2.6.0.ebuild
new file mode 100644
index 000000000000..c1266852c3f2
--- /dev/null
+++ b/x11-libs/libva/libva-2.6.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit autotools git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+	AUTOTOOLS_AUTORECONF="yes"
+else
+	SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm opengl utils vdpau wayland X"
+
+VIDEO_CARDS="nvidia intel i965 nouveau"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.11[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+PDEPEND="video_cards_nvidia? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_nouveau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r3[${MULTILIB_USEDEP}] )
+	vdpau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+	video_cards_intel? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	video_cards_i965? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+	utils? ( media-video/libva-utils )
+"
+
+REQUIRED_USE="|| ( drm wayland X )
+	opengl? ( X )"
+
+DOCS=( NEWS )
+
+MULTILIB_WRAPPED_HEADERS=(
+/usr/include/va/va_backend_glx.h
+/usr/include/va/va_x11.h
+/usr/include/va/va_dri2.h
+/usr/include/va/va_dricommon.h
+/usr/include/va/va_glx.h
+)
+
+src_prepare() {
+	default
+	[[ "${PV}" == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		$(use_enable opengl glx)
+		$(use_enable X x11)
+		$(use_enable wayland)
+		$(use_enable drm)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name "*.la" -delete || die
+}