1 files changed, 52 insertions, 0 deletions
diff --git a/net-misc/dibbler/dibbler-0.8.3.ebuild b/net-misc/dibbler/dibbler-0.8.3.ebuild
new file mode 100644
index 000000000000..6e418525b5cc
--- /dev/null
+++ b/net-misc/dibbler/dibbler-0.8.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dibbler/dibbler-0.8.3.ebuild,v 1.1 2013/04/05 13:59:31 pinkbyte Exp $
+
+EAPI="5"
+
+inherit eutils readme.gentoo
+
+DESCRIPTION="Portable DHCPv6 implementation (server, client and relay)"
+HOMEPAGE="http://klub.com.pl/dhcpv6/"
+SRC_URI="http://klub.com.pl/dhcpv6/dibbler/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~mips ~x86"
+IUSE="doc"
+
+DEPEND="doc? (
+		dev-texlive/texlive-latex
+		dev-tex/floatflt
+	)"
+RDEPEND=""
+
+DOC_CONTENTS="Make sure that you modify client.conf, server.conf and/or relay.conf
+to suit your needs. They are stored in /etc/dibbler"
+
+src_prepare() {
+	epatch_user
+}
+
+src_compile() {
+	emake
+	# devel documentation is broken and users should consult the online version
+	# http://klub.com.pl/dhcpv6/doxygen/
+	use doc && emake -C doc/ user
+}
+
+src_install() {
+	readme.gentoo_create_doc
+
+	dosbin dibbler-{client,relay,server}
+	doman doc/man/*.8
+
+	insinto /etc/dibbler
+	doins doc/examples/*.conf
+	dodir /var/lib/dibbler
+
+	dodoc AUTHORS CHANGELOG RELNOTES TODO
+	use doc && dodoc doc/dibbler-user.pdf
+
+	doinitd "${FILESDIR}"/dibbler-{client,relay,server}
+}