app-text/komikku: add 0.37.0, drop 0.35.2

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

3 files changed, 113 insertions, 77 deletions

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 617ef0177..80f8cf901 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1,2 +1,2 @@
 DIST Komikku-v0.36.1.tar.gz 4342173 BLAKE2B b7ff7a91317a8a723d543c404f5ff88b45efc710856e1e66fdbb81ea54d19698e7f8afe37b08c25e64f76d8a9e6d982c4932729262bb3916c551d09a9b4aac65 SHA512 8ccd8f600c0021f74246a654368ad9cb43b821f2ec2ddc508ac98c3075861eeebb431929ab4147291f68194bf4e689a9d2d63231052e57b8b0384ce20f4c11a6
-DIST komikku-0.35.2.tar.gz 4335169 BLAKE2B 93254ea42612f7e5daffc176db6bd4bdff97ac0be35a489fdf3d7b655160fee2df9b2a0274838edd0c2ac6609ec42ebcab3b8aa6c90203e2a4d86bf0e37828bb SHA512 c834362f54c4d7ce3cc55ac825a24b7026ea14b991f0c862c983da2f15573492296b6799a394296a5a0247c815dc609505807504534a82d49e96411c266af98d
+DIST Komikku-v0.37.0.tar.gz 4364986 BLAKE2B 657498c99331e129aa8db7c111454c9066543641df1931306f1b55ed113c9466f94ea0ffc64524222005d4e07daf01e8fd2a6f55554c4f2d1ffe4a705e456158 SHA512 32cede572df60cbf59ebe8d429e3c6df0987bb5837b3950e0de09094e36b627c6ee53fb910ee66221c2864e3a59620f932dff35f3af0f441fa83622414c115e7
diff --git a/app-text/komikku/komikku-0.35.2-r1.ebuild b/app-text/komikku/komikku-0.35.2-r1.ebuild
deleted file mode 100644
index 650925d8a..000000000
--- a/app-text/komikku/komikku-0.35.2-r1.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-MY_PN="${PN^}"
-MY_P="${MY_PN}-v${PV}"
-
-PYTHON_COMPAT=( python3_{8,9} )
-
-inherit python-single-r1 meson gnome2-utils xdg
-
-DESCRIPTION="An online/offline manga reader for GNOME"
-HOMEPAGE="https://gitlab.com/valos/Komikku"
-SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.gz -> ${P}.tar.gz"
-
-RESTRICT="test"
-KEYWORDS="~amd64"
-LICENSE="GPL-3"
-SLOT="0"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-DEPEND="
-	>=gui-libs/libhandy-1.2.0
-	>=x11-libs/gtk+-3.24.10:3
-	$(python_gen_cond_dep '
-		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
-		dev-python/cloudscraper[${PYTHON_USEDEP}]
-		dev-python/dateparser[${PYTHON_USEDEP}]
-		dev-python/keyring[${PYTHON_USEDEP}]
-		dev-python/lxml[${PYTHON_USEDEP}]
-		dev-python/natsort[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pure-protobuf[${PYTHON_USEDEP}]
-		dev-python/pygobject[${PYTHON_USEDEP}]
-		dev-python/python-magic[${PYTHON_USEDEP}]
-		dev-python/unidecode[${PYTHON_USEDEP}]
-	')
-"
-RDEPEND="
-	${PYTHON_DEPS}
-	${DEPEND}
-	net-libs/webkit-gtk
-"
-
-S="${WORKDIR}/${MY_P}"
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-}
-
-src_install() {
-	meson_src_install
-	python_optimize
-
-	sed -i "s|#!.*|#!/usr/bin/${EPYTHON}|" "${D}/usr/bin/${PN}"  ||
-		die "Failed to fix ${D}/usr/bin/${PN} interpreter"
-}
-
-pkg_preinst() {
-	gnome2_schemas_savelist
-	xdg_pkg_preinst
-}
-
-pkg_postinst() {
-	gnome2_gconf_install
-	gnome2_schemas_update
-	xdg_pkg_postinst
-}
-
-pkg_postrm() {
-	gnome2_gconf_uninstall
-	gnome2_schemas_update
-	xdg_pkg_postrm
-}
diff --git a/app-text/komikku/komikku-0.37.0.ebuild b/app-text/komikku/komikku-0.37.0.ebuild
new file mode 100644
index 000000000..4420c59fe
--- /dev/null
+++ b/app-text/komikku/komikku-0.37.0.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit python-single-r1 meson gnome2-utils virtualx xdg
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-v${PV}"
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[${PYTHON_SINGLE_USEDEP}]
+	>=gui-libs/libhandy-1.5.0
+	net-libs/webkit-gtk
+	x11-libs/gtk+:3
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cloudscraper[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="test? (
+	${RDEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-steps[${PYTHON_USEDEP}]
+	')
+)"
+
+EPYTEST_DESELECT=(
+	'tests/servers/test_apollcomics.py::test_apollcomics[get_manga_data]'
+	'tests/servers/test_apollcomics.py::test_apollcomics[get_chapter_data]'
+	'tests/servers/test_apollcomics.py::test_apollcomics[get_page_image]'
+	'tests/servers/test_dankefurslesen.py::test_dankefurslesen[get_manga_data]'
+	'tests/servers/test_dankefurslesen.py::test_dankefurslesen[get_chapter_data]'
+	'tests/servers/test_dankefurslesen.py::test_dankefurslesen[get_page_image]'
+	'tests/servers/test_dbmultiverse.py::test_dbmultiverse[get_chapter_data]'
+	'tests/servers/test_dbmultiverse.py::test_dbmultiverse[get_page_image]'
+	tests/servers/test_dynasty.py
+	tests/servers/test_genkan.py::test_edelgardescans
+	tests/servers/test_genkan.py::test_hatigarmscans
+	'tests/servers/test_japscan.py::test_japscan[get_page_image]'
+	tests/servers/test_mangadoor.py
+	tests/servers/test_mangaeden.py
+	'tests/servers/test_mangahub.py::test_mangahub[get_page_image]'
+	tests/servers/test_mangakawaii.py
+	tests/servers/test_mangalib.py
+	tests/servers/test_mangasin.py
+	tests/servers/test_nhentai.py
+	'tests/servers/test_readmanhwa.py::test_readmanhwa[search]'
+	'tests/servers/test_readmanhwa.py::test_readmanhwa[get_manga_data]'
+	'tests/servers/test_readmanhwa.py::test_readmanhwa[get_manga_chapter_data]'
+	'tests/servers/test_readmanhwa.py::test_readmanhwa[get_manga_chapter_page_image]'
+	tests/servers/test_romance24h.py::test_romance24h
+	tests/servers/test_scanmanga.py
+	tests/servers/test_scanonepiece.py
+)
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	virtx epytest
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}