blob: ebe4a910abf8aa8f81fad747f34e51f37f37cb30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/cernlib/cernlib-2006-r5.ebuild,v 1.3 2015/05/27 14:52:33 bircoph Exp $
EAPI=5
inherit eutils fortran-2 multilib toolchain-funcs
DEB_PN=cernlib
DEB_PV=20061220+dfsg3
DEB_PR=2
DEB_P=${DEB_PN}_${DEB_PV}
DESCRIPTION="CERN program library for High Energy Physics"
HOMEPAGE="https://cernlib.web.cern.ch/cernlib/"
SRC_URI="
mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}.orig.tar.gz
mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}-${DEB_PR}.debian.tar.gz"
SLOT="0"
LICENSE="GPL-2 LGPL-2 BSD"
KEYWORDS="~amd64 ~hppa ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE=""
RDEPEND="
x11-libs/motif:0
virtual/lapack
dev-lang/cfortran"
DEPEND="${RDEPEND}
x11-misc/imake
x11-misc/makedepend
virtual/pkgconfig"
S="${WORKDIR}/${DEB_PN}-${DEB_PV}"
src_prepare() {
mv ../debian . || die
epatch "${FILESDIR}"/${P}-nogfortran.patch
# set some default paths
sed -i \
-e "s:/usr/local:${EROOT}/usr:g" \
-e "s:prefix)/lib:prefix)/$(get_libdir):" \
-e "s:\$(prefix)/etc:${EROOT}/etc:" \
-e 's:$(prefix)/man:$(prefix)/share/man:' \
debian/add-ons/cernlib.mk || die "sed failed"
# use system blas and lapack set by gentoo framework
sed -i \
-e "s:\$DEPS -lm:$($(tc-getPKG_CONFIG) --libs blas):" \
-e "s:\$DEPS -llapack -lm:$($(tc-getPKG_CONFIG) --libs lapack):" \
-e 's:`depend $d $a blas`::' \
-e 's:X11R6:X11:g' \
debian/add-ons/bin/cernlib.in || die "sed failed"
cp debian/add-ons/Makefile .
export DEB_BUILD_OPTIONS="$(tc-getFC) nostrip nocheck"
einfo "Applying Debian patches"
emake -j1 patch
epatch "${FILESDIR}"/${P}-fgets.patch
epatch "${FILESDIR}"/${P}-ypatchy-short-name.patch
# since we depend on cfortran, do not use the one from cernlib
rm src/include/cfortran/cfortran.h || die
# respect users flags
sed -i \
-e 's/-O3/-O2/g' \
-e "s/-O2/${CFLAGS}/g" \
-e "s|\(CcCmd[[:space:]]*\)gcc|\1$(tc-getCC)|g" \
-e "s|\(CplusplusCmd[[:space:]]*\)g++|\1$(tc-getCXX)|g" \
-e "s|\(FortranCmd[[:space:]]*\)gfortran|\1$(tc-getFC)|g" \
src/config/linux.cf \
|| die "sed linux.cf failed"
sed -i \
-e "s|\(ArCmdBase[[:space:]]*\)ar|\1$(tc-getAR)|g" \
-e "s|\(RanlibCmd[[:space:]]*\)ranlib|\1$(tc-getRANLIB)|g" \
src/config/Imake.tmpl \
|| die "sed Imake.tmpl failed"
sed -i \
-e 's/\$(FCLINK)/\$(FCLINK) $(LDFLAGS)/' \
-e 's/\$(CCLINK)/\$(CCLINK) $(LDFLAGS)/' \
src/config/{biglib,fortran,Imake}.rules \
src/patchy/Imakefile \
|| die "sed for ldflags propagation failed"
# add missing headers for implicit
sed -i \
-e '0,/^#include/i#include <stdlib.h>' \
src/kernlib/kerngen/ccgen*/*.c || die
}
src_compile() {
# parallel make breaks and complex patched imake system, hard to debug
emake -j1 cernlib-indep cernlib-arch
}
src_test() {
LD_LIBRARY_PATH="${S}"/shlib emake -j1 cernlib-test
}
src_install() {
default
cd debian
dodoc changelog README.* deadpool.txt NEWS copyright
newdoc add-ons/README README.add-ons
}
|
GitWeb