Version bump

Package-Manager: portage-2.2_rc60/cvs/Linux x86_64

3 files changed, 183 insertions, 2 deletions

diff --git a/media-video/totem/ChangeLog b/media-video/totem/ChangeLog
index a0b76c6f6e04..5d85dff90d80 100644
--- a/media-video/totem/ChangeLog
+++ b/media-video/totem/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/totem
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/totem/ChangeLog,v 1.267 2009/12/13 11:43:00 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/totem/ChangeLog,v 1.268 2009/12/23 10:21:59 mrpouet Exp $
+
+*totem-2.28.5 (23 Dec 2009)
+
+  23 Dec 2009; Romain Perier <mrpouet@gentoo.org> +totem-2.28.5.ebuild:
+  Version bump.
 
 *totem-2.26.5 (13 Dec 2009)
 
diff --git a/media-video/totem/Manifest b/media-video/totem/Manifest
index f680c79a4dfe..7deb7ec4ec04 100644
--- a/media-video/totem/Manifest
+++ b/media-video/totem/Manifest
@@ -11,6 +11,7 @@ DIST totem-2.26.5.tar.bz2 3198042 RMD160 174e91dad2f51c908e4b777e93003c6888fd282
 DIST totem-2.28.1.tar.bz2 3027102 RMD160 1270f7188d4307251a4178e0890cd0eb30175294 SHA1 abed5ad0de334853024bc32756b5852496e00e9b SHA256 18121f17c37faaa9cc245d46293a24f58f2bba9dc9b84af5e1ffe0ac6e697b04
 DIST totem-2.28.3.tar.bz2 3080412 RMD160 38d912f2aa65cc6951288740845eecb4c3e3934a SHA1 7c41bac6644ebf528fd0a36a6341e14cc483fe79 SHA256 f709041c44eafab1850033609ce3bfa41e3748a19591494d4113d814a802877e
 DIST totem-2.28.4.tar.bz2 3081676 RMD160 c427f08842f263bdb028da8eb9e118e219866bb0 SHA1 bd311e5d0926d1458141dffa6c8fb2fda89d984f SHA256 ac1f9091450e2dde2887dd7176183341fcea5adc4b6cee6887342837f2a6e17e
+DIST totem-2.28.5.tar.bz2 3083946 RMD160 20fa09187a82380d7b7d19c2fb5e8a5a4475307e SHA1 1653528d66a1f11da4bc8f66746828c4a31343d6 SHA256 c788bb314addbeeb2b27a2af0f7448752db22dcfaf8b0a4e704463ba9a9dc063
 EBUILD totem-2.20.3.ebuild 5032 RMD160 2b784ab3e1fe07fc5846e3f0e241c34a1de2a3d0 SHA1 df543761b7eb778820057231ed5adac85231fca3 SHA256 ff7ffe9233c8c168288118d3c55e520c0d6f955804a0a3c13ad292d580392320
 EBUILD totem-2.24.4-r1.ebuild 4146 RMD160 0bbec55a118f60f3a93ccbffbc488c500aa8de0c SHA1 a0142a4c7822b14dece5c7558acc37aafc995947 SHA256 aea75b6d792c5008f19e369e26532d5d04929c8917c1617ea0cf084584cbb255
 EBUILD totem-2.26.3-r1.ebuild 4607 RMD160 e00455982cd7176e812befbe5fbc11108afbd5a4 SHA1 342c47f3f2bf7f44fad724a39ed90efb6181400e SHA256 61290a93c0f13ecb6a1f055a6e646608ea3e9f121142ca92d66e5d58255cae75
@@ -19,5 +20,6 @@ EBUILD totem-2.26.5.ebuild 4565 RMD160 5399b8b30ac07e941a22d90efc973d8fbe91ef42
 EBUILD totem-2.28.1.ebuild 4685 RMD160 95a2c837929c021abbfea581f2a75253465e5a93 SHA1 fa6b42a88c00668c179fcae176b837ac1f329dd5 SHA256 302aa2b41723f7ba97196bd19502cadc2a6a0f20146d595f4ae1515a0f050f0d
 EBUILD totem-2.28.3.ebuild 4689 RMD160 2c85c646ffbc6c6bc126f0e34725b79167f33c10 SHA1 f246065143919b6574b8bd6c5f0985e06e242acd SHA256 f2a6451bf9893160b1c509565ac8d19b3d768bf3ddd637faa9f990e111619448
 EBUILD totem-2.28.4.ebuild 4689 RMD160 622f41a4eb946c4f22dbfc8f4474dd9471fd66ee SHA1 f9b4ae6b4e1a9640fe7ba244f8ee4a054047f42f SHA256 1d6249fea61dbc0b9364ab7a36e0e15965528f873622b6e4574644751f3cca62
-MISC ChangeLog 37878 RMD160 14a260ac6dd7891d920423d9aa300623d5ebfeda SHA1 00ae9d6e9fd5823a24779c8a053cc577efba4947 SHA256 014f737613150eee1b761602845ba00f632c747b40eb753fd9341999d432ea75
+EBUILD totem-2.28.5.ebuild 4689 RMD160 7f901a7dba891c92e7e176a0d80e97e804e3c2b6 SHA1 b3911abf37237d16d95e5d9971d7c50a57a50705 SHA256 01aca97df144f899fc3b9c2de82df51de261c62ed82f93c69b35b7b82faaccdd
+MISC ChangeLog 37995 RMD160 51cbd021cec7628b2719dab344ed96b4770d75d2 SHA1 51d3c72c1a5a8633a0aa3ae25071a30a124969f7 SHA256 ae63614d556d4830e24e88df7cd4e4f8404a12620fb20d3a0ebda1cdfe86d303
 MISC metadata.xml 1872 RMD160 0678604a8be6f8432186df7ce003b9e4be9e0fc4 SHA1 63b76103e6b7c2c5aec965a5610643f4a25df37e SHA256 31b4e571c11c47e62c7f7e66698ac12e79159d59bad01de42461cf308d31f833
diff --git a/media-video/totem/totem-2.28.5.ebuild b/media-video/totem/totem-2.28.5.ebuild
new file mode 100644
index 000000000000..582dc5a1e55b
--- /dev/null
+++ b/media-video/totem/totem-2.28.5.ebuild
@@ -0,0 +1,174 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/totem/totem-2.28.5.ebuild,v 1.1 2009/12/23 10:21:59 mrpouet Exp $
+
+EAPI="2"
+
+inherit autotools eutils gnome2 multilib python
+
+DESCRIPTION="Media player for GNOME"
+HOMEPAGE="http://gnome.org/projects/totem/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+
+IUSE="bluetooth debug doc galago iplayer lirc nautilus nsplugin python tracker +youtube" #zeroconf
+
+# TODO:
+# Cone (VLC) plugin needs someone with the right setup (remi ?)
+# check gmyth requirement ? -> waiting for updates in tree
+# coherence plugin not enabled until we have deps in tree
+RDEPEND=">=dev-libs/glib-2.15
+	>=x11-libs/gtk+-2.16.0
+	>=gnome-base/gconf-2.0
+	>=dev-libs/totem-pl-parser-2.27.0
+	>=x11-themes/gnome-icon-theme-2.16
+	x11-libs/cairo
+	app-text/iso-codes
+	>=dev-libs/libxml2-2.6
+	>=dev-libs/dbus-glib-0.71
+	>=media-libs/gstreamer-0.10.25
+	>=media-libs/gst-plugins-good-0.10
+	>=media-libs/gst-plugins-base-0.10.25
+	>=media-plugins/gst-plugins-gconf-0.10
+
+	>=media-plugins/gst-plugins-taglib-0.10
+	>=media-plugins/gst-plugins-gio-0.10
+	>=media-plugins/gst-plugins-pango-0.10
+	>=media-plugins/gst-plugins-x-0.10
+	>=media-plugins/gst-plugins-meta-0.10-r2
+
+	dev-libs/libunique
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXtst
+	>=x11-libs/libXrandr-1.1.1
+	>=x11-libs/libXxf86vm-1.0.1
+
+	bluetooth? ( || (
+		net-wireless/bluez
+		net-wireless/bluez-libs ) )
+	galago? ( >=dev-libs/libgalago-0.5.2 )
+	iplayer? (
+		dev-python/pygobject
+		dev-python/pygtk
+		dev-python/httplib2
+		dev-python/feedparser
+		dev-python/beautifulsoup )
+	lirc? ( app-misc/lirc )
+	nautilus? ( >=gnome-base/nautilus-2.10 )
+	python? (
+		dev-lang/python[threads]
+		>=dev-python/pygtk-2.12
+		dev-python/pyxdg
+		dev-python/gst-python
+		dev-python/dbus-python
+		dev-python/gconf-python )
+	tracker? (
+		>=app-misc/tracker-0.6
+		<app-misc/tracker-0.7 )
+	youtube? (
+		>=dev-libs/libgdata-0.4.0
+		media-plugins/gst-plugins-soup )"
+# FIXME: freezes totem
+#	zeroconf? ( >=net-libs/libepc-0.3 )
+DEPEND="${RDEPEND}
+	x11-proto/xproto
+	x11-proto/xextproto
+	x11-proto/xf86vidmodeproto
+	app-text/scrollkeeper
+	gnome-base/gnome-common
+	app-text/gnome-doc-utils
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.20
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1.11 )
+	app-text/docbook-xml-dtd:4.5"
+# docbook-xml-dtd is needed for user doc
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-schemas-install
+		--disable-static
+		--disable-vala
+		--with-dbus
+		--with-smclient
+		--enable-easy-codec-installation
+		$(use_enable nsplugin browser-plugins)"
+
+	# Plugin configuration
+	G2CONF="${G2CONF}
+		BROWSER_PLUGIN_DIR=/usr/$(get_libdir)/nsbrowser/plugins
+		PLUGINDIR=/usr/$(get_libdir)/totem/plugins"
+
+	local plugins="properties,thumbnail,screensaver,ontop,gromit,media-player-keys,skipto,brasero-disc-recorder,screenshot"
+	use bluetooth && plugins="${plugins},bemused"
+	use galago && plugins="${plugins},galago"
+	use iplayer && plugins="${plugins},iplayer"
+	use lirc && plugins="${plugins},lirc"
+	use python && plugins="${plugins},opensubtitles,jamendo,pythonconsole,dbus-service"
+	use tracker && plugins="${plugins},tracker"
+	use youtube && plugins="${plugins},youtube"
+	#use zeroconf && plugins="${plugins},publish"
+
+	G2CONF="${G2CONF} --with-plugins=${plugins}"
+
+	G2CONF="${G2CONF}
+		$(use_enable debug)
+		$(use_enable nautilus)
+		$(use_enable python)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix broken smclient option passing
+	epatch "${FILESDIR}/${PN}-2.26.1-smclient-target-detection.patch"
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	eautoreconf
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+}
+
+src_configure() {
+	# FIXME: why does it need write access here, probably need to set up a fake
+	# home in /var/tmp like other pkgs do
+
+	addpredict "$(unset HOME; echo ~)/.gconf"
+	addpredict "$(unset HOME; echo ~)/.gconfd"
+	addpredict "$(unset HOME; echo ~)/.gnome2"
+
+	gnome2_src_configure
+}
+
+src_install() {
+	gnome2_src_install
+	# Installed for plugins, but they're dlopen()-ed
+	# firefox, totem as well as nautilus
+	find "${D}" -name "*.la" -delete || die "remove of la files failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if use python; then
+		python_need_rebuild
+		python_mod_optimize /usr/$(get_libdir)/totem/plugins
+	fi
+
+	ewarn
+	ewarn "If totem doesn't play some video format, please check your"
+	ewarn "USE flags on media-plugins/gst-plugins-meta"
+	ewarn
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/totem/plugins
+}