Fix sandbox.d config install #333131 by Hans Nieser.

Package-Manager: portage-2.2_rc67/cvs/Linux x86_64

3 files changed, 122 insertions, 6 deletions

diff --git a/sys-apps/sandbox/ChangeLog b/sys-apps/sandbox/ChangeLog
index 4acc6240334f..56aeb24aafe7 100644
--- a/sys-apps/sandbox/ChangeLog
+++ b/sys-apps/sandbox/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/sandbox
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.134 2010/08/17 02:58:30 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.135 2010/08/17 21:02:30 vapier Exp $
+
+*sandbox-2.3-r1 (17 Aug 2010)
+
+  17 Aug 2010; Mike Frysinger <vapier@gentoo.org> +sandbox-2.3-r1.ebuild:
+  Fix sandbox.d config install #333131 by Hans Nieser.
 
 *sandbox-2.3 (17 Aug 2010)
 
diff --git a/sys-apps/sandbox/Manifest b/sys-apps/sandbox/Manifest
index 8a8be649fd29..5ab6761e20cf 100644
--- a/sys-apps/sandbox/Manifest
+++ b/sys-apps/sandbox/Manifest
@@ -21,13 +21,13 @@ EBUILD sandbox-1.2.20_alpha2-r1.ebuild 2638 RMD160 e0b26ffd54aa036168678bac8388a
 EBUILD sandbox-1.6-r2.ebuild 2807 RMD160 34f50316548b2e9d98b5dfb70d99e3e380302672 SHA1 bba36e5a8fa8ea20c1e45febc5aeb56296d12cc9 SHA256 0d9c59cc9c328ad90f1ca93130b7975f09c827f55910a590ff2b2c314661b287
 EBUILD sandbox-2.1.ebuild 2600 RMD160 f68ab24a24a12f492cbf6e1f8b9a5549178ceb04 SHA1 b5b6716ac51f490c47f3829b5485026d9039b782 SHA256 d78c0e1bf2730b699a0c4a1bc20ea87017b93b46de5ca3581778c32d15108f5d
 EBUILD sandbox-2.2.ebuild 2754 RMD160 219e1fb4a49b901bfaad5589007415fdca744e44 SHA1 aaba793b314eeddbde69e804ed6ef9fca7f59f85 SHA256 2cbdebb1603c221cb37348c2bd773f0e059bd18c95f47e1f1ac3fcb48870592f
-EBUILD sandbox-2.3.ebuild 2746 RMD160 3a975b26101dd3175f313476b82565bedd8fa35a SHA1 81ee1093054e565b1b3160e8f4bd8d55d2c879a1 SHA256 df8771967722e54d138bc609a83a82c47088b50d883355ab27698fe3fcccb30d
-MISC ChangeLog 19151 RMD160 ecebe4023bf4b1d31b2964c802e6722192b1e467 SHA1 b0c5e09d4da5122ab678881d9e417ae213da8e51 SHA256 51f736f285fd4c9391d2292e73ed943126f85c4ccceadc50e12bd32910704b15
+EBUILD sandbox-2.3-r1.ebuild 2892 RMD160 e56a27e2c8d21ca247ceb936a2cb412e0e48a266 SHA1 b1b1e6f5858c33f6cc0db3892fd4144db5dadf7a SHA256 dfac7d081fdcc075356f45b83198bc22fbdfa9c34a8583635e54304676577e41
+MISC ChangeLog 19312 RMD160 01e3d2580ed69d887f1bae999a4cc580a504a2d3 SHA1 f9e7b30a3705179f2e86cbe26632748f7c122312 SHA256 58f674c7fe8998548d766fed1a65fb42e5e58395c44e1db7b0ff942c2b640d75
 MISC metadata.xml 337 RMD160 c70000494a436cc0f8256d428f86d42b0fdf6017 SHA1 d81a50fa4047e6c0ecf1ab16e4fa6214895c5e9c SHA256 575b378bf8db5526847e6839a3351ec72769d75ed1c5b392559d57f6e6b4294f
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.16 (GNU/Linux)
 
-iF4EAREIAAYFAkxp+2oACgkQTwhj9JtAlp4bQgD8CocxFJXjL1XzgQ1FYiKvbnP7
-yFdpNHmA+J2dkmIZYRUBAIfOWjOOYaKUYhYNtQjOmE58xWt1dcHIlUmoETumPao1
-=61oF
+iF4EAREIAAYFAkxq+X8ACgkQTwhj9JtAlp6puAD/TW+Oyfmb4DU6n8rmcz3CLdVV
+ZZYKKJjA1zATakG77OgA/3nzFyGqkjO/6TtOb4y9er9yiEvSBMW65D/GVlHpkR0R
+=LRM1
 -----END PGP SIGNATURE-----
diff --git a/sys-apps/sandbox/sandbox-2.3-r1.ebuild b/sys-apps/sandbox/sandbox-2.3-r1.ebuild
new file mode 100644
index 000000000000..a5cf8f136d54
--- /dev/null
+++ b/sys-apps/sandbox/sandbox-2.3-r1.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/sandbox-2.3-r1.ebuild,v 1.1 2010/08/17 21:02:30 vapier Exp $
+
+#
+# don't monkey with this ebuild unless contacting portage devs.
+# period.
+#
+
+inherit eutils flag-o-matic toolchain-funcs multilib
+
+DESCRIPTION="sandbox'd LD_PRELOAD hack"
+HOMEPAGE="http://www.gentoo.org/"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+	http://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh -sparc ~x86 ~sparc-fbsd -x86-fbsd"
+IUSE="multilib"
+
+DEPEND="app-arch/xz-utils
+	>=app-misc/pax-utils-0.1.19" #265376
+RDEPEND=""
+
+EMULTILIB_PKG="true"
+has sandbox_death_notice ${EBUILD_DEATH_HOOKS} || EBUILD_DEATH_HOOKS="${EBUILD_DEATH_HOOKS} sandbox_death_notice"
+
+sandbox_death_notice() {
+	ewarn "If configure failed with a 'cannot run C compiled programs' error, try this:"
+	ewarn "FEATURES=-sandbox emerge sandbox"
+}
+
+sb_get_install_abis() { use multilib && get_install_abis || echo ${ABI:-default} ; }
+
+src_unpack() {
+	unpack ${A}
+	if [[ ! -d ${S} ]] ; then
+		# When upgrading from older version, xz unpack may not work #271543
+		xz -dc "${DISTDIR}/${A}" | tar xf - || die
+	fi
+}
+
+src_compile() {
+	filter-lfs-flags #90228
+
+	local OABI=${ABI}
+	for ABI in $(sb_get_install_abis) ; do
+		mkdir "${WORKDIR}/build-${ABI}"
+		cd "${WORKDIR}/build-${ABI}"
+
+		use multilib && multilib_toolchain_setup ${ABI}
+
+		einfo "Configuring sandbox for ABI=${ABI}..."
+		ECONF_SOURCE="../${P}/" \
+		econf ${myconf} || die
+		einfo "Building sandbox for ABI=${ABI}..."
+		emake || die
+	done
+	ABI=${OABI}
+}
+
+src_test() {
+	local OABI=${ABI}
+	for ABI in $(sb_get_install_abis) ; do
+		cd "${WORKDIR}/build-${ABI}"
+		einfo "Checking sandbox for ABI=${ABI}..."
+		emake check || die "make check failed for ${ABI}"
+	done
+	ABI=${OABI}
+}
+
+src_install() {
+	local OABI=${ABI}
+	for ABI in $(sb_get_install_abis) ; do
+		cd "${WORKDIR}/build-${ABI}"
+		einfo "Installing sandbox for ABI=${ABI}..."
+		emake DESTDIR="${D}" install || die "make install failed for ${ABI}"
+		insinto /etc/sandbox.d #333131
+		doins etc/sandbox.d/00default || die
+	done
+	ABI=${OABI}
+
+	doenvd "${FILESDIR}"/09sandbox
+
+	# fix 00default install #333131
+	rm "${D}"/etc/sandbox.d/*.in || die
+
+	keepdir /var/log/sandbox
+	fowners root:portage /var/log/sandbox
+	fperms 0770 /var/log/sandbox
+
+	cd "${S}"
+	dodoc AUTHORS ChangeLog* NEWS README
+}
+
+pkg_preinst() {
+	chown root:portage "${D}"/var/log/sandbox
+	chmod 0770 "${D}"/var/log/sandbox
+
+	local old=$(find "${ROOT}"/lib* -maxdepth 1 -name 'libsandbox*')
+	if [[ -n ${old} ]] ; then
+		elog "Removing old sandbox libraries for you:"
+		elog ${old//${ROOT}}
+		find "${ROOT}"/lib* -maxdepth 1 -name 'libsandbox*' -exec rm -fv {} \;
+	fi
+}
+
+pkg_postinst() {
+	chmod 0755 "${ROOT}"/etc/sandbox.d #265376
+}