1 files changed, 107 insertions, 0 deletions
diff --git a/x11-libs/cairo/cairo-1.8.8-r1.ebuild b/x11-libs/cairo/cairo-1.8.8-r1.ebuild
new file mode 100644
index 000000000000..6f9b5b4c3cb3
--- /dev/null
+++ b/x11-libs/cairo/cairo-1.8.8-r1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.8.8-r1.ebuild,v 1.1 2010/03/26 22:34:15 spatz Exp $
+
+EAPI=2
+
+inherit eutils flag-o-matic autotools
+
+DESCRIPTION="A vector graphics library with cross-device output support"
+HOMEPAGE="http://cairographics.org/"
+SRC_URI="http://cairographics.org/releases/${P}.tar.gz
+	mirror://gentoo/${PN}-1.8-lcd_filter.patch.bz2"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="aqua cleartype debug directfb doc glitz lcdfilter opengl +svg X xcb"
+
+# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
+RESTRICT="test"
+
+RDEPEND="media-libs/fontconfig
+	>=media-libs/freetype-2.1.9
+	sys-libs/zlib
+	media-libs/libpng
+	>=x11-libs/pixman-0.12.0
+	directfb? ( >=dev-libs/DirectFB-0.9.24 )
+	glitz? ( >=media-libs/glitz-0.5.1 )
+	svg? ( dev-libs/libxml2 )
+	X? ( 	>=x11-libs/libXrender-0.6
+		x11-libs/libXext
+		x11-libs/libX11
+		x11-libs/libXft )
+	xcb? (	>=x11-libs/libxcb-0.92
+		x11-libs/xcb-util )"
+#	test? (
+#	pdf test
+#	x11-libs/pango
+#	>=x11-libs/gtk+-2.0
+#	>=app-text/poppler-bindings-0.9.2[gtk]
+#	ps test
+#	app-text/ghostscript-gpl
+#	svg test
+#	>=x11-libs/gtk+-2.0
+#	>=gnome-base/librsvg-2.15.0
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.19
+	>=sys-devel/libtool-2
+	doc? (	>=dev-util/gtk-doc-1.6
+		~app-text/docbook-xml-dtd-4.2 )
+	X? ( x11-proto/renderproto )"
+
+src_prepare() {
+	if use lcdfilter; then
+		# LCD filter patch from Ubuntu, taken from:
+		# http://bazaar.launchpad.net/%7Eubuntu-branches/ubuntu/lucid/cairo/lucid/files/head%3A/debian/patches/
+		epatch "${WORKDIR}"/${PN}-1.8-lcd_filter.patch
+	elif use cleartype; then
+		# ClearType-like patches applied by ArchLinux
+		epatch "${FILESDIR}"/${PN}-1.2.4-lcd-cleartype-like.diff
+	fi
+
+	epatch "${FILESDIR}"/${P}-interix.patch \
+		"${FILESDIR}"/${P}-libpng14.patch
+
+	# We need to run elibtoolize to ensure correct so versioning on FreeBSD
+	# upgraded to an eautoreconf for the above interix patch.
+	eautoreconf
+}
+
+src_configure() {
+	[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
+	# http://bugs.freedesktop.org/show_bug.cgi?id=15463
+	[[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
+
+	#gets rid of fbmmx.c inlining warnings
+	append-flags -finline-limit=1200
+
+	if use glitz && use opengl; then
+		export glitz_LIBS=$(pkg-config --libs glitz-glx)
+	fi
+
+	econf $(use_enable X xlib) $(use_enable doc gtk-doc) \
+		$(use_enable directfb) $(use_enable xcb) \
+		$(use_enable svg) $(use_enable glitz) $(use_enable X xlib-xrender) \
+		$(use_enable debug test-surfaces) --enable-pdf  --enable-png \
+		--enable-ft --enable-ps \
+		$(use_enable aqua quartz) $(use_enable aqua quartz-image) \
+		|| die "configure failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "Installation failed"
+	dodoc AUTHORS ChangeLog NEWS README
+}
+
+pkg_postinst() {
+	if use xcb; then
+		ewarn "You have enabled the Cairo XCB backend which is used only by"
+		ewarn "a select few apps. The Cairo XCB backend is presently"
+		ewarn "un-maintained and needs a lot of work to get it caught up"
+		ewarn "to the Xrender and Xlib backends, which are the backends used"
+		ewarn "by most applications. See:"
+		ewarn "http://lists.freedesktop.org/archives/xcb/2008-December/004139.html"
+	fi
+}