1 files changed, 56 insertions, 0 deletions
diff --git a/app-admin/analog/analog-6.0-r4.ebuild b/app-admin/analog/analog-6.0-r4.ebuild
new file mode 100644
index 000000000000..344dd3829a6f
--- /dev/null
+++ b/app-admin/analog/analog-6.0-r4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A webserver log analyzer"
+HOMEPAGE="http://www.analog.cx/"
+SRC_URI="http://www.analog.cx/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ppc ppc64 sparc x86"
+IUSE=""
+
+DEPEND=">=dev-libs/libpcre-3.4
+	>=media-libs/gd-1.8.4-r2[jpeg,png]
+	sys-libs/zlib"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cd src/
+	epatch "${FILESDIR}/${PN}-5.1-gentoo.diff"
+	epatch "${FILESDIR}/${P}-bzip2.patch"
+	epatch "${FILESDIR}/${P}-undefined-macro.patch"
+
+	sed -i Makefile \
+		-e 's| -o | $(LDFLAGS)&|g' \
+		|| die "sed Makefile"
+}
+
+src_compile() {
+	tc-export CC
+	# emake in main dir just executes "cd src && make",
+	# i.e. MAKEOPTS are ignored
+	emake -C src
+}
+
+src_install() {
+	dobin analog
+	newman analog.man analog.1
+
+	dodoc README.txt Licence.txt analog.cfg
+	dohtml -a html,gif,css,ico docs/*
+	dohtml -r how-to
+	dodoc -r examples
+	docinto cgi ; dodoc anlgform.pl
+
+	insinto /usr/share/analog/images ; doins images/*
+	insinto /usr/share/analog/lang ; doins lang/*
+	dodir /var/log/analog
+	dosym /usr/share/analog/images /var/log/analog/images
+	insinto /etc/analog ; doins "${FILESDIR}/analog.cfg"
+}