media-libs/libopenshot: bump to 0.1.2

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2304

Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libopenshot/Manifest b/media-libs/libopenshot/Manifest
index 31fa84e2a375..9742eff31825 100644
--- a/media-libs/libopenshot/Manifest
+++ b/media-libs/libopenshot/Manifest
@@ -1,2 +1,3 @@
 DIST libopenshot-0.1.0.tar.gz 10970157 SHA256 1eb3cc27d9d5a5c966dd5dd445567239c6cbcc08772ba99e5f3b52c87a28d809 SHA512 bd5767b96ae38da7f31bfcca3ec5b34c458ab271d3e899b1982cd09b0576d29a3101c54fc840766d40aa7cbc83130064f0440f5c465999f0518449318ab87480 WHIRLPOOL c485271357545e85b94753659f0a58f4e7b0f4c4ee2a4d53bbcb1d650a3cef730103b73577848d0e2e6a355d42788451fbc1839c82343b2f172c3fd725906f29
 DIST libopenshot-0.1.1.tar.gz 10970421 SHA256 7f79084b0fda085ee5740f4907a2ac4bd736de6b3c4958b4441f49eaedfc7eee SHA512 7ed329b8a066ace9996342504ce817cd0e20a8599a71fa6483d8b2eeb52b5bfeed0cb4b9d099c34a275fc529d55d1bd0527707264ddd5d106574ee25e4fcd3ec WHIRLPOOL 9a759029f4b0ff1510157c91ac09f67c665446b5551487c6d228c2a668b019bb919aae53e5813b541863d32116017f0fc2a19dbc008e307e3bc9c32cc72df884
+DIST libopenshot-0.1.2.tar.gz 11012039 SHA256 f5b37250aaa4f7ca29727966b818d73d6a100d92dbb7bc5270ee332f820a3657 SHA512 a713b24c5925ea99f5b749e178a635dd30d1ed666d8a1195beaabd44fd4d8b4e5282ee0fda2fef58dc5db3e1a481f535902496128142c445082130a08841540e WHIRLPOOL 7902060db5e5d4ff4136057f33f0c6149827cfa9000bae70f7271ddabe608b5672caaa3dececb68517f4419b36ecd89fb718caa9823e214203fcfc1c648d5536
diff --git a/media-libs/libopenshot/libopenshot-0.1.2.ebuild b/media-libs/libopenshot/libopenshot-0.1.2.ebuild
new file mode 100644
index 000000000000..3d7575801e91
--- /dev/null
+++ b/media-libs/libopenshot/libopenshot-0.1.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5} )
+
+inherit cmake-utils python-single-r1 toolchain-funcs versionator
+
+DESCRIPTION="Video editing library used by OpenShot"
+HOMEPAGE="http://www.openshotvideo.com/"
+SRC_URI="https://github.com/OpenShot/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+imagemagick libav +python test"
+# https://github.com/OpenShot/libopenshot/issues/36
+RESTRICT="test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	net-libs/cppzmq
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	media-libs/libopenshot-audio
+	imagemagick? ( media-gfx/imagemagick:0=[cxx] )
+	libav? ( media-video/libav:=[encode,x264,xvid,vpx,mp3,theora] )
+	!libav? ( media-video/ffmpeg:0=[encode,x264,xvid,vpx,mp3,theora] )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${RDEPEND}
+	python? ( dev-lang/swig )
+	test? ( dev-libs/unittest++ )
+"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && ! tc-has-openmp; then
+		eerror "${P} requires a compiler with OpenMP support. Your current"
+		eerror "compiler does not support it. If you use gcc, you can"
+		eerror "re-emerge it with the 'openmp' use flag enabled."
+		die "The current compiler does not support OpenMP"
+	fi
+}
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# https://github.com/OpenShot/libopenshot/issues/17
+	use test || cmake_comment_add_subdirectory tests
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RUBY=OFF # TODO: add ruby support
+		-DENABLE_PYTHON=$(usex python)
+		-DCMAKE_DISABLE_FIND_PACKAGE_ImageMagick=$(usex !imagemagick)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+		-DPYTHON_LIBRARY="$(python_get_library_path)"
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	pushd "${BUILD_DIR}/tests" > /dev/null || die
+	./openshot-test || die "Tests failed"
+	popd > /dev/null || die
+}
+
+src_install() {
+	cmake-utils_src_install
+	python_optimize
+}