Prepare for stabilization. 7.0.517.41 has been promoted to the stable channel.

Package-Manager: portage-2.1.8.3/cvs/Linux i686

4 files changed, 233 insertions, 5 deletions

diff --git a/www-client/chromium/ChangeLog b/www-client/chromium/ChangeLog
index 52637b9412ee..408605511f76 100644
--- a/www-client/chromium/ChangeLog
+++ b/www-client/chromium/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.203 2010/10/15 07:45:03 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.204 2010/10/19 19:23:35 phajdan.jr Exp $
+
+*chromium-7.0.517.41-r1 (19 Oct 2010)
+
+  19 Oct 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  chromium-7.0.517.41.ebuild, +chromium-7.0.517.41-r1.ebuild:
+  Prepare for stabilization. 7.0.517.41 has been promoted to the stable
+  channel.
 
   15 Oct 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   chromium-8.0.552.0.ebuild, chromium-9999.ebuild:
diff --git a/www-client/chromium/Manifest b/www-client/chromium/Manifest
index 91c6b2b921a9..90df57c9bb34 100644
--- a/www-client/chromium/Manifest
+++ b/www-client/chromium/Manifest
@@ -17,10 +17,11 @@ DIST chromium-8.0.552.0.tar.bz2 134766822 RMD160 ab65406596ea0d04547c41e9212497d
 EBUILD chromium-6.0.472.62.ebuild 6869 RMD160 4f789a1c899d639aed4f69a831dcd932ec690903 SHA1 07c983a01ba282fe0f9684c3a264de81e4623a16 SHA256 14d395f2840efe6d81b5f4225284af9084087c4ac429fcdbb0ddd05a3a0f9ffd
 EBUILD chromium-6.0.472.63.ebuild 6875 RMD160 868088280a7e82a3016c6feee15c61ea8e4b3237 SHA1 9f2a03a0592b51530595f35f24eea41b48a3a275 SHA256 54b9433c933f4faa90e1057baa29dd461e639931d2cacdb963996ed28f7e995c
 EBUILD chromium-7.0.517.36.ebuild 6611 RMD160 11af550adfeb2e2dab6fb5ee2247bf52458ed43c SHA1 72a8bb8d6dd74de4290c3d08d4f0908969694f04 SHA256 dd32a37a19a669afcb5a669405aa004e92a20d5db8b09cd0aac0efac090adbe5
-EBUILD chromium-7.0.517.41.ebuild 6611 RMD160 7d0dbb4f233dfd444550150e8b2ff45e460a074d SHA1 e660e2b9864231e56156f84f6073a2a6341f41b0 SHA256 48d78915a358304a4ab636ddac88de237d54e0ce2781ada05eb5cfd482839c6e
+EBUILD chromium-7.0.517.41-r1.ebuild 6614 RMD160 2f5c691328c33965cdbfc257c8be5a98cbaf1903 SHA1 e8a10b032b98c4119c1a2b08c5dfe372535cc497 SHA256 d63ef76dc46a3881582a17f13db9ba8a3df598683bdc18ece3b70abfc3dcf31d
+EBUILD chromium-7.0.517.41.ebuild 6612 RMD160 f8e75a9102f47c203fabe392e1e1bbce21eb4d80 SHA1 1933bba6b2be0c8465daa991b7be176b695c233a SHA256 39c6a44870d8d2e151320898d99258028984f7f1fd92fb309b15c705fe92e7e8
 EBUILD chromium-7.0.544.0-r2.ebuild 7600 RMD160 4e30b02693752b828e51ac1783c45b3fd4a366b1 SHA1 e119fc2bc5c11e94ffd272fab5ba034c06940b45 SHA256 f888cf80d72f1e08a48400a157d94ada91444b2427dd9a19f298c764899b5aec
 EBUILD chromium-8.0.552.0.ebuild 7529 RMD160 5fad47e8467adc0ff6670e335ccbf0d261086d75 SHA1 18f88c73f58f32c559afa6973bd6d36c31250189 SHA256 2236e24fb34e090e960edffe0bceac5373caeff607eded5b92dd1bf7eef71b9c
 EBUILD chromium-9999.ebuild 9237 RMD160 76903caf5b2038704282d80fdb5644752c2c5349 SHA1 eebfde64ac34592e502a097b5bc33de684694109 SHA256 8f8648bb1c5890896043e36fddee75ebf4377e94f61d00e330b747e708e41a9d
-MISC ChangeLog 44903 RMD160 ea7d82959feb35f152d6dad0eb2db732e721631a SHA1 9f2c1d8b369ac75b94a4b16ea2b1e6daef66a0d3 SHA256 27ed8b353f266739686330fb091767b9400610ef368b9c435e4ecb3e26fd1120
+MISC ChangeLog 45143 RMD160 1cac0e5ebe51d44466722d0da053756823471ded SHA1 ecc0ef412038a2b53c21ace8130b22a3e14c5da9 SHA256 3fed2cde83817df02608eb57e28429c7692eb834a7f9f6a7a06973c8fa789382
 MISC chromium-9999.ebuild.orig 9139 RMD160 001ff2d49c84968243c4ca33c82fdac6eb3af83f SHA1 08cd6b5fa2b7f8ed96b40c947f3937fdfc6c992a SHA256 2e89a70b8d4821905d61fbe0d7bed64d15c758d6bce8d87434c30b2f592af532
 MISC metadata.xml 516 RMD160 55abec043e516fad54cc6c9f5aff0d1ac6aba738 SHA1 9cb50bcd2f1e7f0dc6e257fcab3b24f0f0f90f0c SHA256 b2f497aa9d3ab3deb4cbd25eedc3037df449349a3506f1af7e3de9730c522b8b
diff --git a/www-client/chromium/chromium-7.0.517.41-r1.ebuild b/www-client/chromium/chromium-7.0.517.41-r1.ebuild
new file mode 100644
index 000000000000..30e125bf50f3
--- /dev/null
+++ b/www-client/chromium/chromium-7.0.517.41-r1.ebuild
@@ -0,0 +1,220 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.517.41-r1.ebuild,v 1.1 2010/10/19 19:23:35 phajdan.jr Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
+
+DESCRIPTION="Open-source version of Google Chrome web browser"
+HOMEPAGE="http://chromium.org/"
+SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cups gnome gnome-keyring"
+
+RDEPEND="app-arch/bzip2
+	>=dev-libs/icu-4.4.1
+	>=dev-libs/libevent-1.4.13
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-libs/nss-3.12.3
+	>=gnome-base/gconf-2.24.0
+	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
+	>=media-libs/alsa-lib-1.0.19
+	media-libs/jpeg:0
+	media-libs/libpng
+	cups? ( >=net-print/cups-1.4.4 )
+	sys-libs/zlib
+	>=x11-libs/gtk+-2.14.7
+	x11-libs/libXScrnSaver"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	>=dev-util/gperf-3.0.3
+	>=dev-util/pkgconfig-0.23
+	sys-devel/flex"
+RDEPEND+="
+	|| (
+		x11-themes/gnome-icon-theme
+		x11-themes/oxygen-molecule
+		x11-themes/tango-icon-theme
+		x11-themes/xfce4-icon-theme
+	)
+	x11-apps/xmessage
+	x11-misc/xdg-utils
+	virtual/ttf-fonts"
+
+remove_bundled_lib() {
+	einfo "Removing bundled library $1 ..."
+	local out
+	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
+		|| die "failed to remove bundled library $1"
+	if [[ -z $out ]]; then
+		die "no files matched when removing bundled library $1"
+	fi
+}
+
+pkg_setup() {
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
+}
+
+src_prepare() {
+	# Add Gentoo plugin paths.
+	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
+
+	# Make compile-time dependency on gnome-keyring optional, bug #332411.
+	epatch "${FILESDIR}"/${PN}-gnome-keyring-r0.patch
+
+	remove_bundled_lib "third_party/bzip2"
+	remove_bundled_lib "third_party/codesighs"
+	remove_bundled_lib "third_party/cros"
+	remove_bundled_lib "third_party/icu"
+	remove_bundled_lib "third_party/jemalloc"
+	remove_bundled_lib "third_party/lcov"
+	remove_bundled_lib "third_party/libevent"
+	remove_bundled_lib "third_party/libjpeg"
+	remove_bundled_lib "third_party/libpng"
+	remove_bundled_lib "third_party/libxml"
+	remove_bundled_lib "third_party/libxslt"
+	remove_bundled_lib "third_party/lzma_sdk"
+	remove_bundled_lib "third_party/molokocacao"
+	remove_bundled_lib "third_party/ocmock"
+	remove_bundled_lib "third_party/pyftpdlib"
+	remove_bundled_lib "third_party/simplejson"
+	remove_bundled_lib "third_party/tlslite"
+	# TODO: also remove third_party/zlib. For now the compilation fails if we
+	# remove it (minizip-related).
+}
+
+src_configure() {
+	local myconf=""
+
+	# Never tell the build system to "enable" SSE2, it has a few unexpected
+	# additions, bug #336871.
+	myconf+=" -Ddisable_sse2=1"
+
+	# Use system-provided libraries.
+	# TODO: use_system_ffmpeg (http://crbug.com/50678).
+	# TODO: use_system_sqlite (http://crbug.com/22208).
+	# TODO: use_system_hunspell (upstream changes needed).
+	# TODO: use_system_ssl when we have a recent enough system NSS.
+	myconf+="
+		-Duse_system_bzip2=1
+		-Duse_system_icu=1
+		-Duse_system_libevent=1
+		-Duse_system_libjpeg=1
+		-Duse_system_libpng=1
+		-Duse_system_libxml=1
+		-Duse_system_zlib=1"
+
+	# The dependency on cups is optional, see bug #324105.
+	if use cups; then
+		myconf+=" -Duse_cups=1"
+	else
+		myconf+=" -Duse_cups=0"
+	fi
+
+	if use "gnome-keyring"; then
+		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
+	else
+		# TODO: we should also disable code trying to dlopen
+		# gnome-keyring in that case.
+		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
+	fi
+
+	# Enable sandbox.
+	myconf+="
+		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
+
+	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
+	# and the performance gain isn't worth it.
+	myconf+=" -Dv8_use_snapshot=0"
+
+	# Disable tcmalloc memory allocator. It causes problems,
+	# for example bug #320419.
+	myconf+=" -Dlinux_use_tcmalloc=0"
+
+	# Use target arch detection logic from bug #296917.
+	local myarch="$ABI"
+	[[ $myarch = "" ]] && myarch="$ARCH"
+
+	if [[ $myarch = amd64 ]] ; then
+		myconf+=" -Dtarget_arch=x64"
+	elif [[ $myarch = x86 ]] ; then
+		myconf+=" -Dtarget_arch=ia32"
+	elif [[ $myarch = arm ]] ; then
+		# TODO: check this again after
+		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
+		append-flags -fno-tree-sink
+
+		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
+	else
+		die "Failed to determine target arch, got '$myarch'."
+	fi
+
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
+		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
+	fi
+
+	# Work around a likely GCC bug, see bug #331945.
+	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
+		append-flags -fno-ipa-cp
+	fi
+
+	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
+	# Depending on GCC version the warnings are different and we don't want
+	# the build to fail because of that.
+	myconf+=" -Dwerror="
+
+	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die
+}
+
+src_compile() {
+	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)" \
+		|| die
+}
+
+src_install() {
+	exeinto "${CHROMIUM_HOME}"
+	pax-mark m out/Release/chrome
+	doexe out/Release/chrome
+	doexe out/Release/chrome_sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
+	doexe out/Release/xdg-settings || die
+	doexe "${FILESDIR}"/chromium-launcher.sh || die
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/chrome.pak || die
+	doins out/Release/resources.pak || die
+
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
+
+	# chrome.1 is for chromium --help
+	newman out/Release/chrome.1 chrome.1 || die
+	newman out/Release/chrome.1 chromium.1 || die
+
+	doexe out/Release/ffmpegsumo_nolink || die
+	doexe out/Release/libffmpegsumo.so || die
+
+	# Install icon and desktop entry.
+	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
+	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
+		"MimeType=text/html;text/xml;application/xhtml+xml;"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
+
+	# Install GNOME default application entry (bug #303100).
+	if use gnome; then
+		dodir /usr/share/gnome-control-center/default-apps || die
+		insinto /usr/share/gnome-control-center/default-apps
+		doins "${FILESDIR}"/chromium.xml || die
+	fi
+}
diff --git a/www-client/chromium/chromium-7.0.517.41.ebuild b/www-client/chromium/chromium-7.0.517.41.ebuild
index 084468dbb2e0..852a2b8780cd 100644
--- a/www-client/chromium/chromium-7.0.517.41.ebuild
+++ b/www-client/chromium/chromium-7.0.517.41.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.517.41.ebuild,v 1.1 2010/10/14 08:07:08 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.517.41.ebuild,v 1.2 2010/10/19 19:23:35 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -26,7 +26,7 @@ RDEPEND="app-arch/bzip2
 	>=media-libs/alsa-lib-1.0.19
 	media-libs/jpeg:0
 	media-libs/libpng
-	cups? ( >=net-print/cups-1.4.4 )
+	cups? ( >=net-print/cups-1.3.11 )
 	sys-libs/zlib
 	>=x11-libs/gtk+-2.14.7
 	x11-libs/libXScrnSaver"