Initial ebuild. Needed for wayland support in media-libs/clutter. Closes bug #513856.

Package-Manager: portage-2.2.15/cvs/Linux x86_64
Manifest-Sign-Key: 0xC6085806

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-libs/libinput/libinput-0.7.0.ebuild b/dev-libs/libinput/libinput-0.7.0.ebuild
new file mode 100644
index 000000000000..dc8583b8e33f
--- /dev/null
+++ b/dev-libs/libinput/libinput-0.7.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libinput/libinput-0.7.0.ebuild,v 1.1 2014/12/23 22:25:18 eva Exp $
+
+EAPI="5"
+
+inherit eutils
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/libinput/"
+SRC_URI="http://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+# License appears to be a variant of libtiff
+LICENSE="libtiff"
+SLOT="0/5"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="
+	>=dev-libs/libevdev-0.4
+	>=sys-libs/mtdev-1.1
+	virtual/libudev
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-libs/check-0.9.10 )
+"
+# tests can even use: dev-util/valgrind
+
+src_prepare() {
+	# Doc handling in kinda strange but everything
+	# is available in the tarball already.
+	sed -e 's/^\(SUBDIRS =.*\)doc\(.*\)$/\1\2/' \
+		-i Makefile.am Makefile.in || die
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	econf \
+		--disable-event-gui \
+		$(use_enable test tests)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc -r doc/html
+	prune_libtool_files
+}