dev-util/gn: bump to 0.1616

Package-Manager: Portage-2.3.70_p2, Repoman-2.3.16_p22
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-util/gn/gn-0.1616.ebuild b/dev-util/gn/gn-0.1616.ebuild
new file mode 100644
index 000000000000..172a7364d2a3
--- /dev/null
+++ b/dev-util/gn/gn-0.1616.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2018-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+SRC_URI="https://dev.gentoo.org/~floppym/dist/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="vim-syntax"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r3.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip
+	echo "$@" >&2
+	"$@" || die
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	if use vim-syntax; then
+		insinto /usr/share/vim/vimfiles
+		doins -r tools/gn/misc/vim/{autoload,ftdetect,ftplugin,syntax}
+	fi
+}