1 files changed, 42 insertions, 0 deletions
diff --git a/net-analyzer/masscan/masscan-1.3.2.ebuild b/net-analyzer/masscan/masscan-1.3.2.ebuild
new file mode 100644
index 000000000000..6a290f96f458
--- /dev/null
+++ b/net-analyzer/masscan/masscan-1.3.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Mass IP port scanner"
+HOMEPAGE="https://github.com/robertdavidgraham/masscan"
+SRC_URI="https://github.com/robertdavidgraham/masscan/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="AGPL-3"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="net-libs/libpcap"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/$(CC)/s!$(CFLAGS)!$(LDFLAGS) $(CFLAGS)!g' \
+		-e '/^GITVER :=/s!= .(.*!=!g' \
+		-e '/^SYS/s|gcc|$(CC)|g' \
+		-e '/^CFLAGS =/{s,=,+=,;s,-g -ggdb,,;s,-O3,,;}' \
+		-e '/^CC =/d' \
+		Makefile || die
+
+	tc-export CC
+}
+
+src_install() {
+	dobin bin/masscan
+
+	insinto /etc/masscan
+	doins data/exclude.conf
+	doins "${FILESDIR}"/masscan.conf
+
+	dodoc doc/bot.html *.md
+
+	doman doc/masscan.8
+}