media-libs/fcft: Bump to 2.5.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Ryan Fox <flewkey@2a03.party>

3 files changed, 90 insertions, 2 deletions

diff --git a/media-libs/fcft/Manifest b/media-libs/fcft/Manifest
index 9084c202d..5167c874a 100644
--- a/media-libs/fcft/Manifest
+++ b/media-libs/fcft/Manifest
@@ -6,3 +6,4 @@ DIST fcft-2.4.3.tar.gz 324345 BLAKE2B 06f79351887b875bc37e940b2fe6fb89f00d905171
 DIST fcft-2.4.4.tar.gz 324371 BLAKE2B 2bba92bb67904e8ce26228191fad77fe4b5bf881dc38fa851f80f8ef69bc6df44ad6775d86157df7671f064042cc4b4523206b96e9a4b9b7375950624dea50a6 SHA512 45d1ab44b820f78f78ab71839d16af8244cb07abd363e9d9bf0cde0df60cb7f2de9e134081c02ee68f24aca76842ea6301d28b71af7148f62019a0af6c45d035
 DIST fcft-2.4.5.tar.gz 403734 BLAKE2B 3fbd0119bb1d955b0e01be4f0ab00348b0b589849e0b338b39e424edd4994bb7ef9f51daa4e2905052a524e47d7b0f1c324300bb755eb4a43a8d920bdb820a1a SHA512 e29cabcb76357c91a93b63eaac1d548a7e4a4c05f6db39448bef6949c5e42965493b588b5c1d5cd2a223bce29e6f2a673ed63ebfa2d0d59a7edc453df06c5c8d
 DIST fcft-2.4.6.tar.gz 411139 BLAKE2B bbf0becd32060b74fdd0bbea09cdeb9251fdf660b63fb06c6d27b2cf7e7c088fb9a7e97ef2eb16326a139739a671fbd1ee0ae06ba026a27b16a16b37560db33f SHA512 554d4e01a24aba36eb44c195eef8b82aac08e8e32ddae3dabc45bef20428d02aee981610edecfb9f8311250b5c2c783664b0929305a857dd2910431512a91d95
+DIST fcft-2.5.0.tar.gz 440068 BLAKE2B fa98eace254c2f0e04735b2f6a17bc68a94e24ad201474d3af546d385279fe275ab8a283ca0e50566879befc3bc28f7ecaef2e3aa8380d1f55999f1c0c136b66 SHA512 2bd65232ecaf10a4995051eb1409aa8e676365c7d7574e1cd6cbda73e809558572beb0c0bd7e85ee4cf946bfbc83968bef90e54fa70833ab64d70f5439de9bad
diff --git a/media-libs/fcft/fcft-2.5.0.ebuild b/media-libs/fcft/fcft-2.5.0.ebuild
new file mode 100644
index 000000000..2dbb8707a
--- /dev/null
+++ b/media-libs/fcft/fcft-2.5.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="https://codeberg.org/dnkl/fcft/archive/${PV}.tar.gz  -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fcft.git"
+fi
+
+DESCRIPTION="A simple library for font loading and glyph rasterization"
+HOMEPAGE="https://codeberg.org/dnkl/fcft"
+LICENSE="MIT"
+SLOT="0/3"
+IUSE="examples +text-shaping test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/tllist
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/pixman
+	text-shaping? (
+		dev-libs/libutf8proc:=
+		media-libs/harfbuzz
+	)
+	examples? (
+		dev-libs/libutf8proc:=
+		dev-libs/wayland
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		text-shaping? ( media-fonts/noto-emoji )
+	)
+"
+BDEPEND="
+	app-text/scdoc
+	app-i18n/unicode-data
+	examples? (
+		dev-libs/wayland-protocols
+		dev-util/wayland-scanner
+	)
+"
+
+src_prepare() {
+	default
+
+	rm -r "unicode" || die "Failed removing vendored unicode-data"
+
+	sed -i "s;unicode/UnicodeData.txt;${EPREFIX}/usr/share/unicode-data/UnicodeData.txt;" \
+		meson.build || die "Failed changing UnicodeData.txt to system's copy"
+	sed -i "s;unicode/emoji-data.txt;${EPREFIX}/usr/share/unicode-data/emoji/emoji-data.txt;" \
+		meson.build || die "Failed changing emoji-data.txt to system's copy"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature text-shaping run-shaping)
+		$(meson_use examples)
+		"-Dwerror=false"
+	)
+
+	use test && emesonargs+=(
+		$(meson_use text-shaping test-text-shaping)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	use examples && newbin "${BUILD_DIR}/example/example" fcft-example
+	mv "${D}/usr/share/doc/${PN}" "${D}/usr/share/doc/${PF}" || die "Failed to install docs"
+}
diff --git a/media-libs/fcft/fcft-9999.ebuild b/media-libs/fcft/fcft-9999.ebuild
index d6ec4d3f3..2dbb8707a 100644
--- a/media-libs/fcft/fcft-9999.ebuild
+++ b/media-libs/fcft/fcft-9999.ebuild
@@ -26,7 +26,10 @@ RDEPEND="
 	media-libs/fontconfig
 	media-libs/freetype
 	x11-libs/pixman
-	text-shaping? ( media-libs/harfbuzz )
+	text-shaping? (
+		dev-libs/libutf8proc:=
+		media-libs/harfbuzz
+	)
 	examples? (
 		dev-libs/libutf8proc:=
 		dev-libs/wayland
@@ -54,11 +57,13 @@ src_prepare() {
 
 	sed -i "s;unicode/UnicodeData.txt;${EPREFIX}/usr/share/unicode-data/UnicodeData.txt;" \
 		meson.build || die "Failed changing UnicodeData.txt to system's copy"
+	sed -i "s;unicode/emoji-data.txt;${EPREFIX}/usr/share/unicode-data/emoji/emoji-data.txt;" \
+		meson.build || die "Failed changing emoji-data.txt to system's copy"
 }
 
 src_configure() {
 	local emesonargs=(
-		$(meson_feature text-shaping)
+		$(meson_feature text-shaping run-shaping)
 		$(meson_use examples)
 		"-Dwerror=false"
 	)