bump gimp to 2.4.4

Package-Manager: portage-2.1.4.1

3 files changed, 151 insertions, 2 deletions

diff --git a/media-gfx/gimp/ChangeLog b/media-gfx/gimp/ChangeLog
index 3ac8f6e9f673..88e4db294f57 100644
--- a/media-gfx/gimp/ChangeLog
+++ b/media-gfx/gimp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gimp
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.247 2008/01/22 07:45:28 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.248 2008/02/04 17:24:39 hanno Exp $
+
+*gimp-2.4.4 (04 Feb 2008)
+
+  04 Feb 2008; Hanno Boeck <hanno@gentoo.org> +gimp-2.4.4.ebuild:
+  Version bump.
 
 *gimp-2.4.3 (22 Jan 2008)
 
diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index a1207150715c..555f08dbdd8c 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -5,12 +5,14 @@ DIST gimp-2.4.0.tar.bz2 17617876 RMD160 e21ce418a4b367b776f49d655ea42c9b09cd05d6
 DIST gimp-2.4.1.tar.bz2 17763371 RMD160 2fd7973e6a836718e952f3b8dfa8d635140020b9 SHA1 5d554959e9583845acff713e5f65e02fcf37db0c SHA256 fffdf060723c738004bfcdb2d72edb44652900d9ae3e5bad21940425938c3ba1
 DIST gimp-2.4.2.tar.bz2 17777846 RMD160 f9da1008c29746379eb728f27e9b0d452ba2318f SHA1 4913a411abde3fccae5350e00a9bd20742715367 SHA256 00393b2d2aa163a7791dc4456306bf903d920d345aeee162d0e2ce85cfae5fb1
 DIST gimp-2.4.3.tar.bz2 17737035 RMD160 52b5089a70d68177b5a8191723a03bad225aadcd SHA1 2be7a61d11c86da41e4645fee518a7bfe951302a SHA256 0b498978aec6054008cb2429e403660ae8690068820d5ffd0a7d0cc54d6d2fd5
+DIST gimp-2.4.4.tar.bz2 17775071 RMD160 b497e8bdf986bf94673ac702ecf0289350fc14e0 SHA1 47c80470e15e3fa29e46652130e870e0c952789f SHA256 d059c7159bca6e90f2a8201f1efdbd1c5af52a876e7c6462a7829d4b1618d4d6
 EBUILD gimp-2.2.17.ebuild 4468 RMD160 5edb165b9d2a87fde7721bd94d0f551bc78b4b62 SHA1 e3597a3e2763af8de525db82f7fc2e2a80b162b7 SHA256 01a713b465de58358a5504d06c0dc33e55e1f648b874b424a1f3aebb47830930
 EBUILD gimp-2.3.19.ebuild 3449 RMD160 a1931074784c38e52c2d9debbdb2141cb9b86597 SHA1 fe0fec80a6de241b2e52e1f5559cd096d966895c SHA256 5f679e7ccda242e000d0ea4c390ae82f75f8394cf35a8521c119647bcca5c7d2
 EBUILD gimp-2.4.0.ebuild 3716 RMD160 71fd99e34a168d7d90f8e35ab07388cf3e41cf0e SHA1 cd62a493e84a36b39b3be3d4f1db69265635cf19 SHA256 39d924a368e2a3ac579713eeab77703c7b5b195526cfaedfed365b81e6c524a7
 EBUILD gimp-2.4.1.ebuild 3716 RMD160 71bae9c51e5ee7c4ced4db55e89e2568d1fb11d4 SHA1 46ecf3779494ff08c5ade9f30cc9fc2c997c0756 SHA256 59a3e4ef995dd7e2a6715bea9c8b4f57112c380dcf7fba3403715a9201f25f5e
 EBUILD gimp-2.4.2.ebuild 3706 RMD160 cf265b6a9274af37bff76aa7048e20a1bbcbc946 SHA1 41ffb1ab555669664ba5cca84b4ae53d35ed1ce0 SHA256 cdbaa54bf2571d3ab60001866a4270a58c0fac37846135f3256bdc0f85a93a1b
 EBUILD gimp-2.4.3.ebuild 3714 RMD160 4216ae18c729c4b4725f325c850790a6e9847d4a SHA1 1e3e27afa0c5b88cc5c003f37dd1d7dab310e61c SHA256 2b2143a984851116e5a5cd34dd1a5ebf605596e25834368a1ea4e49c3c92e64f
+EBUILD gimp-2.4.4.ebuild 4041 RMD160 d2691fb9a252414cbcb937098daa16b3c47dd37e SHA1 3638237b4c22aec7ccaa08fe4d7606eff4d4fbe8 SHA256 215556bc979c3e9b152bb0553c6e31d8ebf72cbdef1eb40ac9d5eb23dfed4abc
 EBUILD gimp-9999.ebuild 3786 RMD160 ede6db9fbc04791c7dd3ac7f38bdd86d9e296fc6 SHA1 488c776ec66885737fc8da4fcd34c7689badc968 SHA256 f859ede7919d34622459e7ac823bc4a515d137692dc07de3f37f04c0556f06ea
-MISC ChangeLog 33757 RMD160 1a40abe604b003803aa44854f7e2180275c16292 SHA1 40d89b95642b376328b330e284672c640bef85cf SHA256 854dda4f9b445a80ee91b0dc06ea77b2f92decc2f030759b33f682cc51bef699
+MISC ChangeLog 33869 RMD160 3e2a5d9e357a289d966469378111418af820a129 SHA1 d5db58b698bd8c70d42c3f92f2286cb65b294fc6 SHA256 f6a88d95948af10c6cc08fbeae7638584dfd3337dcb6fdb3a019d7a1f898dd82
 MISC metadata.xml 220 RMD160 a49072631c03f8ac3685b12169abeef3b34ad3d6 SHA1 9614887db749b0a3c17016da5b3ec0e42b908ad3 SHA256 c893488c84e6da8039f2b473982f03e934ec12f8fe2c1ace770f9e34969db081
diff --git a/media-gfx/gimp/gimp-2.4.4.ebuild b/media-gfx/gimp/gimp-2.4.4.ebuild
new file mode 100644
index 000000000000..457347f155a4
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.4.4.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.4.4.ebuild,v 1.1 2008/02/04 17:24:39 hanno Exp $
+
+inherit fdo-mime flag-o-matic multilib python eutils autotools
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.4/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 -mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="alsa aalib altivec curl dbus debug doc exif gtkhtml gnome hal lcms mmx mng pdf png python smp sse svg tiff wmf"
+# jpeg temporarily removed, disabling jpeg requires upstream fix which will come in 2.5
+
+RDEPEND=">=dev-libs/glib-2.12.3
+	>=x11-libs/gtk+-2.10.13
+	>=x11-libs/pango-1.12.2
+	>=media-libs/freetype-2.1.7
+	>=media-libs/fontconfig-2.2.0
+	>=media-libs/libart_lgpl-2.3.8-r1
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-themes/hicolor-icon-theme
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.14a-r1 )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	hal? ( sys-apps/hal )
+	doc? ( app-doc/gimp-help )
+	gnome? ( >=gnome-base/gnome-vfs-2.10.0
+		>=gnome-base/libgnomeui-2.10.0
+		>=gnome-base/gnome-keyring-0.4.5 )
+	gtkhtml? ( =gnome-extra/gtkhtml-2* )
+	>=media-libs/jpeg-6b-r2
+	exif? ( >=media-libs/libexif-0.6.15 )
+	lcms? ( media-libs/lcms )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-bindings-0.3.1 )
+	png? ( >=media-libs/libpng-1.2.2 )
+	python?	( >=dev-lang/python-2.2.1
+		>=dev-python/pygtk-2.10.4 )
+	tiff? ( >=media-libs/tiff-3.5.7 )
+	svg? ( >=gnome-base/librsvg-2.8.0 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.12.0
+	>=dev-util/intltool-0.31
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+pkg_setup() {
+	if use pdf && ! built_with_use app-text/poppler-bindings gtk; then
+		eerror "This package requires app-text/poppler-bindings compiled with GTK+ support."
+		die "Please reemerge app-text/poppler-bindings with USE=\"gtk\"."
+	fi
+	if use alsa && ! built_with_use media-libs/alsa-lib midi; then
+		eerror "This package requires media-libs/alsa-lib compiled with midi support."
+		die "Please reemerge media-libs/alsa-lib with USE=\"midi\"."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Workaround for MIME-type, this is fixed in gimp trunk, so we can
+	# remove this with >= 2.5
+	use svg && epatch "${FILESDIR}/gimp-svg.diff"
+
+	eautoreconf
+}
+
+src_compile() {
+	# workaround portage variable leakage
+	local AA=
+
+	# gimp uses inline functions (e.g. plug-ins/common/grid.c) (#23078)
+	# gimp uses floating point math, needs accuracy (#98685)
+	filter-flags "-fno-inline" "-ffast-math"
+	# gimp assumes char is signed (fixes preview corruption)
+	if use ppc || use ppc64; then
+		append-flags "-fsigned-char"
+	fi
+
+	econf --enable-default-binary \
+		--with-x \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with curl) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with dbus) \
+		$(use_with hal) \
+		$(use_with gnome) \
+		$(use_with gtkhtml gtkhtml2) \
+		--with-libjpeg \
+		$(use_with exif libexif) \
+		$(use_with lcms) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with wmf) \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "make install failed"
+
+	dodoc AUTHORS ChangeLog* HACKING NEWS README*
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+
+	elog
+	elog "If you want Postscript file support, emerge ghostscript."
+	elog
+
+	python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}