Version bump #133181 by Conrad Kostecki.

Package-Manager: portage-2.1_pre10-r5

1 files changed, 49 insertions, 0 deletions

diff --git a/sys-fs/device-mapper/device-mapper-1.02.07.ebuild b/sys-fs/device-mapper/device-mapper-1.02.07.ebuild
new file mode 100644
index 000000000000..57d876b172c2
--- /dev/null
+++ b/sys-fs/device-mapper/device-mapper-1.02.07.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/device-mapper/device-mapper-1.02.07.ebuild,v 1.1 2006/05/13 15:20:05 vapier Exp $
+
+inherit eutils multilib
+
+DESCRIPTION="Device mapper ioctl library for use with LVM2 utilities"
+HOMEPAGE="http://sources.redhat.com/dm/"
+SRC_URI="ftp://sources.redhat.com/pub/dm/${PN}.${PV}.tgz
+	ftp://sources.redhat.com/pub/dm/old/${PN}.${PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="selinux"
+
+DEPEND="selinux? ( sys-libs/libselinux )"
+
+S=${WORKDIR}/${PN}.${PV}
+
+src_compile() {
+	econf --sbindir=/sbin $(use_enable selinux) || die "econf failed"
+	emake || die "compile problem"
+}
+
+src_install() {
+	make install DESTDIR="${D}" || die
+
+	# move shared libs to /
+	mv "${D}"/usr/$(get_libdir) "${D}"/ || die "move libdir"
+	dolib.a lib/ioctl/libdevmapper.a || die "dolib.a"
+	gen_usr_ldscript libdevmapper.so
+
+	insinto /etc
+	doins "${FILESDIR}"/dmtab
+	insinto /lib/rcscripts/addons
+	doins "${FILESDIR}"/dm-start.sh
+
+	dodoc INSTALL INTRO README VERSION WHATS_NEW
+}
+
+pkg_preinst() {
+	local l=${ROOT}/$(get_libdir)/libdevmapper.so.1.01
+	[[ -e ${l} ]] && cp "${l}" "${D}"/$(get_libdir)/
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /$(get_libdir)/libdevmapper.so.1.01
+}