Remove now unnecessary gnome-power-manager blocker, all revisions of it that could file collide with hal are gone now and it included the 2.22 versions in the blocker, which was not necessary and is problematic with HAL stabling but g-p-m staying at 2.22. This fixes bug 287037; Gracious revbump to ensure amd64 stable users get the blocker fixed in VDB, permission from mrpouet to keep the stable keyword

Package-Manager: portage-2.2_rc33/cvs/Linux x86_64
RepoMan-Options: --force

5 files changed, 332 insertions, 10 deletions

diff --git a/sys-apps/hal/ChangeLog b/sys-apps/hal/ChangeLog
index fb7ce7d845fe..b0a53986ed15 100644
--- a/sys-apps/hal/ChangeLog
+++ b/sys-apps/hal/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for sys-apps/hal
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/ChangeLog,v 1.298 2009/09/29 21:25:15 mrpouet Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/ChangeLog,v 1.299 2009/09/30 11:59:28 leio Exp $
+
+*hal-0.5.12_rc1-r8 (30 Sep 2009)
+
+  30 Sep 2009; Mart Raudsepp <leio@gentoo.org> hal-0.5.12_rc1-r7.ebuild,
+  +hal-0.5.12_rc1-r8.ebuild, hal-0.5.13-r2.ebuild:
+  Remove now unnecessary gnome-power-manager blocker, all revisions of it
+  that could file collide with hal are gone now and it included the 2.22
+  versions in the blocker, which was not necessary and is problematic with
+  HAL stabling but g-p-m staying at 2.22. This fixes bug 287037; Gracious
+  revbump to ensure amd64 stable users get the blocker fixed in VDB,
+  permission from mrpouet to keep the stable keyword
 
   29 Sep 2009; Romain Perier <mrpouet@gentoo.org>
   hal-0.5.12_rc1-r7.ebuild:
diff --git a/sys-apps/hal/Manifest b/sys-apps/hal/Manifest
index b2320cc6bcdb..e17fbda5f96a 100644
--- a/sys-apps/hal/Manifest
+++ b/sys-apps/hal/Manifest
@@ -10,7 +10,8 @@ DIST hal-0.5.13-gentoo-patches-1.tar.bz2 4049 RMD160 82aa03e2c99a92aadd68f6ada69
 DIST hal-0.5.13.tar.bz2 918835 RMD160 34537d5f8bfb96c52ca066e787282b354179eb8f SHA1 788485fa78b2aa7a9d6b7de537a68ceff1564420 SHA256 d47c9799c18929cffbce5bfa48f35c89657d7f630c6da682f193928697c71ab5
 EBUILD hal-0.5.11-r9.ebuild 8893 RMD160 82350f2795c3be604aabd4d67fefbf45b98a742e SHA1 1f47d075d01d759b7bf287ba3f4b4bb8cad19b2d SHA256 af6589feba9fb9395f7d1e23bede156800fe3a870b94750c48c31c6a5572e5e8
 EBUILD hal-0.5.12_rc1-r6.ebuild 9821 RMD160 3861e904a70e10534fbde7af2c2c88f46f154c5d SHA1 c91f15233b0af3fd5661ae66a58646317d9a606e SHA256 f367e528a48ecdf93bd1334299462ec093e8674810b567ceaa9b747f9038b634
-EBUILD hal-0.5.12_rc1-r7.ebuild 9818 RMD160 8237b824b87fee1f6ea11438bfa2d9c5ea4465e5 SHA1 1cd01f5880adca43193951c7be1c6edc9116c0ac SHA256 9d829dad7cb96801ded4dd8521b7d86ded5433e65a266b7be8b587ccb7762ca8
-EBUILD hal-0.5.13-r2.ebuild 9849 RMD160 1016d9476397124b935d22d06b95492a6e72a0d6 SHA1 83563d3d82d36a4e3c0e8650674e20ba4ffe6353 SHA256 6ecaeef46862d291d38ef908b2464b1eb67515ba63b5d2ddd02c88c53cb8c17b
-MISC ChangeLog 53062 RMD160 ce7b25f90e41f4c1d5e625c740bb677e9deee73e SHA1 45dd2464248839542aa65db018a6fd65ce9e6bf5 SHA256 5ec1b2d289b1bdb07c6b44d4f56b6d767e1def8913a38a580d83ac6d8a0b09ad
+EBUILD hal-0.5.12_rc1-r7.ebuild 9769 RMD160 95a92aa81f15944ef2f10b425933f2dfb5418dbb SHA1 bc45ad8afdadf32cf745cb417d3dd14cac55edf7 SHA256 818095452fa1458bc069a3fbb56f853ee91bfa4208d04706e5b471e242f0af3d
+EBUILD hal-0.5.12_rc1-r8.ebuild 9669 RMD160 3d3bf3d280d6306e46c3e5857e07e2ea285c9c8b SHA1 3a8144727df4099a6f545cc4c281dadfdf838be0 SHA256 5eb8061c0b074fb7f01fb17f8e30655e8d1b684aa7a39bdcc8145a868866e6ed
+EBUILD hal-0.5.13-r2.ebuild 9799 RMD160 85fe6476b9c7916f2bedf9e3c56eb06909e8e4a5 SHA1 8fbc9245765ccb4c13bc628d901b6b8448664650 SHA256 96d2ed08817c2ebe294acb28bcb183313464aa22c2719b4fcb6bef7dc1c5ba94
+MISC ChangeLog 53636 RMD160 3e0ffc25620cbfc527625fc457b118d13bd7c816 SHA1 da855ded49e8a43028268ad0c15f0b17e1e1964b SHA256 7fe631e489194e4da6d5309b703eefa1e4021885b8831a9ca2f8a9a3968511c2
 MISC metadata.xml 2017 RMD160 90b6fed11f5582fce64fe36354e94b811478d21e SHA1 2b2693c7d677adf363e41e16cc71787fbe01d383 SHA256 910ab10f73ca0bccdea716f39dd3d3cc3d594bd25f6bbb7e25b70082be194048
diff --git a/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild b/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild
index 6a0bd33e3d61..ded3556a1661 100644
--- a/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild
+++ b/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild,v 1.2 2009/09/29 21:25:15 mrpouet Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.12_rc1-r7.ebuild,v 1.3 2009/09/30 11:59:28 leio Exp $
 
 EAPI="2"
 
@@ -59,8 +59,7 @@ DEPEND="${RDEPEND}
 					dev-libs/libxml2
 					dev-util/gtk-doc
 					app-text/docbook-sgml-utils
-				)
-		!<gnome-extra/gnome-power-manager-2.24.4-r2"
+				)"
 PDEPEND=">=app-misc/hal-info-20081219
 	!gnome-extra/hal-device-manager
 	laptop? ( >=sys-power/pm-utils-0.99.3 )"
diff --git a/sys-apps/hal/hal-0.5.12_rc1-r8.ebuild b/sys-apps/hal/hal-0.5.12_rc1-r8.ebuild
new file mode 100644
index 000000000000..6ede964360c9
--- /dev/null
+++ b/sys-apps/hal/hal-0.5.12_rc1-r8.ebuild
@@ -0,0 +1,312 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.12_rc1-r8.ebuild,v 1.1 2009/09/30 11:59:28 leio Exp $
+
+EAPI="2"
+
+inherit eutils linux-info autotools flag-o-matic multilib
+
+PATCH_VERSION="8"
+
+MY_P=${P/_/}
+S=${WORKDIR}/${MY_P}
+PATCHNAME="${MY_P}-gentoo-patches-${PATCH_VERSION}"
+DESCRIPTION="Hardware Abstraction Layer"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/hal"
+SRC_URI="http://hal.freedesktop.org/releases/${MY_P}.tar.bz2
+	 http://dev.gentoo.org/~dang/files/${PATCHNAME}.tar.bz2"
+
+LICENSE="|| ( GPL-2 AFL-2.0 )"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+
+KERNEL_IUSE="kernel_linux kernel_FreeBSD"
+IUSE="X acpi apm crypt consolekit debug dell disk-partition doc laptop policykit selinux ${KERNEL_IUSE}"
+
+RDEPEND=">=dev-libs/dbus-glib-0.61
+	>=dev-libs/glib-2.14
+	>=dev-libs/expat-1.95.8
+	 =virtual/libusb-0*
+	>=sys-apps/pciutils-2.2.7-r1
+	>=dev-util/gperf-3.0.3
+	  sys-apps/usbutils
+	  virtual/eject
+	amd64? ( >=sys-apps/dmidecode-2.7 )
+	dell? ( >=sys-libs/libsmbios-0.13.4 )
+	disk-partition? ( >=sys-apps/parted-1.8.0 )
+	ia64? ( >=sys-apps/dmidecode-2.7 )
+	kernel_linux? (
+		>=sys-fs/udev-117
+		>=sys-apps/util-linux-2.13
+		>=sys-kernel/linux-headers-2.6.19
+		crypt? ( >=sys-fs/cryptsetup-1.0.5 )
+		)
+	kernel_FreeBSD? ( >=dev-libs/libvolume_id-0.77 )
+	x86? ( >=sys-apps/dmidecode-2.7 )
+	selinux? ( sys-libs/libselinux sec-policy/selinux-hal )
+	consolekit? ( sys-auth/consolekit[policykit=] )
+	policykit? (
+		sys-auth/consolekit[policykit]
+		sys-auth/policykit[pam]
+		)"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=dev-util/intltool-0.35
+	doc? (
+		app-text/xmlto
+		dev-libs/libxml2
+		dev-util/gtk-doc
+		app-text/docbook-sgml-utils
+	)"
+PDEPEND=">=app-misc/hal-info-20081219
+	!gnome-extra/hal-device-manager
+	laptop? ( >=sys-power/pm-utils-0.99.3 )"
+
+## HAL Daemon drops privledges so we need group access to read disks
+HALDAEMON_GROUPS_LINUX="haldaemon,plugdev,disk,cdrom,cdrw,floppy,usb"
+HALDAEMON_GROUPS_FREEBSD="haldaemon,plugdev,operator"
+
+function check_hotplug_net() {
+	local CONFIG_CHECK="~HOTPLUG ~NET"
+	local WARNING_HOTPLUG="CONFIG_HOTPLUG:\tis not set (required for HAL)\n"
+	local WARNING_NET="CONFIG_NET:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_inotify() {
+	local CONFIG_CHECK="~INOTIFY_USER"
+	local WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_acpi_proc() {
+	local CONFIG_CHECK="~ACPI_PROCFS ~ACPI_PROC_EVENT"
+	local WARNING_ACPI_PROCFS="CONFIG_ACPI_PROCFS:\tis not set (required for HAL)\n"
+	local WARNING_ACPI_PROC_EVENT="CONFIG_ACPI_PROC_EVENT:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+pkg_setup() {
+	if use kernel_linux ; then
+		if [[ -e "${ROOT}/usr/src/linux/.config" ]] ; then
+			kernel_is ge 2 6 19 || ewarn "HAL requires a kernel version 2.6.19 or newer"
+
+			if kernel_is lt 2 6 23 && use acpi ; then
+				check_acpi_proc
+			fi
+		fi
+
+		check_hotplug_net
+		check_inotify
+	fi
+
+	# http://devmanual.gentoo.org/ebuild-writing/functions/
+	# http://bugs.gentoo.org/show_bug.cgi?id=191605
+
+	# Create groups for hotplugging and HAL
+	enewgroup haldaemon
+	enewgroup plugdev
+
+	# HAL drops priviledges by default now ...
+	# ... so we must make sure it can read disk/cdrom info (ie. be in ${HALDAEMON_GROUPS} groups)
+	if use kernel_linux; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_LINUX}
+	elif use kernel_FreeBSD; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_FREEBSD}
+	fi
+
+	# Make sure that the haldaemon user is in the ${HALDAEMON_GROUPS}
+	# If users have a problem with this, let them file a bug
+	if [[ ${ROOT} == / ]] ; then
+		if use kernel_linux; then
+			usermod -G ${HALDAEMON_GROUPS_LINUX} haldaemon
+		elif use kernel_FreeBSD; then
+			pw usermod haldaemon -G ${HALDAEMON_GROUPS_FREEBSD}
+		fi
+	fi
+}
+
+src_prepare() {
+	# Only apply one of the policy patches.  Bug #267042
+	if use policykit ; then
+		rm "${WORKDIR}/${PATCHNAME}/patches/0001-plugdev-dbus-policy.patch"
+	else
+		rm "${WORKDIR}/${PATCHNAME}/patches/0002-policykit-dbus-policy.patch"
+	fi
+
+	EPATCH_MULTI_MSG="Applying Gentoo Patchset ..." \
+	EPATCH_SUFFIX="patch" \
+	EPATCH_SOURCE="${WORKDIR}/${PATCHNAME}/patches/" \
+	EPATCH_FORCE="yes" \
+	epatch
+
+	eautoreconf
+}
+
+src_configure() {
+	local acpi="$(use_enable acpi)"
+	local backend=
+	local hardware=
+	local consolekit="$(use_enable consolekit console-kit)"
+
+	append-flags -rdynamic
+
+	if use kernel_linux ; then
+		backend="linux"
+	elif use kernel_FreeBSD ; then
+		backend="freebsd"
+	else
+		eerror "Invalid backend"
+	fi
+
+	if use kernel_linux ; then
+		if use acpi ; then
+			# Using IBM ACPI and Toshiba ACPI results in double notification as this
+			# was merged into the Linux Kernel 2.6.22
+			if kernel_is lt 2 6 22 ; then
+				acpi="$acpi --enable-acpi-ibm --enable-acpi-toshiba"
+			else
+				acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			fi
+
+			acpi="$acpi --enable-acpi-proc --enable-acpi-acpid"
+		else
+			acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			acpi="$acpi --disable-acpi-proc --disable-acpi-acpid"
+		fi
+
+		hardware="--with-cpufreq --with-usb-csr --with-keymaps"
+		use arm && hardware="$hardware --with-omap --enable-pmu"
+		use ppc && hardware="$hardware --enable-pmu"
+		if use x86 || use amd64; then
+			hardware="$hardware --with-macbook --with-macbookpro"
+		fi
+
+		if use dell ; then
+			hardware="$hardware --with-dell-backlight"
+		else
+			hardware="$hardware --without-dell-backlight"
+		fi
+
+		hardware="$hardware --enable-sonypic"
+	else
+		hardware="--without-cpufreq --without-usb-csr --without-keymaps"
+		hardware="$hardware --without-omap"
+		hardware="$hardware --without-dell-backlight"
+		hardware="$hardware --enable-acpi-ibm --enable-acpi-toshiba"
+		hardware="$hardware --disable-sonypic"
+	fi
+
+	# Policykit support depends on consolekit support.  Therefore, force on
+	# consolekit, even if it's USE flag is off, if policykit support is on.
+	# This enables packages to USE-depend on hal[policykit?]
+	if use policykit ; then
+		consolekit="--enable-console-kit"
+	fi
+
+	econf --with-backend=${backend} \
+		  --with-os-type=gentoo \
+		  --with-pid-file=/var/run/hald.pid \
+		  --with-hwdata=/usr/share/misc \
+		  --with-socket-dir=/var/run/hald \
+		  --enable-umount-helper \
+		  --enable-man-pages \
+		  --disable-acl-management \
+		  --enable-pci \
+		  $(use_enable apm) \
+		  $(use_enable debug verbose-mode) \
+		  $(use_enable disk-partition parted) \
+		  $(use_enable doc docbook-docs) \
+		  $(use_enable doc gtk-doc) \
+		  $(use_enable policykit policy-kit) \
+		  ${consolekit} \
+		  --docdir=/usr/share/doc/${PF} \
+		  --localstatedir=/var \
+		  ${acpi} ${hardware} \
+	|| die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README || die "docs failed"
+
+	# hal umount for unclean unmounts
+	exeinto /$(get_libdir)/udev/
+	newexe "${FILESDIR}/hal-unmount.dev" hal_unmount || die "udev helper failed"
+
+	# initscript
+	newinitd "${FILESDIR}/0.5.10-hald.rc" hald || die "init script failed"
+
+	# configuration
+	cp "${FILESDIR}/0.5.10-hald.conf" "${WORKDIR}/" || \
+		die "failed to copy hald.conf"
+
+	if use debug; then
+		sed -e 's:HALD_VERBOSE="no":HALD_VERBOSE="yes":' \
+			-i "${WORKDIR}/0.5.10-hald.conf" || die "failed to change verbose"
+	fi
+	newconfd "${WORKDIR}/0.5.10-hald.conf" hald || \
+		die "failed to install hald.conf"
+
+	if use X ; then
+		# New Configuration Snippets
+		dodoc "${WORKDIR}/${PATCHNAME}/config-examples/"*.fdi || \
+			die "dodoc X examples failed"
+	fi
+
+	# We now create and keep /media here as both gnome-mount and pmount
+	# use these directories, to avoid collision.
+	keepdir /media
+
+	# We also need to create and keep /etc/fdi/{information,policy,preprobe}
+	# or else hal bombs.
+	keepdir /etc/hal/fdi/{information,policy,preprobe}
+
+	# HAL stores it's fdi cache in /var/cache/hald
+	keepdir /var/cache/hald
+
+	# HAL keeps its unix socket here
+	keepdir /var/run/hald
+	keepdir /var/lib/hal
+}
+
+pkg_postinst() {
+	# Despite what people keep changing this location. Either one works.. it doesn't matter
+	# http://dev.gentoo.org/~plasmaroo/devmanual/ebuild-writing/functions/
+
+	elog "The HAL daemon needs to be running for certain applications to"
+	elog "work. Suggested is to add the init script to your start-up"
+	elog "scripts, this should be done like this :"
+	elog "\`rc-update add hald default\`"
+	echo
+	elog "Access to hal is not protected by either policykit or the plugdev group."
+	elog "If you have problems discovering/configuring hardware, try adding"
+	elog "yourself to plugdev."
+	echo
+	elog "IF you have additional applications which consume ACPI events, you"
+	elog "should consider installing acpid to allow applications to share ACPI"
+	elog "events."
+	if use X ; then
+		echo
+		elog "If you wish to use a non US layout, you may do so by executing:"
+		elog "setxkbmap <layout> or by utilizing your Desktop Environment's"
+		elog "Keyboard Layout Settings mechanism."
+		elog "Under GNOME, this is gnome-keyboard-properties, and under KDE"
+		elog "it is kxkb."
+	fi
+	echo
+	elog "In order have suspend/hibernate function with HAL or apps that use HAL"
+	elog "(such as gnome-power-manager), you should build HAL with the laptop"
+	elog "useflag which will install pm-utils."
+	if use X ; then
+		echo
+		elog "X Input Hotplugging (if you build xorg-server with the HAL useflag)"
+		elog "reads user specific configuration from /etc/hal/fdi/policy/."
+		echo
+		elog "You should remove the Input sections from your xorg.conf once you have"
+		elog "migrated the rules to a HAL fdi file."
+	fi
+
+	ebeep 5
+	epause 5
+}
diff --git a/sys-apps/hal/hal-0.5.13-r2.ebuild b/sys-apps/hal/hal-0.5.13-r2.ebuild
index df3e067e6765..81e00545d083 100644
--- a/sys-apps/hal/hal-0.5.13-r2.ebuild
+++ b/sys-apps/hal/hal-0.5.13-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.13-r2.ebuild,v 1.2 2009/08/17 11:49:49 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.13-r2.ebuild,v 1.3 2009/09/30 11:59:28 leio Exp $
 
 EAPI="2"
 
@@ -59,8 +59,7 @@ DEPEND="${RDEPEND}
 					dev-libs/libxml2
 					dev-util/gtk-doc
 					app-text/docbook-sgml-utils
-				)
-		!<gnome-extra/gnome-power-manager-2.24.4-r2"
+				)"
 PDEPEND=">=app-misc/hal-info-20081219
 	!gnome-extra/hal-device-manager
 	laptop? ( >=sys-power/pm-utils-0.99.3 )"