app-editors/retext: Bump to 7.2.1

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Nils Freydank <holgersson@posteo.de>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/app-editors/retext/Manifest b/app-editors/retext/Manifest
index 8ce4d6df0bc1..132fac73e7b1 100644
--- a/app-editors/retext/Manifest
+++ b/app-editors/retext/Manifest
@@ -1,2 +1,3 @@
 DIST ReText-7.1.0.tar.gz 484989 BLAKE2B 74f07218cba1d76d011e5347c65ec03ef84da29119c177f35cca206cb269ae4755fdb85448562a378d2ab610930d23b4eccb62a39807409c6e80a68102be2034 SHA512 92333f31f7a57440d642246ed30156384285bb44640a0d6e7654e82749681893eaef3cb16e41fa2d7b618aa59f1ea8cb07d431736b00f35cb9130d7294e3d105
 DIST ReText-7.2.0.tar.gz 516895 BLAKE2B e35cfa59b248135be4454359516c36f94e927cb13d60669cffde6b8b70eb5049e2083e6bd50ea1f602f7454025271599a92e34d4bc95920cb17271882f8f6d31 SHA512 ed1cb0088fcd3f1cba96bb07137766c6ae8177e8c9a91f22334ef2f949b58792e03f0b5022d9ef71bfb611b7969c651b4c7920f48ed8e1ad07caff2f69c85a35
+DIST ReText-7.2.1.tar.gz 522364 BLAKE2B 6334fd6dc1c625378426e408a0d4ad6bb9c02dcba18fcfa566d61ce006a44c34327686a8eb756f2195620e644e096b9393a7cfa73229aa0dab7d29ddf715edaa SHA512 1a375acb40792e3cae9f955a75ebac7c30c9e5cc719477989b28d8d7f06e18ad14d98f1a600a5b6d050b3276ef22bd46b5f1f07af90d561cca500674ff461604
diff --git a/app-editors/retext/retext-7.2.1.ebuild b/app-editors/retext/retext-7.2.1.ebuild
new file mode 100644
index 000000000000..13399224b736
--- /dev/null
+++ b/app-editors/retext/retext-7.2.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Please don't add pypy support before testing if it's actually supported. The
+# old compat matrix is no longer accessible as of 2021-02-13 but stated back
+# in 2020-07-05 that PyQt5 was explicitly not supported.
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit distutils-r1 optfeature virtualx xdg-utils
+
+MY_PN="ReText"
+MY_P="${MY_PN}-${PV/_/~}"
+
+DESCRIPTION="Simple editor for Markdown and reStructuredText"
+HOMEPAGE="https://github.com/retext-project/retext https://github.com/retext-project/retext/wiki"
+
+if [[ ${PV} == *9999 ]]
+	then
+		inherit git-r3
+		EGIT_REPO_URI="https://github.com/retext-project/retext.git"
+	else
+		SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+		KEYWORDS="~amd64 ~x86"
+		S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	>=dev-python/markups-3.1.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/python-markdown-math[${PYTHON_USEDEP}]
+	dev-python/PyQt5[dbus,gui,printsupport,widgets,${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="test? ( dev-python/PyQt5[testlib,${PYTHON_USEDEP}] )"
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+
+	optfeature "dictionary support" dev-python/pyenchant
+	# See https://bugs.gentoo.org/772197.
+	optfeature "rendering with webengine" dev-python/PyQtWebEngine
+
+	einfo "Starting with retext-7.0.4 the markdown-math plugin is installed."
+	einfo "Note that you can use different math delimiters, e.g. \(...\) for inline math."
+	einfo "For more details take a look at:"
+	einfo "https://github.com/mitya57/python-markdown-math#math-delimiters"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}