New upstream version, missing ~sparc keyword until daap dependency is fixed. Uses the same patches as 0.8.2_beta2 minus the sap one.

Package-Manager: portage-2.0.51.22-r1

4 files changed, 285 insertions, 5 deletions

diff --git a/media-video/vlc/ChangeLog b/media-video/vlc/ChangeLog
index d85abea373a0..82323b674252 100644
--- a/media-video/vlc/ChangeLog
+++ b/media-video/vlc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/vlc
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.92 2005/06/10 17:29:24 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.93 2005/06/26 18:57:38 flameeyes Exp $
+
+*vlc-0.8.2 (26 Jun 2005)
+
+  26 Jun 2005; Diego Pettenò <flameeyes@gentoo.org> +vlc-0.8.2.ebuild:
+  New upstream version, missing ~sparc keyword until daap dependency is fixed.
+  Uses the same patches as 0.8.2_beta2 minus the sap one.
 
   10 Jun 2005; Diego Pettenò <flameeyes@gentoo.org> vlc-0.8.1-r3.ebuild,
   vlc-0.8.2_beta2.ebuild:
diff --git a/media-video/vlc/Manifest b/media-video/vlc/Manifest
index dd2e7c3d8676..03cd1f89c849 100644
--- a/media-video/vlc/Manifest
+++ b/media-video/vlc/Manifest
@@ -1,7 +1,7 @@
 -----BEGIN PGP SIGNED MESSAGE-----
 Hash: SHA1
 
-MD5 5f397816417860bd30c1ec8d25977500 ChangeLog 18726
+MD5 baf05ef34c41400241272c11897a8fe7 ChangeLog 18962
 MD5 7300a7b361fa9f48e37722c6952bd432 metadata.xml 158
 MD5 2fbab31179d6bdf6dafb6aa263fe492f vlc-0.6.2-r1.ebuild 6503
 MD5 652bc3bbeeeb343edfed07a13e2ecb7a vlc-0.6.2.ebuild 5551
@@ -10,6 +10,7 @@ MD5 ce0ead5f060f1a70fe6e867bc3ed231e vlc-0.8.1-r1.ebuild 6953
 MD5 82c6363b6853c66488c9ab0cb2bc2ef2 vlc-0.8.1-r2.ebuild 7164
 MD5 e6e1eb64af6cddda4ce8177ed782d1c3 vlc-0.8.1-r3.ebuild 7233
 MD5 4b4f12a15f8279439174a01ce570da75 vlc-0.8.2_beta2.ebuild 8833
+MD5 ff8f0c9d92bae23928b080065de6ba0b vlc-0.8.2.ebuild 8518
 MD5 09c124e45049f615519ded3278a97376 files/0.6.2-mozilla-fix.patch 1261
 MD5 d766f772e3e3be4f8d6cbf4d54bf2700 files/digest-vlc-0.6.2 63
 MD5 cc5d4fb953ad7bd0ee3e14076811a1d4 files/digest-vlc-0.6.2-r1 202
@@ -20,10 +21,11 @@ MD5 c5c0f3cdd6b2afd05a3090dfc55074e0 files/glide.patch 744
 MD5 0ee383795d543048e4d47eb58f6d36bb files/mpeg2dec-20030612-configure.in-fpic.patch 1065
 MD5 1047cf43de2ff9156978d79e7a7bab05 files/digest-vlc-0.8.1-r3 127
 MD5 50e666eaab2d6547b696bc3519e0d250 files/digest-vlc-0.8.2_beta2 138
+MD5 460bf7b3005ee9cf204e50526bfca381 files/digest-vlc-0.8.2 127
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v1.4.1 (GNU/Linux)
 
-iD8DBQFCqcztj5H05b2HAEkRAsEnAKCPkU4vXESUMv4HFmThgcb0Hy2+EQCfWFgJ
-CLVDEluPsKJGhXZZAhbPpsk=
-=cOvn
+iD8DBQFCvvrFj5H05b2HAEkRAnKXAJ42pKZnFtT4ILf+YSRYGH/rGcmxZQCeN6+H
+NPNg7jrMNfiojJlApYwOHkY=
+=onH1
 -----END PGP SIGNATURE-----
diff --git a/media-video/vlc/files/digest-vlc-0.8.2 b/media-video/vlc/files/digest-vlc-0.8.2
new file mode 100644
index 000000000000..5447220458b7
--- /dev/null
+++ b/media-video/vlc/files/digest-vlc-0.8.2
@@ -0,0 +1,2 @@
+MD5 c9d07ee1c41766bf56a27b47bdba2ad0 vlc-0.8.2.tar.bz2 5785680
+MD5 f9e951907a20dc830fb1f94e0a8d4340 vlc-patches-4.tar.bz2 2438
diff --git a/media-video/vlc/vlc-0.8.2.ebuild b/media-video/vlc/vlc-0.8.2.ebuild
new file mode 100644
index 000000000000..176c1fa323b3
--- /dev/null
+++ b/media-video/vlc/vlc-0.8.2.ebuild
@@ -0,0 +1,270 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.8.2.ebuild,v 1.1 2005/06/26 18:57:38 flameeyes Exp $
+
+# Missing USE-flags due to missing deps:
+# media-vidoe/vlc:tremor - Enables Tremor decoder support
+# media-video/vlc:tarkin - Enables experimental tarkin codec
+# media-video/vlc:h264 - Enables H264 encoding support with libx264
+
+# Missing USE-flags due to needed testing
+# media-video/vlc:dirac - Enables experimental dirac codec
+
+inherit libtool toolchain-funcs eutils wxwidgets
+
+PATCHLEVEL="4"
+DESCRIPTION="VLC media player - Video player and streamer"
+HOMEPAGE="http://www.videolan.org/vlc/"
+SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2
+	http://digilander.libero.it/dgp85/gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+# ~sparc keyword dropped due to missing daap dependency.. mark or use.mask it
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="a52 3dfx nls unicode debug altivec httpd vlm gnutls live v4l cdda ogg matroska dvb dvd vcd ffmpeg aac dts flac mpeg vorbis theora X opengl freetype svg fbcon svga oss aalib ggi libcaca esd arts alsa wxwindows ncurses xosd lirc joystick mozilla hal stream mp3 xv bidi gtk2 sdl png xml2 samba daap slp corba screen mod speex"
+
+RDEPEND="hal? ( =sys-apps/hal-0.4* )
+		cdda? ( >=dev-libs/libcdio-0.71
+			>=media-libs/libcddb-0.9.5 )
+		live? ( >=media-plugins/live-2005.01.29 )
+		dvd? (  media-libs/libdvdread
+				media-libs/libdvdcss
+				>=media-libs/libdvdnav-0.1.9
+				media-libs/libdvdplay )
+		esd? ( media-sound/esound )
+		ogg? ( media-libs/libogg )
+		matroska? ( >=media-libs/libmatroska-0.7.5 )
+		mp3? ( media-libs/libmad )
+		ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20050226-r1 )
+		a52? ( media-libs/a52dec )
+		dts? ( media-libs/libdts )
+		flac? ( media-libs/flac )
+		mpeg? ( >=media-libs/libmpeg2-0.3.2 )
+		vorbis? ( media-libs/libvorbis )
+		theora? ( media-libs/libtheora )
+		X? ( virtual/x11 )
+		xv? ( virtual/x11 )
+		freetype? ( media-libs/freetype
+			media-fonts/ttf-bitstream-vera )
+		svga? ( media-libs/svgalib )
+		ggi? ( media-libs/libggi )
+		aalib? ( media-libs/aalib )
+		libcaca? ( media-libs/libcaca )
+		arts? ( kde-base/arts )
+		alsa? ( virtual/alsa )
+		wxwindows? ( =x11-libs/wxGTK-2.6* )
+		ncurses? ( sys-libs/ncurses )
+		xosd? ( x11-libs/xosd )
+		lirc? ( app-misc/lirc )
+		mozilla? ( www-client/mozilla )
+		3dfx? ( media-libs/glide-v3 )
+		bidi? ( >=dev-libs/fribidi-0.10.4 )
+		gnutls? ( >=net-libs/gnutls-1.0.17 )
+		opengl? ( virtual/opengl )
+		sys-libs/zlib
+		png? ( media-libs/libpng )
+		media-libs/libdvbpsi
+		aac? ( >=media-libs/faad2-2.0-r2 )
+		sdl? ( >=media-libs/libsdl-1.2.8 )
+		xml2? ( dev-libs/libxml2 )
+		samba? ( net-fs/samba )
+		vcd? ( >=dev-libs/libcdio-0.72
+			>=media-video/vcdimager-0.7.21 )
+		daap? ( >=media-libs/libopendaap-0.3.0 )
+		slp? ( net-libs/openslp )
+		corba? ( >=gnome-base/orbit-2.8.0
+			>=dev-libs/glib-2.3.2 )
+		v4l? ( sys-kernel/linux-headers )
+		dvb? ( sys-kernel/linux-headers )
+		joystick? ( sys-kernel/linux-headers )
+		mod? ( media-libs/libmodplug )
+		speex? ( media-libs/speex )
+		svg? ( >=gnome-base/librsvg-2.5.0 )"
+#		threads? ( dev-libs/pth )
+#		portaudio? ( >=media-libs/portaudio-0.19 )
+
+DEPEND="${RDEPEND}
+	dev-util/cvs
+	>=sys-devel/gettext-0.11.5
+	=sys-devel/automake-1.6*
+	sys-devel/autoconf
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	if use wxwindows; then
+		WX_GTK_VER="2.6"
+		if use gtk2; then
+			if use unicode; then
+				need-wxwidgets unicode || die "You need to install wxGTK with unicode support."
+			else
+				need-wxwidgets gtk2 || die "You need to install wxGTK with gtk2 support."
+			fi
+		else
+			need-wxwidgets gtk || die "You need to install wxGTK with gtk support."
+		fi
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+
+	# We only have glide v3 in portage
+	cd ${S}
+
+	EPATCH_EXCLUDE="00_all_sap.patch"
+	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/0.8.2_beta2"
+
+	./bootstrap
+
+	sed -i -e \
+		"s:/usr/include/glide:/usr/include/glide3:;s:glide2x:glide3:" \
+		configure || die "sed glide failed."
+
+	# Fix the default font
+	sed -i -e "s:/usr/share/fonts/truetype/freefont/FreeSerifBold.ttf:/usr/share/fonts/ttf-bitstream-vera/VeraBd.ttf:" modules/misc/freetype.c
+}
+
+src_compile () {
+	# Avoid timestamp skews with autotools
+	touch configure.ac
+	touch aclocal.m4
+	touch configure
+	touch config.h.in
+	find . -name Makefile.in | xargs touch
+
+	# reason why:
+	# skins2 interface is horribly broken for some reason.
+	# Therefore it's being disabled for the standard wxwindows
+	# interface which isn't
+	myconf="${myconf} --disable-skins2"
+
+	# reason why:
+	# mozilla-config is not in ${PATH}
+	# so the configure script won't find it
+	# unless we setup the proper variable
+	if use mozilla ; then
+		myconf="${myconf} --enable-mozilla MOZILLA_CONFIG=/usr/lib/mozilla/mozilla-config"
+	else
+		myconf="${myconf} --disable-mozilla"
+	fi
+
+	if use wxwindows; then
+		myconf="${myconf} --with-wx-config=$(basename ${WX_CONFIG}) --with-wx-config-path=$(dirname ${WX_CONFIG})"
+	fi
+
+	if use ffmpeg; then
+		myconf="${myconf} --enable-ffmpeg"
+
+		built_with_use media-video/ffmpeg aac \
+			&& myconf="${myconf} --with-ffmpeg-aac"
+
+		built_with_use media-video/ffmpeg dts \
+			&& myconf="${myconf} --with-ffmpeg-dts"
+
+		built_with_use media-video/ffmpeg zlib \
+			&& myconf="${myconf} --with-ffmpeg-zlib"
+
+		built_with_use media-video/ffmpeg encode \
+			&& myconf="${myconf} --with-ffmpeg-mp3lame"
+
+	else
+		myconf="${myconf} --disable-ffmpeg"
+	fi
+
+	# Portaudio support needs at least v19
+	# pth (threads) support is quite unstable with latest ffmpeg/libmatroska.
+	econf \
+		$(use_enable altivec) \
+		$(use_enable unicode utf8) \
+		$(use_enable stream sout) \
+		$(use_enable httpd) \
+		$(use_enable vlm) \
+		$(use_enable gnutls) \
+		$(use_enable v4l) \
+		$(use_enable cdda) $(use_enable cdda cddax)\
+		$(use_enable vcd) $(use_enable vcd vcdx) \
+		$(use_enable dvb) $(use_enable dvb pvr) \
+		$(use_enable ogg) \
+		$(use_enable matroska mkv) \
+		$(use_enable flac) \
+		$(use_enable vorbis) \
+		$(use_enable theora) \
+		$(use_enable X x11) \
+		$(use_enable xv xvideo) \
+		$(use_enable opengl glx) $(use_enable opengl) \
+		$(use_enable freetype) \
+		$(use_enable bidi fribidi) \
+		$(use_enable dvd dvdread) $(use_enable dvd dvdplay) $(use_enable dvd dvdnav) \
+		$(use_enable fbcon fb) \
+		$(use_enable svga svgalib) \
+		$(use_enable 3dfx glide) \
+		$(use_enable aalib aa) \
+		$(use_enable libcaca caca) \
+		$(use_enable oss) \
+		$(use_enable esd) \
+		$(use_enable arts) \
+		$(use_enable alsa) \
+		$(use_enable wxwindows) \
+		$(use_enable ncurses) \
+		$(use_enable xosd) \
+		$(use_enable lirc) \
+		$(use_enable joystick) \
+		$(use_enable live livedotcom) $(use_with live livedotcom-tree /usr/lib/live) \
+		$(use_enable mp3 mad) \
+		$(use_enable aac faad) \
+		$(use_enable a52) \
+		$(use_enable dts) \
+		$(use_enable mpeg libmpeg2) \
+		$(use_enable ggi) \
+		$(use_enable 3dfx glide) \
+		$(use_enable sdl) \
+		$(use_enable hal) \
+		$(use_enable png) \
+		$(use_enable xml2 libxml2) \
+		$(use_enable samba smb) \
+		$(use_enable daap) \
+		$(use_enable slp) \
+		$(use_enable corba) \
+		$(use_enable mod) \
+		$(use_enable speex) \
+		--disable-pth \
+		--disable-portaudio \
+		${myconf} || die "configuration failed"
+
+	if [[ $(gcc-major-version) == 2 ]]; then
+		sed -i -e s:"-fomit-frame-pointer":: vlc-config || die "-fomit-frame-pointer patching failed"
+	fi
+
+	# reason why:
+	# looks for xpidl in /usr/lib/mozilla/xpidl
+	# and doesn't find it there because it's
+	# in /usr/bin! - ChrisWhite
+	if use mozilla; then
+		sed -e "s:^XPIDL = .*:XPIDL = /usr/bin/xpidl:" -i mozilla/Makefile \
+		|| die "could not fix XPIDL path"
+	fi
+
+	emake -j1 || die "make of VLC failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "Installation failed!"
+
+	dodoc ABOUT-NLS AUTHORS MAINTAINERS HACKING THANKS TODO NEWS README \
+		doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
+
+	rm -r ${D}/usr/share/vlc/vlc*.png ${D}/usr/share/vlc/vlc*.xpm ${D}/usr/share/vlc/vlc*.ico \
+		${D}/usr/share/vlc/kvlc*.png ${D}/usr/share/vlc/kvlc*.xpm ${D}/usr/share/vlc/qvlc*.png \
+		${D}/usr/share/vlc/qvlc*.xpm ${D}/usr/share/vlc/gvlc*.png ${D}/usr/share/vlc/gvlc*.xpm \
+		${D}/usr/share/vlc/gvlc*.ico ${D}/usr/share/vlc/gnome-vlc*.png \
+		${D}/usr/share/vlc/gnome-vlc*.xpm ${D}/usr/share/vlc/skins2 \
+		${D}/usr/share/doc/vlc
+
+	for res in 16 32 48; do
+		insinto /usr/share/icons/hicolor/${res}x${res}/apps/
+		newins ${S}/share/vlc${res}x${res}.png vlc.png
+	done
+
+	make_desktop_entry vlc "VLC Media Player" vlc "AudioVideo;Player"
+}