Version bump #525872 by Arfrever Frehtes Taifersar Arahesis.

Package-Manager: portage-2.2.14_rc1/cvs/Linux x86_64
Manifest-Sign-Key: 0xD2E96200

3 files changed, 223 insertions, 15 deletions

diff --git a/dev-libs/DirectFB/ChangeLog b/dev-libs/DirectFB/ChangeLog
index 6901f28b4325..695664afc55b 100644
--- a/dev-libs/DirectFB/ChangeLog
+++ b/dev-libs/DirectFB/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/DirectFB
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/DirectFB/ChangeLog,v 1.138 2014/10/18 22:12:55 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/DirectFB/ChangeLog,v 1.139 2014/10/19 18:09:49 vapier Exp $
+
+*DirectFB-1.7.6 (19 Oct 2014)
+
+  19 Oct 2014; Mike Frysinger <vapier@gentoo.org> +DirectFB-1.7.6.ebuild:
+  Version bump #525872 by Arfrever Frehtes Taifersar Arahesis.
 
 *DirectFB-1.7.5 (18 Oct 2014)
 
diff --git a/dev-libs/DirectFB/DirectFB-1.7.6.ebuild b/dev-libs/DirectFB/DirectFB-1.7.6.ebuild
new file mode 100644
index 000000000000..3990ab0abd5d
--- /dev/null
+++ b/dev-libs/DirectFB/DirectFB-1.7.6.ebuild
@@ -0,0 +1,201 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/DirectFB/DirectFB-1.7.6.ebuild,v 1.1 2014/10/19 18:09:49 vapier Exp $
+
+EAPI=5
+inherit autotools eutils toolchain-funcs
+
+# Map Gentoo IUSE expand vars to DirectFB drivers
+# echo `sed -n '/Possible gfxdrivers are:/,/^$/{/Possible/d;s:\[ *::;s:\].*::;s:,::g;p}' configure.in`
+I_TO_D_intel="i810,i830"
+I_TO_D_mga="matrox"
+I_TO_D_r128="ati128"
+I_TO_D_s3="unichrome"
+I_TO_D_sis="sis315"
+I_TO_D_via="cle266"
+# cyber5k davinci ep9x omap pxa3xx sh772x savage pvr2d
+IUSE_VIDEO_CARDS=" intel mach64 mga neomagic nsc nvidia r128 radeon s3 sis tdfx via vmware"
+IUV=${IUSE_VIDEO_CARDS// / video_cards_}
+# echo `sed -n '/Possible inputdrivers are:/,/^$/{/\(Possible\|^input\)/d;s:\[ *::;s:\].*::;s:,::g;p}' configure.in`
+I_TO_D_elo2300="elo-input"
+I_TO_D_evdev="linuxinput"
+I_TO_D_mouse="ps2mouse,serialmouse"
+# dbox2remote dreamboxremote gunze h3600_ts penmount sonypijogdial ucb1x00 wm97xx zytronic
+IUSE_INPUT_DEVICES=" dynapro elo2300 evdev joystick keyboard lirc mouse mutouch tslib"
+IUD=${IUSE_INPUT_DEVICES// / input_devices_}
+
+DESCRIPTION="Thin library on top of the Linux framebuffer devices"
+HOMEPAGE="http://www.directfb.org/"
+SRC_URI="http://directfb.org/downloads/Core/${PN}-${PV:0:3}/${P}.tar.gz
+	http://directfb.org/downloads/Old/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 -mips ~ppc ~ppc64 ~sh -sparc ~x86"
+IUSE="alsa bmp cddb debug divine drmkms +dynload doc egl fbcon fusiondale fusionsound gif gles2 gstreamer imlib2 input_hub jpeg jpeg2k mad mmx mng mpeg2 mpeg3 multicore opengl oss png pnm sawman sdl sse static-libs svg swfdec tiff timidity tremor truetype v4l vdpau vorbis webp X xine zlib ${IUV} ${IUD}"
+REQUIRED_USE="gles2? ( opengl )"
+
+# ffmpeg useflag broken
+# ffmpeg? ( virtual/ffmpeg )
+#	$(use_enable ffmpeg) \
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	cddb? ( media-libs/libcddb )
+	drmkms? ( x11-libs/libdrm[libkms] )
+	gif? ( media-libs/giflib )
+	gstreamer? ( media-libs/gstreamer:1.0 media-libs/gst-plugins-base:1.0 )
+	imlib2? ( media-libs/imlib2 )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( media-libs/jasper[jpeg] )
+	mad? ( media-libs/libmad )
+	mng? ( media-libs/libmng )
+	mpeg3? ( media-libs/libmpeg3 )
+	opengl? ( media-libs/mesa[gbm,egl?,gles2?] x11-libs/libdrm )
+	png? ( media-libs/libpng:0 )
+	sdl? ( media-libs/libsdl )
+	svg? ( x11-libs/libsvg-cairo )
+	swfdec? ( media-libs/swfdec )
+	tiff? ( media-libs/tiff:0 )
+	timidity? (
+		media-libs/libtimidity
+		media-sound/timidity++
+	)
+	tremor? ( media-libs/tremor )
+	truetype? ( >=media-libs/freetype-2.0.1 )
+	vdpau? ( x11-proto/xproto x11-libs/libX11 x11-libs/libXext x11-libs/libvdpau )
+	vorbis? ( media-libs/libvorbis )
+	webp? ( media-libs/libwebp )
+	X? ( x11-libs/libXext x11-libs/libX11 )
+	xine? ( media-libs/xine-lib[vdpau?] )
+	zlib? ( sys-libs/zlib )	"
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xextproto x11-proto/xproto )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.7.5-flags.patch \
+		"${FILESDIR}"/${PN}-1.6.3-pkgconfig.patch \
+		"${FILESDIR}"/${PN}-1.7.1-build.patch \
+		"${FILESDIR}"/${PN}-1.6.3-setregion.patch \
+		"${FILESDIR}"/${PN}-1.6.3-atomic-fix-compiler-error-when-building-for-thumb2.patch
+	sed -i \
+		-e '/#define RASPBERRY_PI/d' \
+		systems/egl/egl_system.c || die #497124
+
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+driver_list() {
+	local pfx=$1
+	local dev devs map
+	shift
+	for dev in "$@" ; do
+		use ${pfx}_${dev} || continue
+		map="I_TO_D_${dev}"
+		devs=${devs:+${devs},}${!map:-${dev}}
+	done
+	echo ${devs:-none}
+}
+
+src_configure() {
+	local myaudio="wave"
+	use alsa && myaudio+=",alsa"
+	use oss && myaudio+=",oss"
+
+	local sdlconf="--disable-sdl"
+	if use sdl ; then
+		# since SDL can link against DirectFB and trigger a
+		# dependency loop, only link against SDL if it isn't
+		# broken #61592
+		echo 'int main(){}' > sdl-test.c
+		$(tc-getCC) sdl-test.c -lSDL 2>/dev/null \
+			&& sdlconf="--enable-sdl" \
+			|| ewarn "Disabling SDL since libSDL.so is broken"
+	fi
+
+	# fix --with-gfxdrivers= logic, because opengl, vdpau and gles2 are no video_cards
+	local gfxdrivers="$(driver_list video_cards ${IUSE_VIDEO_CARDS})"
+	use opengl && gfxdrivers="${gfxdrivers},gl"
+	use vdpau && gfxdrivers="${gfxdrivers},vdpau"
+	use gles2 && gfxdrivers="${gfxdrivers},gles2"
+	gfxdrivers="$(echo ${gfxdrivers} | sed 's/none,//')"
+
+	# fix --with-inputdrivers= logic, don't know where to put "input_hub"
+	local inputdrivers="$(driver_list input_devices ${IUSE_INPUT_DEVICES})"
+	use input_hub && inputdrivers="${inputdrivers},input_hub"
+	inputdrivers="$(echo ${inputdrivers} | sed 's/none,//')"
+
+	# The xine-vdpau flag requires a custom patch to xine-lib which we don't carry:
+	# http://git.directfb.org/?p=extras/DirectFB-extra.git;a=blob;f=interfaces/IDirectFBVideoProvider/xine-lib-1.2-vdpau-hooks.patch;hb=HEAD
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable X x11) \
+		$(use_enable divine) \
+		$(use_enable sawman) \
+		$(use_enable fusiondale) \
+		$(use_enable fusionsound) \
+		$(use_enable fbcon fbdev) \
+		$(use_enable mmx) \
+		$(use_enable sse) \
+		$(use_enable egl) \
+		$(use_enable egl idirectfbgl-egl) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable mng) \
+		$(use_enable gstreamer) \
+		$(use_enable gif) \
+		$(use_enable tiff) \
+		$(use_enable imlib2) \
+		$(use_enable pnm) \
+		$(use_enable svg) \
+		$(use_enable mpeg2) \
+		$(use_enable mpeg3 libmpeg3) \
+		--disable-flash \
+		$(use_enable xine) \
+		--disable-xine-vdpau \
+		--disable-ffmpeg \
+		$(use_enable bmp) \
+		$(use_enable jpeg2k jpeg2000) \
+		--disable-openquicktime \
+		--disable-avifile \
+		$(use_enable truetype freetype) \
+		$(use_enable webp) \
+		$(use_enable debug) \
+		$(use_enable zlib) \
+		--disable-video4linux \
+		$(use_enable v4l video4linux2) \
+		$(use_enable vdpau x11vdpau) \
+		$(use_enable multicore) \
+		$(use_enable dynload) \
+		$(use_enable opengl mesa) \
+		$(use_enable drmkms) \
+		--with-fs-drivers="${myaudio}" \
+		$(use_with timidity) \
+		--with-wave \
+		$(use_with vorbis) \
+		$(use_with tremor) \
+		$(use_with mad) \
+		$(use_with cddb cdda) \
+		--with-playlist \
+		${sdlconf} \
+		--with-gfxdrivers="${gfxdrivers}" \
+		--with-inputdrivers="${inputdrivers}" \
+		--disable-vnc
+}
+
+src_install() {
+	default
+	dodoc fb.modes
+	use doc && dohtml -r docs/html/*
+}
+
+pkg_postinst() {
+	ewarn "Each DirectFB update breaks DirectFB related applications."
+	ewarn "Please run \"revdep-rebuild\" which can be"
+	ewarn "found by emerging the package 'gentoolkit'."
+	ewarn
+	ewarn "If you have an ALPS touchpad, then you might get your mouse"
+	ewarn "unexpectedly set in absolute mode in all DirectFB applications."
+	ewarn "This can be fixed by removing linuxinput from INPUT_DEVICES."
+}
diff --git a/dev-libs/DirectFB/Manifest b/dev-libs/DirectFB/Manifest
index bcbf4fecb5c7..6a1d4a803b7b 100644
--- a/dev-libs/DirectFB/Manifest
+++ b/dev-libs/DirectFB/Manifest
@@ -17,26 +17,28 @@ DIST DirectFB-1.4.9.tar.gz 3095137 SHA256 988a40dbc81fe1ecaf69a3581ed49bf4f6bbb5
 DIST DirectFB-1.6.3.tar.gz 4296908 SHA256 7a96aced0f69b2ec0810e9923068e61c21e6b19dd593e09394c872414df75e70 SHA512 86fb98951a4dc579b0d60e96976e6d85bf99e35f2fbd0d5f7cdc3d7c9ea0242052ff8dbb46bfb093e70439158cda37000e67d2a05265d3a6d2e7ac7231c2ebb7 WHIRLPOOL ce9d1f3a1e7e9aaed3572244390c0dec87faa5e8af1a58153ad849774e08be0037f42983852de323cab745dc6b3d018640ec2d5987270b6a4b5ab7595bbd97aa
 DIST DirectFB-1.7.1.tar.gz 5875460 SHA256 dd7de38b3cd1408411b37ca28ec73e14b7672e5e28256b7bf91826240c81f519 SHA512 caf24c04b8155b9b9dbea321c627925f60809aa7edd1ab4f9fcf28a40e14accdb2a4226f5de7a26ab5928b7df7fd85c616a966d036800ba2a675724314065982 WHIRLPOOL 9d1448b48e8fec0dac633e5afd6eb92d48edfa3874998d88d50a7dec99c89a20d738cfbcf0aef8cff346cffc0901bf5e675c6df92bbf97a35880add34877b90d
 DIST DirectFB-1.7.5.tar.gz 5996591 SHA256 7b76d4a48aa71cce4d5e1878afc548cc48f21d55751d8d5aa4c4cdfcbb40ed03 SHA512 d447f2c3892d90902773ae58e0f0cc87b384070f6f5d63a2412138d7c4a53288b688092fa681e6489dcbf36b2bd48c3e3aab162da52680499841b07b5a6daa4f WHIRLPOOL 123e1ab63e556fa50c9a4b288a773f55d3ab46fe4ed5d32b2198f140fde9afaa98167112a3bfbb9e0496349463e37ea36a32200f278b7bdc1cfb1b9dfbabafb8
+DIST DirectFB-1.7.6.tar.gz 5975444 SHA256 44f32bacfb842ea234599532f8481fe41b5bd2310d2bd101508eb3a5df26c9e1 SHA512 18cf1aad6c277a6de147a9b0aff1cd7408ddd7c7159ef21dab9a548db7399c681603624e7820b186a29e03edaa7737350a61e2abaec572887e9cc56658bf85a2 WHIRLPOOL 2868906bbd2b4e681c6702f164f7ba4f01a0f538aea0c744c6e77ce32b274a967232ef0046ec21b74c9c53c4824182e632159cca5ea0c7c27292cb258257d6a8
 EBUILD DirectFB-1.4.9-r1.ebuild 4106 SHA256 0d929a96b66c51e6262104673ace0aeb913b3d014cb54df0ffdb5651be8abeaf SHA512 06bc862108effb7939e7428fcf725d39735ddbe5e1ceb902058dc055c52d9bf3ccb4cc4b9b307d3a8ce35e641746f3b429ac5604b4f674556b0f561dec9d6468 WHIRLPOOL 0a28e06359d23ef793ed91730d37ab25ee4f094c016f01308146dea9974ddab72c203bb6dfd5394ba35a5ae47b6490ceaee109fede823d69b361fa48481e8d9d
 EBUILD DirectFB-1.6.3-r1.ebuild 5127 SHA256 1b21f5bfa5875d23563e51f590e4f7df889206121f588882de39734ac623705b SHA512 7d7bade222f1d3c55a72a7ff74193bf01d2e79e6dfa34f8e20d9822490629e51432d4c1dc7d2107d86e7acca84174366b59219b9a54b5db2cb3f4d1885a49db5 WHIRLPOOL a8e4f0a883a9ccb4081e70ec42c0c36832f8551ca46d0aa4046a6aa7c4cf0672461c95f8851eb015f1cccd9392bad75dfe0c4e7033a970f5be047f61be9a0a6a
 EBUILD DirectFB-1.7.1.ebuild 6725 SHA256 138139c0c934bcc176304c8ccac1a8b4397c1e90dba1e211a13b2629dfc09a0c SHA512 3321f3a03d3a7d94b9005fbc2ad1611c1d7c88f20f65a6b1bd738a2d491839ca4f3533083da54e13760886c86bdd14989c455c3dd707e42f059c13f38aa2ca10 WHIRLPOOL 71f6baf575102ab5472e30bbd4b63cff063a133be14f27b5546f1e52506a0bc2e1156fa56ca6a84fa4f2f6d36ed2e2a4355c51b4e6038049e3b210453ef3ab0b
 EBUILD DirectFB-1.7.5.ebuild 6739 SHA256 dcb52090727a02128747d1c1d6a33eec155a8ad18fd8ec070af684e6dad76140 SHA512 740eceada4e53ac2cee986a0fe597bcf7d8dac329e6086bab9dce5d5eccc928779e53ef6b5148d7d2e32bbd04e4f74bb70a3dc0ad573c246f48cff839f125fc0 WHIRLPOOL 477a13c351e749c5260b0554afc5c8424717dc677f1b0e4a0dbe2adcc7e5b34cac765827c88a7eb896aa59fcdf06a11fd4041b3428c05157d2c730eb8f88dc9c
-MISC ChangeLog 19616 SHA256 c361afbc735fe92e7b38b5a4c07a8c94701971db8d5655a46cef93aa51e4d49b SHA512 9af24a063d80d465e266f666e5cc0a46941005a7014195526f780fe4ba895e679757b0b7d792a0e42b28d23d5ce1ca9edc134362c040bacb8628fa3245d255f4 WHIRLPOOL d5439416ae6ec475ee3ab7d6ebaccfb616b85a4a7b6c10fb5828ff9fb3285db81a925bb0cf7016aaffab89c606c62a1926fa1eb8973b9811f0babb2142f48d28
+EBUILD DirectFB-1.7.6.ebuild 6739 SHA256 631540343e59948b01b9676e18dc2fafbe048f7e0783777d8ba3752b2de518d2 SHA512 7d0af861445515a993617aae3b96646f9c6a7c2fd342657e98788226fccb02d711c1c408be49c8784ee82172711d4f9121ee21c14175e794efc3bdf6c2218094 WHIRLPOOL 12a804540fe2e41a5d4c54f3a05664a32415cdcdbde57fa1fedbc75de3d280661fe1f721f4cd2d523b8793132db5e6318ddce30509c9d52a11537c69d097b189
+MISC ChangeLog 19785 SHA256 745eaa39832dfc0ca9457f34061a6bcf340b4d1fa602f183d15f32e8c82e6657 SHA512 f69a2af6ec8866b7300088b694ab97352b7bf33083c7ee3677bfc64d279c9cc27b8e1ee2c62dfc3a986c290f92c993943452036d1ab4de589e0b9ce51f35fbff WHIRLPOOL 6c8f8c1dc4b2687298983bd4209d2179c9da9c467662eeec87d09724f4ce07df0706f721def7aaa71ad5255c6753be6697cbcba0f44684812f59b92cba426a24
 MISC metadata.xml 1851 SHA256 d554b7954117c98106bc96875aebe5f8a88c38fcb356a55b1784c3eb3579005a SHA512 348db55422f923d22fa9ec8f73fcb0c492e412f5177e4e5109bca76a5d3daf03fa346af7c04183cbb1c1b8aea6472eabd7b2e4ea74ec7c4eb2751e2185764257 WHIRLPOOL bd9a0c7ce4fef1fa7ffd54652bc8fa5083cba5f63f589fa3675a49e923fd3003a63f145e1d9d53fdf1cf58d02f321c25f079b0e47137ecece7e0bc1a4ecf7c24
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2
 
-iQIcBAEBCAAGBQJUQuXpAAoJEPGu1DbS6WIAAucP/igSet/V+1gupCnsnjNic95l
-xtcfoNpzYUPkYfj8zZGG7oMFAL9HX4W0P6Nn5v0ocuyT+gDRetu5ASa7F3nJlTCL
-E6KuY9KllYhIDLbG4ucDoGzLAEHSQ1EbWmwfIfVrRFuHfSjAb4nnq098WsYTZRAt
-i4yR8704IhAKOu9d8ZtujXgeISLnzR5Yr1wsgmMYHZb4UA1mzRFj8XM09076cX+w
-Op36/2aajMuI/QPuGMvXp2r+5KXR9q4XsUEJwon5xXJk10cnNj7EAbVpkIlAWRSa
-tRfuLV6hJF0U6oAwnE8O5AbN5hBO1yo4l00q4Q1mMabmLnknYtIDyJzlQPGY97FX
-XJJJ1w582s2IWFBkWt8cII5TcYBGsMp5t0XLAjwa7x19wezHjhLtvZc3o79HAhRu
-sVzboTwfZEzrsTY3Hr8ePdA+/6hQR8WVV8MZhaiLKF/JGVol6v/6saFa2wWTNWwS
-oEs4YheZ1ihr1HV1jyoQLAoXH7aQA5MHpL83h2qdUOOPPjkTseZJcW3f6YiFFtQR
-OyC/smQ/61AF8IfFoX7x8Ne82YYKkO9CkkCS3rJIb7i+jhv584PIwdc3hKwTW/iG
-uX9fxZgvPrn8Tz3rSyU2DAkThqeL6jD6vOBXquFGYAwERGYyMWNAaP4MxdF7q/ar
-+prmq2CxYUTi6OG6sBJb
-=kfVA
+iQIcBAEBCAAGBQJUQ/5vAAoJEPGu1DbS6WIAQjUP/3voYZyI8igleSr6hqGiStcN
+Lomi/zckbc8Xk9HD1tMr+pPYCRh/vEmpNheG8yRSi8jvb1Vr6MxHocRJh2G7bFM+
+S9IWsjZ5cL5is4QPsCv+4lS+FL5YTZ6hFrNWKVh6nlgNRKSLUM8Q5tOGIOhD5mjm
+gL495VOPIs5HB6ynTOQzFW0p/1tUiB5sw5b2Ean/KI7u2AGIZFVA2+sEwuBDGMof
+6EszmEuAmZ4byeD0EtNrTy4zmG5wV8b2idE240ukAZiTWIFjtpKGhioIO9zNmAh7
+Hn8FDo1RDUzBkhGdnRkSXJ3ERCuXJwjK+hFBXZbRPXkZY3xkrxqRIcATIFcMzh4F
+QHon6WDiTqkjApOepTmn2VVmJ0NuISNukYt+NdbhEYP81Wu21MZZ0DCufBYESfqb
+r4SuClCv5c4Zm3eV5GzCc9Xw6JPctLK4ZF7hhPE7DpU6yYrDxi0B0YmL0Xfd2/oG
+FJF3toGFIJHu0u3McLVLnDfgF7wleywEjfP1FSVAFFjpdspojIDBHSl+J9UlcBCG
+ToOnbGLzXJ6LefX8LrZbt7I6HFAXP86ChVOEkmQVrnpTWqV+WPG+elKREYecwoQh
+GmnU6k97scsImTlanvhO1h5LP22blKv1mH7q0UNqwmVCWiuGRJyWtSjL3+iWt3Uw
+wgBo6nBMBt6xSxBXPnPN
+=gf2c
 -----END PGP SIGNATURE-----