app-misc/reptyr: Bump to version 0.7.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/app-misc/reptyr/reptyr-0.7.0.ebuild b/app-misc/reptyr/reptyr-0.7.0.ebuild
new file mode 100644
index 000000000000..d8ca305260d3
--- /dev/null
+++ b/app-misc/reptyr/reptyr-0.7.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1 toolchain-funcs flag-o-matic vcs-snapshot
+
+DESCRIPTION="A utility to attach a running program to a new terminal"
+HOMEPAGE="https://github.com/nelhage/reptyr"
+SRC_URI="https://github.com/nelhage/${PN}/archive/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	# respect CFLAGS
+	sed -i '/^override/d' Makefile || die
+}
+
+src_compile() {
+	append-cppflags -D_GNU_SOURCE
+	emake CC=$(tc-getCC) CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+	dodoc ChangeLog NOTES README.md
+	newbashcomp reptyr{.bash,}
+}