blob: 2b38cf7dd2992f65958886190a256e7c53075468 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DESCRIPTION="rpcsvc protocol definitions from glibc"
HOMEPAGE="https://github.com/thkukuk/rpcsvc-proto"
SRC_URI="https://github.com/thkukuk/rpcsvc-proto/releases/download/v${PV}/${P}.tar.xz"
LICENSE="LGPL-2.1+ BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc ~x86"
RDEPEND="
!<sys-libs/glibc-2.26
virtual/libintl
"
DEPEND="${RDEPEND}"
# sys-devel/gettext is only for libintl detection macros.
BDEPEND="sys-devel/gettext"
src_prepare() {
default
# Search for a valid 'cpp' command.
# The CPP envvar might contain '${CC} -E', which does not work for rpcgen.
# Bug 718138, 870031, 870061.
local x cpp=
for x in {${CHOST}-,}{,clang-}cpp; do
if type -P "${x}" >/dev/null; then
cpp=${x}
break
fi
done
[[ -n ${cpp} ]] || die "Unable to find cpp"
sed -i -e "s/CPP = \"cpp\";/CPP = \"${cpp}\";/" rpcgen/rpc_main.c || die
}
src_install() {
default
# provided by sys-fs/quota[rpc]
rm "${ED}"/usr/include/rpcsvc/rquota.{x,h} || die
}
|
GitWeb
