dev-libs/rasqal: 0.9.33 version bump

Closes: https://bugs.gentoo.org/545554
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

2 files changed, 70 insertions, 0 deletions

diff --git a/dev-libs/rasqal/Manifest b/dev-libs/rasqal/Manifest
index d408a528953e..ed11d7141053 100644
--- a/dev-libs/rasqal/Manifest
+++ b/dev-libs/rasqal/Manifest
@@ -1 +1,2 @@
 DIST rasqal-0.9.32.tar.gz 1544623 BLAKE2B c94833d2906fc211d743d63a52478e6acc9f26c7528beb1bea0ec8c365b5d13e6ac85e57b75b920d1ccb5768112d06cf615212c7bf248120671730c5095b3c88 SHA512 071f5ff30a1271bdd747cab7991a34c75f9c0132e81d7662acb13a2e380b98c325a9b2998f6a08a393251623680074a76f58f70bdd93b5c1416779aacc7be428
+DIST rasqal-0.9.33.tar.gz 1595647 BLAKE2B 87bca86b2f0dceb0801f5a34dae9ae1f87d8a7d0dc1e03fdf04998a0d4885ed76be2719d3e01489a5510a26715bb093a75ce194cc42f3cedff88f64161d6a2fb SHA512 05728682797470db9e51d156012e8fde9dec1554d107372faa11cbe6cdc3356e92386f4f8de6d7c41e3100b76f9b1c6809102a913829cddbd2ff29043c04d522
diff --git a/dev-libs/rasqal/rasqal-0.9.33.ebuild b/dev-libs/rasqal/rasqal-0.9.33.ebuild
new file mode 100644
index 000000000000..df3e0ecc3f50
--- /dev/null
+++ b/dev-libs/rasqal/rasqal-0.9.33.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool
+
+DESCRIPTION="Library that handles Resource Description Framework (RDF)"
+HOMEPAGE="http://librdf.org/rasqal/"
+SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="+crypt gmp kernel_linux +mhash pcre static-libs test xml"
+
+RDEPEND="
+	>=media-libs/raptor-2.0.15
+	crypt? (
+		!mhash? ( dev-libs/libgcrypt:0 )
+		mhash? ( app-crypt/mhash )
+	)
+	!gmp? ( dev-libs/mpfr:= )
+	gmp? ( dev-libs/gmp:= )
+	kernel_linux? ( >=sys-apps/util-linux-2.19 )
+	pcre? ( dev-libs/libpcre )
+	xml? ( dev-libs/libxml2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/bison-3
+	>=sys-devel/flex-2.5.36
+	virtual/pkgconfig
+	test? ( dev-perl/XML-DOM )
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+HTML_DOCS=( {NEWS,README,RELEASE}.html )
+
+src_prepare() {
+	default
+	elibtoolize # g/fbsd .so versioning
+}
+
+src_configure() {
+	# FIXME: From 0.9.27 to .28 --with-random-approach= was introduced, do we
+	# need a logic for it? Perhaps for dev-libs/gmp?
+	local myeconfargs=(
+		--with-decimal=$(usex gmp gmp mpfr)
+		--with-uuid-library=$(usex kernel_linux libuuid internal)
+		$(use_enable pcre)
+		--with-regex-library=$(usex pcre pcre posix)
+		$(use_enable static-libs static)
+		$(use_enable xml xml2)
+	)
+
+	if use crypt; then
+		myeconfargs+=( $(usex mhash mhash gcrypt) )
+	else
+		myeconfargs+=( --with-digest-library=internal )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}