app-admin/glance: MITAKA release

Package-Manager: portage-2.2.26

2 files changed, 137 insertions, 0 deletions

diff --git a/app-admin/glance/Manifest b/app-admin/glance/Manifest
index ef1d037bb500..452b480bbb49 100644
--- a/app-admin/glance/Manifest
+++ b/app-admin/glance/Manifest
@@ -1 +1,2 @@
 DIST glance-11.0.1.tar.gz 1571617 SHA256 357d8cc17b23aefce8c53c9230a26db504d8039baf7e07d8ab9448ce2ceaccf3 SHA512 d43e79700179bbef39d82f8baa378c377f391e7bbd9022ec9e399379fb026be36b06b7ad7b89e39cb0b2a876111b451ad1acf3ad27cead5b58ce02106867bfa6 WHIRLPOOL bbd70deae3ac5b3d549fcca20e666d1ee3f240d59556712783ff4bb8fe780c0c06ff1344476a7a036aa5e99afcdc3a369a7bf322227717f17c42cc02e5f3b477
+DIST glance-12.0.0.tar.gz 1746851 SHA256 42213a4cd59bbcaa5f34d09ff48494a4d9831de9f27fc8541726a685a4c4f509 SHA512 c0a4327bb091dca52a125dbc314c8fe13b2914ed0191ee8a39a36a7ccc5324fc8910f4c2af5a615f7783e3acee0f46a9a5370de278af53f80ce45b08c15ace48 WHIRLPOOL 1a23d1629f1be1b13b2c45ff77b7777d9cd011c01c45e1e6e5457d12b7b5cf6dcdfc757a36fde4cc84d34872be3fb1941e8cd158e2734215cab4f753f154a78e
diff --git a/app-admin/glance/glance-12.0.0.ebuild b/app-admin/glance/glance-12.0.0.ebuild
new file mode 100644
index 000000000000..db3b2a85146a
--- /dev/null
+++ b/app-admin/glance/glance-12.0.0.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 user
+
+DESCRIPTION="Services for discovering, registering, and retrieving VM images"
+HOMEPAGE="https://launchpad.net/glance"
+SRC_URI="https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc mysql postgres +sqlite +swift"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+CDEPEND=">=dev-python/pbr-1.6.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}"
+
+#note to self, wsgiref is a python builtin, no need to package it
+#>=dev-python/wsgiref-0.1.2[${PYTHON_USEDEP}]
+
+RDEPEND="
+	${CDEPEND}
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		dev-python/mysql-python
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	>=dev-python/webob-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/futurist-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/keystonemiddleware-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/WSME-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.0[${PYTHON_USEDEP}]
+	<dev-python/prettytable-0.8.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-1.8.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/glance_store-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/semantic_version-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-0.6[${PYTHON_USEDEP}]
+"
+
+#PATCHES=(
+#)
+
+pkg_setup() {
+	enewgroup glance
+	enewuser glance -1 -1 /var/lib/glance glance
+}
+
+python_prepare_all() {
+	sed -i '/xattr/d' test-requirements.txt || die
+	sed -i '/pysendfile/d' test-requirements.txt || die
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	for svc in api glare registry scrubber; do
+		newinitd "${FILESDIR}/glance.initd" glance-${svc}
+	done
+
+	diropts -m 0750 -o glance -g glance
+	dodir /var/log/glance /var/lib/glance/images /var/lib/glance/scrubber
+	keepdir /etc/glance
+	keepdir /var/log/glance
+	keepdir /var/lib/glance/images
+	keepdir /var/lib/glance/scrubber
+
+	insinto /etc/glance
+	insopts -m 0640 -o glance -g glance
+	doins -r etc/*.ini etc/*.conf etc/*.sample etc/*.json etc/meta*
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}