Add missing dep on dev-texlive/texlive-genericextra (bug #531664).

Package-Manager: portage-2.2.14/cvs/Linux x86_64
Manifest-Sign-Key: 0x4AB3E85B4F064CA3

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-tex/glossaries/glossaries-4.12-r1.ebuild b/dev-tex/glossaries/glossaries-4.12-r1.ebuild
new file mode 100644
index 000000000000..014627941351
--- /dev/null
+++ b/dev-tex/glossaries/glossaries-4.12-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-tex/glossaries/glossaries-4.12-r1.ebuild,v 1.1 2014/12/06 02:37:27 radhermit Exp $
+
+EAPI=5
+
+inherit latex-package
+
+DESCRIPTION="Create glossaries and lists of acronyms"
+HOMEPAGE="http://www.ctan.org/pkg/glossaries/"
+SRC_URI="http://dev.gentoo.org/~radhermit/dist/${P}.zip"
+
+LICENSE="LPPL-1.2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~s390 ~sh ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples"
+
+RDEPEND="dev-lang/perl
+	dev-texlive/texlive-latexrecommended
+	>=dev-texlive/texlive-latexextra-2012
+	>=dev-texlive/texlive-genericextra-2014"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+TEXMF="/usr/share/texmf-site"
+S=${WORKDIR}/${PN}
+
+src_install() {
+	latex-package_src_doinstall styles
+
+	dobin makeglossaries
+
+	dodoc CHANGES README
+	if use doc ; then
+		latex-package_src_doinstall pdf
+	fi
+	if use examples ; then
+		docinto examples
+		dodoc samples/*.tex
+	fi
+}