sys-process/dcron/dcron-3.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/dcron/dcron-3.2.ebuild,v 1.11 2007/06/07 00:06:22 vapier Exp $

inherit cron toolchain-funcs

DESCRIPTION="A cute little cron from Matt Dillon"
HOMEPAGE="http://apollo.backplane.com/FreeSrc/"
SRC_URI="http://apollo.backplane.com/FreeSrc/${PN}${PV//.}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 m68k mips ppc ppc64 s390 sh sparc x86"
IUSE=""

DEPEND=""
RDEPEND=""

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/dcron-2.9-Makefile.patch
	epatch "${FILESDIR}"/dcron-3.2-pidfile.patch
	epatch "${FILESDIR}"/dcron-2.9-EDITOR.patch
	epatch "${FILESDIR}"/${P}-build.patch #181043
}

src_compile() {
	append-cppflags -D_GNU_SOURCE # for asprintf()
	emake CC="$(tc-getCC)" || die
}

src_install() {
	docrondir
	docron crond -m0700 -o root -g wheel
	docrontab

	dodoc CHANGELOG README "${FILESDIR}"/crontab
	doman crontab.1 crond.8

	newinitd "${FILESDIR}"/dcron.init dcron
	newconfd "${FILESDIR}"/dcron.confd dcron

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/dcron.logrotate dcron

	insinto /etc
	doins "${FILESDIR}"/crontab
}