blob: b38db06a919993a483ceaa90c5a6f8b1eb81aa41 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.13-r1.ebuild,v 1.14 2009/11/14 07:55:24 mr_bones_ Exp $
EAPI=2
inherit flag-o-matic toolchain-funcs eutils libtool
DESCRIPTION="Simple Direct Media Layer"
HOMEPAGE="http://www.libsdl.org/"
SRC_URI="http://www.libsdl.org/release/SDL-${PV}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
# WARNING:
# if you disable the audio, video, joystick use flags or turn on the custom-cflags use flag
# in USE and something breaks, you pick up the pieces. Be prepared for
# bug reports to be marked INVALID.
IUSE="oss alsa esd nas X dga xv xinerama fbcon directfb ggi svga tslib aalib opengl libcaca +audio +video +joystick custom-cflags pulseaudio"
RDEPEND="audio? ( >=media-libs/audiofile-0.1.9 )
alsa? ( media-libs/alsa-lib )
esd? ( >=media-sound/esound-0.2.19 )
nas? (
media-libs/nas
x11-libs/libXt
x11-libs/libXext
x11-libs/libX11
)
X? (
x11-libs/libXt
x11-libs/libXext
x11-libs/libX11
x11-libs/libXrandr
)
directfb? ( >=dev-libs/DirectFB-0.9.19 )
ggi? ( >=media-libs/libggi-2.0_beta3 )
svga? ( >=media-libs/svgalib-1.4.2 )
aalib? ( media-libs/aalib )
libcaca? ( >=media-libs/libcaca-0.9-r1 )
opengl? ( virtual/opengl virtual/glu )
tslib? ( x11-libs/tslib )
pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
nas? (
x11-proto/xextproto
x11-proto/xproto
)
X? (
x11-proto/xextproto
x11-proto/xproto
)
x86? ( || ( >=dev-lang/yasm-0.6.0 >=dev-lang/nasm-0.98.39-r3 ) )"
S=${WORKDIR}/SDL-${PV}
pkg_setup() {
if use !audio || use !video || use !joystick ; then
ewarn "Since you've chosen to turn off some of libsdl's functionality,"
ewarn "don't bother filing libsdl-related bugs until trying to remerge"
ewarn "libsdl with the audio, video, and joystick flags in USE."
ewarn "You need to know what you're doing to selectively turn off parts of libsdl."
epause 30
fi
if use custom-cflags ; then
ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
ewarn "don't bother filing libsdl-related bugs until trying to remerge"
ewarn "libsdl without the custom-cflags use flag in USE."
epause 10
fi
}
src_prepare() {
# patches for bugs #40224 #145917 #198147 #217097
epatch \
"${FILESDIR}"/${P}-libcaca-new-api.patch \
"${FILESDIR}"/${P}-sdl-config.patch \
"${FILESDIR}"/${P}-xinerama-head-0.patch \
"${FILESDIR}"/${P}-pulseaudio.patch \
"${FILESDIR}"/${P}-cld.patch
./autogen.sh
elibtoolize
}
src_configure() {
local myconf=
if [[ $(tc-arch) != "x86" ]] ; then
myconf="${myconf} --disable-nasm"
else
myconf="${myconf} --enable-nasm"
fi
use custom-cflags || strip-flags
use audio || myconf="${myconf} --disable-audio"
use video \
&& myconf="${myconf} --enable-video-dummy" \
|| myconf="${myconf} --disable-video"
use joystick || myconf="${myconf} --disable-joystick"
local directfbconf="--disable-video-directfb"
if use directfb ; then
# since DirectFB can link against SDL and trigger a
# dependency loop, only link against DirectFB if it
# isn't broken #61592
echo 'int main(){}' > directfb-test.c
$(tc-getCC) directfb-test.c -ldirectfb 2>/dev/null \
&& directfbconf="--enable-video-directfb" \
|| ewarn "Disabling DirectFB since libdirectfb.so is broken"
fi
myconf="${myconf} ${directfbconf}"
econf \
--disable-rpath \
--enable-events \
--enable-cdrom \
--enable-threads \
--enable-timers \
--enable-file \
--enable-cpuinfo \
$(use_enable oss) \
$(use_enable alsa) \
$(use_enable esd) \
$(use_enable pulseaudio) \
--disable-arts \
$(use_enable nas) \
$(use_enable X video-x11) \
$(use_enable dga) \
$(use_enable xv video-x11-xv) \
$(use_enable xinerama video-x11-xinerama) \
$(use_enable X video-x11-xrandr) \
$(use_enable dga video-dga) \
$(use_enable fbcon video-fbcon) \
$(use_enable ggi video-ggi) \
$(use_enable svga video-svga) \
$(use_enable aalib video-aalib) \
$(use_enable libcaca video-caca) \
$(use_enable opengl video-opengl) \
$(use_enable tslib input-tslib) \
$(use_with X x) \
--disable-video-x11-xme \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
dodoc BUGS CREDITS README README-SDL.txt README.CVS TODO WhatsNew
dohtml -r ./
}
|
GitWeb