Added shapepatch. Thanks to Geoffrey <geoffrey@andrews.edu>, see bug #20877.

1 files changed, 58 insertions, 0 deletions

diff --git a/media-gfx/transfig/transfig-3.2.4-r2.ebuild b/media-gfx/transfig/transfig-3.2.4-r2.ebuild
new file mode 100644
index 000000000000..3f0340c2735f
--- /dev/null
+++ b/media-gfx/transfig/transfig-3.2.4-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/transfig/transfig-3.2.4-r2.ebuild,v 1.1 2004/09/02 02:54:03 usata Exp $
+
+inherit gcc eutils
+
+MY_P=${PN}.${PV}
+S=${WORKDIR}/${MY_P}
+SHAPE_P=shape-patch.${PV}-shape-1.1
+
+DESCRIPTION="A set of tools for creating TeX documents with graphics which can be printed in a wide variety of environments"
+SRC_URI="http://www.xfig.org/xfigdist/${MY_P}.tar.gz
+	http://www.ctan.org/tex-archive/graphics/transfig-shapepatch/${SHAPE_P}.tar.gz"
+HOMEPAGE="http://www.xfig.org"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~x86 ~ppc ~sparc ~alpha ~hppa ~amd64"
+IUSE=""
+
+DEPEND="virtual/x11
+	>=media-libs/jpeg-6
+	media-libs/libpng"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+	epatch ${FILESDIR}/${P}.patch
+	epatch ../${SHAPE_P}/${PN}.${SHAPE_P#*.}.patch	# bug #20877
+
+	#bad way to fix a bad issue
+	if [ "$(gcc-major-version)" -eq "3" -a "$(gcc-minor-version)" -ge "3" ]
+	then
+		epatch  ${FILESDIR}/${P}-gcc-3.3.patch
+	fi
+}
+
+src_compile() {
+	xmkmf || die "xmkmf failed"
+	make Makefiles || die "make Makefiles failed"
+
+	emake BINDIR=/usr/bin LIBDIR=/usr/lib || die "emake failed"
+}
+
+src_install() {
+	make \
+		DESTDIR=${D} \
+		BINDIR=/usr/bin \
+		LIBDIR=/usr/lib \
+		install || die
+
+	#Install docs
+	dodoc README CHANGES LATEX.AND.XFIG NOTES
+	dodoc ../${SHAPE_P}/shapepatch.README
+	doman doc/fig2dev.1
+	doman doc/fig2ps2tex.1
+	doman doc/pic2tpic.1
+}