sys-boot/plymouth: Pre 0.9 snapshot ebuild.

Pre 0.9 snapshot ebuild based on latest git sources. It introduces libkms.

EAPI bumped to 4.

Package-Manager: portage-2.1.10.27/cvs/Linux x86_64

1 files changed, 82 insertions, 0 deletions

diff --git a/sys-boot/plymouth/plymouth-0.9_pre20111013.ebuild b/sys-boot/plymouth/plymouth-0.9_pre20111013.ebuild
new file mode 100644
index 000000000000..a6ae170936bc
--- /dev/null
+++ b/sys-boot/plymouth/plymouth-0.9_pre20111013.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/plymouth-0.9_pre20111013.ebuild,v 1.1 2011/10/18 09:57:50 aidecoe Exp $
+
+EAPI=4
+
+inherit autotools-utils
+
+DESCRIPTION="Graphical boot animation (splash) and logger"
+HOMEPAGE="http://cgit.freedesktop.org/plymouth/"
+SRC_URI="
+	http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2
+	http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE_VIDEO_CARDS="video_cards_intel video_cards_nouveau video_cards_radeon"
+IUSE="${IUSE_VIDEO_CARDS} gdm +libkms +openrc +pango static-libs"
+
+CDEPEND=">=media-libs/libpng-1.2.16
+	>=x11-libs/gtk+-2.12:2
+	pango? ( >=x11-libs/pango-1.21 )
+	video_cards_intel? ( x11-libs/libdrm[video_cards_intel] )
+	video_cards_nouveau? ( x11-libs/libdrm[video_cards_nouveau] )
+	video_cards_radeon? ( x11-libs/libdrm[video_cards_radeon] )
+	"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig
+	"
+RDEPEND="${CDEPEND}
+	>=sys-kernel/dracut-008-r1[dracut_modules_plymouth]
+	openrc? ( sys-boot/plymouth-openrc-plugin )
+	"
+
+DOCS=(AUTHORS README TODO)
+PATCHES=(
+	"${FILESDIR}"/${PV}-gentoo-fb-path.patch
+	)
+
+src_prepare() {
+	autotools-utils_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-system-root-install
+		$(use_enable libkms)
+		$(use_enable pango)
+		$(use_enable gdm gdm-transition)
+		$(use_enable video_cards_intel libdrm_intel)
+		$(use_enable video_cards_nouveau libdrm_nouveau)
+		$(use_enable video_cards_radeon libdrm_radeon)
+		)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	if use static-libs; then
+		mv "${D}/$(get_libdir)"/libply{,-splash-core}.{a,la} \
+			"${D}/usr/$(get_libdir)"/ || die 'mv *.{a,la} files failed'
+		gen_usr_ldscript libply.so libply-splash-core.so
+	else
+		einfo "Removing /usr/$(get_libdir)/plymouth/*.la"
+		rm "${D}/usr/$(get_libdir)"/plymouth/{*.la,renderers/*.la} \
+			|| die 'rm *.la'
+	fi
+
+	insinto /usr/share/plymouth
+	newins "${DISTDIR}"/gentoo-logo.png bizcom.png
+}
+
+pkg_postinst() {
+	elog "Follow instructions on"
+	elog ""
+	elog "  http://dev.gentoo.org/~aidecoe/doc/en/plymouth.xml"
+	elog ""
+	elog "to set up Plymouth."
+}