dev-python/zipp: Use flit to build (for bootstrap)

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/zipp/zipp-3.7.0-r1.ebuild b/dev-python/zipp/zipp-3.7.0-r1.ebuild
new file mode 100644
index 000000000000..5ebc37f8cd89
--- /dev/null
+++ b/dev-python/zipp/zipp-3.7.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="https://github.com/jaraco/zipp/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	test? ( dev-python/jaraco-itertools[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# speed tests are flaky by design
+	test_zipp.py::TestPath::test_implied_dirs_performance
+)
+
+src_prepare() {
+	# dep of disabled test
+	sed -i -e '/func_timeout/d' test_zipp.py || die
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "zipp"
+		version = "${PV}"
+		description = "Backport of pathlib-compatible object wrapper for zip files"
+	EOF
+}