dev-python/graph-tool: add 2.46

Closes: https://bugs.gentoo.org/896786
Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 7b20b54bb936..92991b0d8a35 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.45.tar.bz2 15156784 BLAKE2B b9086e5545ace668f703bf06363a382fab734a63d5684d44b62407a06a0464df6a4a9c8c7ccd26e53118c1d24469ed2eb4670939dc0889fafe2f73a2c176101b SHA512 46a4a3a22033c74c69e0ba5ce8f0856d2f35934d52850ef4a542384c8fd327daf56341675a3299a8db87d4a227b5583f0564f8917ecf28081cb1dd4091563490
+DIST graph-tool-2.46.tar.bz2 15189665 BLAKE2B 85b80feb7019cbd37b4440f6caa97eee4b27e439b2dc865742849e1f4cba9f9090d193fba7de87c84062da4b3f60887e19ee5f33b127373151b7767dacfdd4ae SHA512 a06c2d9acd23a11ea1faf2507222c3c4bfc8973e4fd7185a407d785a43f7409e77ace7af02030106a1bd13ffd719c6c10f7ebb76579448fa9bddd38b9ff7fb2a
diff --git a/dev-python/graph-tool/graph-tool-2.46.ebuild b/dev-python/graph-tool/graph-tool-2.46.ebuild
new file mode 100644
index 000000000000..8908fe7983be
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.46.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}