dev-libs/libxmlb: add 0.3.19

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-libs/libxmlb/Manifest b/dev-libs/libxmlb/Manifest
index 3b2074d68fbb..fcb0d2199be7 100644
--- a/dev-libs/libxmlb/Manifest
+++ b/dev-libs/libxmlb/Manifest
@@ -1,2 +1,3 @@
 DIST libxmlb-0.3.14.tar.gz 127096 BLAKE2B d99ec674385cd8dc31d92b14ac1539138b00c980ba3561fd406099a64afdf2f8b6fa2d808b5a33daafbcbc5ef87e20a02a534f860699f78bc71aa55d4b507d51 SHA512 6c77b9475ca3430270ca29e3d1c5720740c54ff55da76501495da315ea039500e64791689600aa59f3003ff54d030203616ad468169c296bf34434a68e24df50
 DIST libxmlb-0.3.18.tar.gz 131331 BLAKE2B 8ee200c28b5159a895d601700b6553945b23e321d2266a0438a176747be4922b81bdbc9b9a27c3ff8490f8d40fd5e2d6e7eb5c2ca21484438a55adc54c6d3be3 SHA512 2576aca6b7651cf484694ad157914982ef1e3949ea641b4181966e5d5292b3d8c16318fe61b14d8c7e6d0e0d184ed30d498f874f5ada196f0ca69c6180d9061f
+DIST libxmlb-0.3.19.tar.gz 131490 BLAKE2B 1455e14a90f29865f304b16cbf0355966e7fd0766f8033cb2b2bc9fe28ad0a1266c1e06faaeb3677a683be56bc2fd9a64094d958f00358292fae55949229ab9a SHA512 07db2e99b2f78f6e99cccbf5ca250978955d5a9bf18aaa675b2292d1df438fc3f98a5d0e8ddcfa41e686782f35947fe92b54b520b4e6e278d6e5c871e7491271
diff --git a/dev-libs/libxmlb/libxmlb-0.3.19.ebuild b/dev-libs/libxmlb/libxmlb-0.3.19.ebuild
new file mode 100644
index 000000000000..1d407706e7cc
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.3.19.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # libxmlb.so version
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc introspection +lzma stemmer test +zstd"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	sys-apps/util-linux
+	lzma? ( app-arch/xz-utils )
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	zstd? ( app-arch/zstd:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-build/meson-0.47.0
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature lzma)
+		$(meson_feature zstd)
+		$(meson_use doc gtkdoc)
+		$(meson_use introspection)
+		$(meson_use stemmer)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/installed-tests \
+			|| die
+	fi
+}