lxqt-base/lxqt-panel: add 2.1.4

Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

2 files changed, 118 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 479c23618aa4..f643dc5ac4fa 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,2 +1,3 @@
 DIST lxqt-panel-2.0.1.tar.xz 662616 BLAKE2B d27f99e5ba301ad1d03a8e8e4dad939c4f5ba8e7825fe0ac93d8a3b1649f21bd6614d144322b5355112f44f8b8eebf5f9ed3f8e5b4bac85d27530ba02abe0d31 SHA512 df2cef5f03f65eb20eaf58cf8dc2f390bc4daa67638e301e0df15c82b8332f842d8e1ee9f1f5bc2240a25ce4b2f404aa7aa69a415a41f5cbb17592f8c77a414e
 DIST lxqt-panel-2.1.3.tar.xz 699548 BLAKE2B 235d35135098f76a98a61bd5af8ca4b81f39ff1e82b431efda37c7dda1b5fcf56d2a70d86d84a314ecb9bad5b663dc249ad0c102ee80bb21d94b8457196cba84 SHA512 ee5943f41696101866aef029b40a5a0b03648f5b74eb7277ca8b8b90569cb61653b65634fbb9c6ddf60ebb1fbeeac9d99fd2793b9a22ab209d1901b92a080c6c
+DIST lxqt-panel-2.1.4.tar.xz 711304 BLAKE2B aba4c662ffbc3d9af8845c1520ec876bbbc40478aa6775e01bca08b3cbf2d82a8ca57e3ca25ae8929b360b3ac9275350c0a6e40047513c720cb89d37d8e6e900 SHA512 ccb192ee9e35a397160aae5367dea26ade5bea583e65ee4692a0300bda9fd681e07fcb8b010557bcd2ad208f66c3872b92792ddd837ca995c1e032e3a81efd87
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-2.1.4.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-2.1.4.ebuild
new file mode 100644
index 000000000000..d2ebada7c04e
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-2.1.4.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="
+	+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
+	+mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
+	+spacer +statusnotifier sysstat +taskbar tray +volume +worldclock
+"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.1.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-4.1.0
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	kde-frameworks/kwindowsystem:6[X]
+	kde-plasma/layer-shell-qt:6
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	=lxqt-base/lxqt-menu-data-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:6 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-lxqt
+		>=dev-qt/qtbase-6.6:6[concurrent]
+	)
+	sysstat? ( >=lxqt-base/libsysstat-1.1.0 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/xcb-util
+		x11-libs/xcb-util-image
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-libs/libpulse
+			media-sound/pavucontrol-qt
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}