blob: 584209f7ef850caebd2cdc596774012c69a8aa1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/vice-2.2.ebuild,v 1.2 2010/03/23 23:58:01 ssuominen Exp $
EAPI=2
inherit autotools eutils games
DESCRIPTION="The Versatile Commodore 8-bit Emulator"
HOMEPAGE="http://vice-emu.sourceforge.net/"
SRC_URI="http://www.zimmers.net/anonftp/pub/cbm/crossplatform/emulators/VICE/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="Xaw3d alsa gnome nls png readline sdl ipv6 memmap ethernet oss zlib X gif jpeg xv dga xrandr ffmpeg lame pulseaudio"
RDEPEND="
x11-libs/libX11
x11-libs/libXext
x11-libs/libXpm
x11-libs/libICE
x11-libs/libSM
x11-libs/libXt
x11-libs/libXxf86vm
x11-apps/xset
Xaw3d? ( x11-libs/Xaw3d )
!Xaw3d? ( !gnome? ( x11-libs/libXaw ) )
alsa? ( media-libs/alsa-lib )
gnome? (
x11-libs/gtk+:2
dev-libs/atk
x11-libs/pango
)
lame? ( media-sound/lame )
ffmpeg? ( >=media-video/ffmpeg-0.5_p20373 )
ethernet? (
>=net-libs/libpcap-0.9.8
>=net-libs/libnet-1.1.2.1
)
nls? ( virtual/libintl )
png? ( media-libs/libpng )
readline? ( sys-libs/readline )
sdl? ( media-libs/libsdl )
gif? ( media-libs/giflib )
jpeg? ( media-libs/jpeg:0 )
xv? ( x11-libs/libXv )
dga? ( x11-libs/libXxf86dga )
xrandr? ( x11-libs/libXrandr )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
x11-apps/bdftopcf
x11-apps/mkfontdir
x11-proto/xproto
x11-proto/xf86vidmodeproto
x11-proto/xextproto
dga? ( x11-proto/xf86dgaproto )
xv? ( x11-proto/videoproto )
nls? ( sys-devel/gettext )"
src_prepare() {
epatch "${FILESDIR}"/${P}-xshm.patch
sed -i \
-e "s:/usr/local/lib/VICE:${GAMES_DATADIR}/${PN}:" \
man/vice.1 \
$(grep -rl /usr/local/lib doc) \
|| die "sed failed"
sed -i \
-e 's:png_check_sig:png_sig_cmp:g' \
-e "/VICEDIR=/s:=.*:=\"${GAMES_DATADIR}/${PN}\";:" \
configure.in \
|| die "sed failed"
AT_NO_RECURSIVE=1 eautoreconf
}
src_configure() {
# don't try to actually run fc-cache (bug #280976)
FCCACHE=/bin/true \
PKG_CONFIG=pkg-config \
egamesconf \
--disable-dependency-tracking \
--enable-fullscreen \
--enable-parsid \
--with-resid \
--without-arts \
--without-esd \
--without-midas \
$(use_enable ffmpeg) \
$(use_enable lame) \
$(use_enable gnome gnomeui) \
$(use_enable nls) \
$(use_with Xaw3d xaw3d) \
$(use_with alsa) \
$(use_with pulseaudio pulse) \
$(use_with png) \
$(use_with readline) \
$(use_with sdl sdlsound) \
$(use_enable ipv6) \
$(use_enable oss) \
$(use_enable memmap) \
$(use_enable ethernet) \
$(use_with zlib) \
$(use_with X x)
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
dodoc AUTHORS ChangeLog FEEDBACK README
prepgamesdirs
}
|
GitWeb