dev-python/mypy: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 113 deletions

diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index 07f452a7a8ed..93abb4a0dad8 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -1,2 +1 @@
 DIST mypy-1.10.0.gh.tar.gz 3062151 BLAKE2B ddc7354b2b62247387fd04b309c50d4ffa5c1b8af58873cc8787bd17c04069b528850bfb586925aa7df6634a65af6a1e951e4d6036d5bd0e688b8608980510bd SHA512 c936c299d9d4b6911505ef7b7df6f8d7344bd199a2d654e66467291f6e6ba4432dfa7aed5a504e6ec9518d9d53ac85f771e7b31dc6a72e06e79c443547bc2b66
-DIST mypy-1.9.0.gh.tar.gz 3029335 BLAKE2B 5329a95e5ac52933413a91bec2c8bd728451508b7ead880c7c4542bbe5d4cd4d2155c6d372d31a653af9a913de51d8e35d44c1dde193787ce8eaedd8d64d682d SHA512 aaa975b97e72f00a384a38fee190e39c6469b062a7083c76bb94bb7058ed38f713f65b96bb36a871a430633cab424a0f11e995868f867e2f7a13c4754ed96c89
diff --git a/dev-python/mypy/mypy-1.9.0.ebuild b/dev-python/mypy/mypy-1.9.0.ebuild
deleted file mode 100644
index b9f21a0e93c7..000000000000
--- a/dev-python/mypy/mypy-1.9.0.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} )
-
-inherit distutils-r1 multiprocessing
-
-DESCRIPTION="Optional static typing for Python"
-HOMEPAGE="
-	https://www.mypy-lang.org/
-	https://github.com/python/mypy/
-	https://pypi.org/project/mypy/
-"
-SRC_URI="
-	https://github.com/python/mypy/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="+native-extensions"
-
-# stubgen collides with this package: https://bugs.gentoo.org/585594
-RDEPEND="
-	!dev-util/stubgen
-	>=dev-python/psutil-4[${PYTHON_USEDEP}]
-	>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
-	>=dev-python/mypy_extensions-1.0.0[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/tomli[${PYTHON_USEDEP}]
-	' 3.10)
-"
-BDEPEND="
-	native-extensions? (
-		${RDEPEND}
-		dev-python/types-psutil[${PYTHON_USEDEP}]
-		dev-python/types-setuptools[${PYTHON_USEDEP}]
-	)
-	test? (
-		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
-		>=dev-python/filelock-3.3.0[${PYTHON_USEDEP}]
-		>=dev-python/lxml-4.9.1[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-# frustratingly, mypyc produces non-deterministic output. If ccache is enabled it will be a waste of time,
-# but simultaneously it might trash your system and fill up the cache with a giant wave of non-reproducible
-# test files (https://github.com/mypyc/mypyc/issues/1014)
-export CCACHE_DISABLE=1
-
-src_compile() {
-	local -x MYPY_USE_MYPYC=$(usex native-extensions 1 0)
-	distutils-r1_src_compile
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# the majority of them require Internet (via pip)
-		mypy/test/testpep561.py
-		# known broken with assertions enabled
-		# https://github.com/python/mypy/issues/16043
-		mypyc/test/test_run.py::TestRun::run-i64.test::testI64GlueMethodsAndInheritance
-		mypyc/test/test_run.py::TestRun::run-floats.test::testFloatOps
-		# these assume that types-docutils are not installed
-		mypy/test/testpythoneval.py::PythonEvaluationSuite::pythoneval.test::testIgnoreImportIfNoPython3StubAvailable
-		mypy/test/testpythoneval.py::PythonEvaluationSuite::pythoneval.test::testNoPython3StubAvailable
-		# TODO
-		mypy/test/meta/test_parse_data.py
-		mypy/test/meta/test_update_data.py
-		mypy/test/teststubtest.py::StubtestUnit::test_runtime_typing_objects
-	)
-	case ${EPYTHON} in
-		python3.12)
-			EPYTEST_DESELECT+=(
-				# more assertions, sigh
-				mypyc/test/test_run.py::TestRun::run-bools.test::testBoolOps
-				mypyc/test/test_run.py::TestRun::run-i64.test::testI64BasicOps
-				mypyc/test/test_run.py::TestRun::run-i64.test::testI64DefaultArgValues
-				mypyc/test/test_run.py::TestRun::run-i64.test::testI64ErrorValuesAndUndefined
-			)
-			;;
-	esac
-
-	# Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
-	# fail with high COLUMNS values
-	local -x COLUMNS=80
-
-	# The tests depend on having in-source compiled extensions if you want to
-	# test those compiled extensions. Various crucial test dependencies aren't
-	# installed. Even pyproject.toml is needed because that's where pytest args
-	# are in. Hack them into the build directory and delete them afterwards.
-	# See: https://github.com/python/mypy/issues/16143
-	local -x MYPY_TEST_PREFIX="${S}"
-	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	cp -r "${S}"/{conftest.py,pyproject.toml} . || die
-
-	local failed=
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	nonfatal epytest -n "$(makeopts_jobs)" --dist=worksteal || failed=1
-
-	rm conftest.py pyproject.toml || die
-
-	[[ ${failed} ]] && die "epytest failed with ${EPYTHON}"
-}