proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 46 insertions, 0 deletions

diff --git a/media-libs/libass/libass-0.11.1.ebuild b/media-libs/libass/libass-0.11.1.ebuild
new file mode 100644
index 000000000000..318f657255ce
--- /dev/null
+++ b/media-libs/libass/libass-0.11.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils multilib-minimal
+
+DESCRIPTION="Library for SSA/ASS subtitles rendering"
+HOMEPAGE="http://github.com/libass/libass"
+SRC_URI="http://github.com/libass/libass/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0/5" # subslot = libass soname version
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="+enca +fontconfig +harfbuzz static-libs"
+
+RDEPEND="fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
+	>=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}]
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/fribidi-0.19.5-r1[${MULTILIB_USEDEP}]
+	harfbuzz? ( >=media-libs/harfbuzz-0.9.12[truetype,${MULTILIB_USEDEP}] )
+	enca? ( >=app-i18n/enca-1.14-r1[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+X86_CPU_OPTS="abi_x86_32 abi_x86_64"
+for i in ${X86_CPU_OPTS} ; do
+	DEPEND="${DEPEND}
+		${i}? ( dev-lang/yasm )"
+done
+
+DOCS="Changelog"
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable enca) \
+		$(use_enable fontconfig) \
+		$(use_enable harfbuzz) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}