media-libs/mlt: add 7.10.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/media-libs/mlt/Manifest b/media-libs/mlt/Manifest
index c4ecdaff24a0..7f98e63578bd 100644
--- a/media-libs/mlt/Manifest
+++ b/media-libs/mlt/Manifest
@@ -1 +1,2 @@
+DIST mlt-7.10.0.tar.gz 1477944 BLAKE2B 29b364526f0f202ac4a2a218d977d8a6b0dbc822fc6605c264d84cd2c5f4754dee7f82cb60a19cd9d9a1a78126b61c1b892b80c21bcb46a8c925941b06c519d2 SHA512 bb5cbf1cd6800b92c1f651cc6f10df271bae3f20afc080822f9aea89fad6d1e852d516e5cd38ff26e44085c5d6f7e27ccefb9c468270dab3d4813b382e61c4ae
 DIST mlt-7.8.0a.tar.gz 1458730 BLAKE2B 0f544923c7f1667d2a2379bcb84a68dca2c701ce7b9cebe4e9b5f81efcb494674111fea09e9025108b8714e792a0179d465d226bb0a0231a197a67c99d82f976 SHA512 aa44d604f2246db11e5c572e2c3f9121ef0ace1fdead95a6a4a20f7555a3139b067fd2d464f27d23cc90cfcf8907ae9cf8f33b26f76c110a6ba2329867f88bd1
diff --git a/media-libs/mlt/mlt-7.10.0.ebuild b/media-libs/mlt/mlt-7.10.0.ebuild
new file mode 100644
index 000000000000..df3bc79a01f1
--- /dev/null
+++ b/media-libs/mlt/mlt-7.10.0.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-single-r1 cmake
+
+DESCRIPTION="Open source multimedia framework for television broadcasting"
+HOMEPAGE="https://www.mltframework.org/"
+SRC_URI="https://github.com/mltframework/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/7"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug ffmpeg frei0r gtk jack libsamplerate opencv opengl python qt5 rtaudio rubberband sdl test vdpau vidstab xine xml"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Needs unpackaged 'kwalify'
+RESTRICT="test"
+
+# rtaudio will use OSS on non linux OSes
+# Qt already needs FFTW/PLUS so let's just always have it on to ensure
+# MLT is useful: bug #603168.
+DEPEND="
+	>=media-libs/libebur128-1.2.2:=
+	sci-libs/fftw:3.0=
+	ffmpeg? ( media-video/ffmpeg:0=[vdpau?,-flite] )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gtk? (
+		media-libs/libexif
+		x11-libs/pango
+	)
+	jack? (
+		>=dev-libs/libxml2-2.5
+		media-libs/ladspa-sdk
+		virtual/jack
+	)
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	opencv? ( >=media-libs/opencv-4.5.1:=[contrib] )
+	opengl? (
+		media-libs/libglvnd
+		media-video/movit
+	)
+	python? ( ${PYTHON_DEPS} )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+		media-libs/libexif
+		x11-libs/libX11
+	)
+	rtaudio? (
+		>=media-libs/rtaudio-4.1.2
+		kernel_linux? ( media-libs/alsa-lib )
+	)
+	rubberband? ( media-libs/rubberband )
+	sdl? (
+		media-libs/libsdl2[X,opengl,video]
+		media-libs/sdl2-image
+	)
+	vidstab? ( media-libs/vidstab )
+	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
+	xml? ( >=dev-libs/libxml2-2.5 )
+"
+#	java? ( >=virtual/jre-1.8:* )
+#	perl? ( dev-lang/perl )
+#	php? ( dev-lang/php )
+#	ruby? ( ${RUBY_DEPS} )
+#	sox? ( media-sound/sox )
+#	tcl? ( dev-lang/tcl:0= )
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( >=dev-lang/swig-2.0 )
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.10.0-swig-underlinking.patch
+	"${FILESDIR}"/${PN}-6.22.1-no_lua_bdepend.patch
+	"${FILESDIR}"/${PN}-7.0.1-cmake-symlink.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
+	if use python; then
+		sed -i "/mlt.so/s/ -lmlt++ /& ${CFLAGS} ${LDFLAGS} /" src/swig/python/build || die
+		python_fix_shebang src/swig/python
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DGPL=ON
+		-DGPL3=ON
+		-DBUILD_TESTING=$(usex test)
+		-DMOD_KDENLIVE=ON
+		-DMOD_SDL1=OFF
+		-DMOD_SDL2=$(usex sdl)
+		-DMOD_AVFORMAT=$(usex ffmpeg)
+		-DMOD_PLUS=ON
+		-DMOD_FREI0R=$(usex frei0r)
+		-DMOD_GDK=$(usex gtk)
+		-DMOD_JACKRACK=$(usex jack)
+		-DMOD_GLAXNIMATE=OFF
+		-DMOD_RESAMPLE=$(usex libsamplerate)
+		-DMOD_OPENCV=$(usex opencv)
+		-DMOD_MOVIT=$(usex opengl)
+		-DMOD_QT=$(usex qt5)
+		-DMOD_RTAUDIO=$(usex rtaudio)
+		-DMOD_RUBBERBAND=$(usex rubberband)
+		-DMOD_VIDSTAB=$(usex vidstab)
+		-DMOD_XINE=$(usex xine)
+		-DMOD_XML=$(usex xml)
+		-DMOD_SOX=OFF
+	)
+
+	# TODO: rework upstream CMake to allow controlling MMX/SSE/SSE2
+	# TODO: add swig language bindings?
+	# see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
+
+	if use python; then
+		mycmakeargs+=( -DSWIG_PYTHON=ON )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /usr/share/${PN}
+	doins -r demo
+
+	#
+	# Install SWIG bindings
+	#
+
+	docinto swig
+
+	if use python; then
+		dodoc "${S}"/src/swig/python/play.py
+		python_optimize
+	fi
+}