New ebuild for Nautilus extension for launching commands from the right-click menu, formerly maintained in Sunrise; thanks to Luca Marturana, Luis Medinas, Guy Ratcliffe, rajas, Alex Tarkovsky, Jakub Moc, Thomas Sachau, Justin Lecher, David Abbott, and Adam Mills (bug #104816).

Package-Manager: portage-2.2.0_alpha90/cvs/Linux x86_64

1 files changed, 56 insertions, 0 deletions

diff --git a/gnome-extra/nautilus-actions/nautilus-actions-3.2.2-r300.ebuild b/gnome-extra/nautilus-actions/nautilus-actions-3.2.2-r300.ebuild
new file mode 100644
index 000000000000..018f778da096
--- /dev/null
+++ b/gnome-extra/nautilus-actions/nautilus-actions-3.2.2-r300.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/nautilus-actions/nautilus-actions-3.2.2-r300.ebuild,v 1.1 2012/03/08 02:57:30 tetromino Exp $
+
+EAPI="4"
+
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="Configures programs to be launched when files are selected in Nautilus"
+HOMEPAGE="http://www.nautilus-actions.org/"
+
+LICENSE="GPL-2 FDL-1.3"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="deprecated"
+
+RDEPEND=">=dev-libs/glib-2.30:2
+	>=dev-libs/libxml2-2.6:2
+	dev-libs/libunique:3
+	>=gnome-base/libgtop-2.23.1:2
+	>=gnome-base/nautilus-3
+	sys-apps/util-linux
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libICE
+	>=x11-libs/libSM-1
+
+	!gnome-extra/nautilus-actions:2"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.35.5
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		$(use_enable deprecated)
+		--disable-gconf
+		--with-gtk=3"
+}
+
+src_prepare() {
+	# install docs in /usr/share/doc/${PF}, not ${P}
+	sed -i -e "s:/doc/@PACKAGE@-@VERSION@:/doc/${PF}:g" \
+		Makefile.{am,in} \
+		docs/Makefile.{am,in} \
+		docs/nact/Makefile.{am,in} || die
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	# Do not install COPYING
+	rm -v "${ED}usr/share/doc/${PF}"/COPYING* || die
+}