net-misc/purritobin/purritobin-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 2019-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="minimalistic commandline pastebin"
HOMEPAGE="https://bsd.ac"

inherit systemd toolchain-funcs

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/PurritoBin/PurritoBin.git"
else
	SRC_URI="https://github.com/PurritoBin/PurritoBin/archive/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~arm64 ~x86"
	S="${WORKDIR}/PurritoBin-${PV}"
fi

LICENSE="ISC"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"

RDEPEND="
	net-libs/usockets[ssl]
	acct-user/purritobin
	acct-group/purritobin
"
DEPEND="${RDEPEND}
	www-apps/uwebsockets
"
BDEPEND="test? ( sys-apps/coreutils )"

src_configure() {
	default
	tc-export CXX
}

src_test() {
	P_DD_FLAGS="iflag=fullblock" \
	default
}

src_install() {
	emake PREFIX="/usr" MANDIR="/usr/share/man" DESTDIR="${ED}" install
	insinto /var/www/purritobin
	doins frontend/paste.html
	fowners purritobin:purritobin /var/www/purritobin
	newinitd services/openrc purritobin
	systemd_newunit services/systemd purritobin.service
	einstalldocs
}