app-admin/webapp-config: fix bashism in tests, bug #561798

1 files changed, 66 insertions, 0 deletions

diff --git a/app-admin/webapp-config/webapp-config-1.54-r2.ebuild b/app-admin/webapp-config/webapp-config-1.54-r2.ebuild
new file mode 100644
index 000000000000..3a0e46fed759
--- /dev/null
+++ b/app-admin/webapp-config/webapp-config-1.54-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+SRC_URI="https://dev.gentoo.org/~twitch153/${PN}/${P}.tar.bz2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="Gentoo's installer for web-based applications"
+HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+portage"
+
+DEPEND="app-text/xmlto
+	sys-apps/gentoo-functions"
+RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+python_prepare() {
+	epatch "${FILESDIR}/${P}-pvr-check.patch"
+	epatch "${FILESDIR}/${P}-fix-bashism.patch"
+}
+python_compile_all() {
+	emake -C doc/
+}
+
+python_install() {
+	# According to this discussion:
+	# http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
+	# distutils does not provide for specifying two different script install
+	# locations. Since we only install one script here the following should
+	# be ok
+	distutils-r1_python_install --install-scripts="/usr/sbin"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/vhosts
+	doins config/webapp-config
+
+	keepdir /usr/share/webapps
+	keepdir /var/db/webapps
+
+	dodoc AUTHORS
+	doman doc/*.[58]
+	dohtml doc/*.[58].html
+}
+
+python_test() {
+	PYTHONPATH="." "${PYTHON}" WebappConfig/tests/external.py \
+		|| die "Testing failed with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "webapp-config now requires that all -I/-U/-C commands be followed"
+	elog "by the package name and package version of the webapp"
+	elog "eg.) 'webapp-config -d drupal -I drupal 8.0.0_beta10'"
+	elog "See 'man 8 webapp-config' for more information"
+}