proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/app-emulation/uae/uae-0.8.29-r2.ebuild b/app-emulation/uae/uae-0.8.29-r2.ebuild
new file mode 100644
index 000000000000..bd951a854a86
--- /dev/null
+++ b/app-emulation/uae/uae-0.8.29-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils autotools
+
+DESCRIPTION="The Umiquious Amiga Emulator"
+HOMEPAGE="http://www.amigaemulator.org/"
+SRC_URI="ftp://ftp.amigaemulator.org/pub/uae/sources/develop/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="sdl alsa scsi"
+
+DEPEND="sdl? ( media-libs/libsdl
+		   media-libs/sdl-gfx
+		   x11-libs/gtk+:2
+		   alsa? ( media-libs/alsa-lib )
+	)
+	!sdl? ( x11-libs/libXext
+		 x11-libs/gtk+:2
+	)
+	alsa? ( media-libs/alsa-lib )
+	scsi? ( app-cdr/cdrtools )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.8.25-allow_spaces_in_zip_filenames.diff
+	epatch "${FILESDIR}"/${PN}-0.8.25-struct_uae_wrong_fields_name.diff
+	epatch "${FILESDIR}"/${PN}-0.8.26-uae_reset_args.diff
+	epatch "${FILESDIR}"/${PN}-0.8.26-underlinking.patch
+
+	cp "${FILESDIR}"/sdlgfx.h "${S}"/src || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# disabling lots of options, cause many code-paths are broken, these should compile,
+	# if you want/need other options, please test if they work with other combinations
+	# before opening a bug
+	econf --enable-ui --with-x --without-svgalib \
+		--without-asciiart --without-sdl-sound --enable-threads \
+		$(use_with sdl) $(use_with sdl sdl-gfx) \
+		$(use_with alsa) \
+		$(use_enable scsi scsi-device)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	dobin uae readdisk
+	cp docs/unix/README docs/README.unix || die
+	rm -r docs/{AmigaOS,BeOS,pOS,translated,unix} || die
+	dodoc docs/*
+
+	insinto /usr/share/uae/amiga-tools
+	doins amiga/{*hack,trans*,uae*}
+}
+
+pkg_postinst() {
+	elog
+	elog "Upstream recommends using SDL graphics (with an environment variable)"
+	elog "SDL_VIDEO_X11_XRANDR=1 for fullscreen support."
+	echo
+}