media-libs/sdl-gfx: EAPI8 bump, use https

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/38410
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/media-libs/sdl-gfx/sdl-gfx-2.0.26-r2.ebuild b/media-libs/sdl-gfx/sdl-gfx-2.0.26-r2.ebuild
new file mode 100644
index 000000000000..f7192215325c
--- /dev/null
+++ b/media-libs/sdl-gfx/sdl-gfx-2.0.26-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+MY_P="${P/sdl-/SDL_}"
+DESCRIPTION="Graphics drawing primitives library for SDL"
+HOMEPAGE="https://www.ferzkopp.net/joomla/content/view/19/14/"
+SRC_URI="https://www.ferzkopp.net/Software/SDL_gfx-2.0/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0/16" # libSDL_gfx.so.16
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc cpu_flags_x86_mmx"
+
+RDEPEND=">=media-libs/libsdl-1.2.15-r4[video,${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	sed -i -e 's/-O //' configure.in || die
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable cpu_flags_x86_mmx mmx)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use doc ; then
+		docinto html
+		dodoc -r Docs/*
+	fi
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}