media-sound/pamix: EAPI 8 bump, switch to media-libs/libpulse

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 56 insertions, 7 deletions

diff --git a/media-sound/pamix/pamix-1.6-r3.ebuild b/media-sound/pamix/pamix-1.6-r3.ebuild
new file mode 100644
index 000000000000..72606c883207
--- /dev/null
+++ b/media-sound/pamix/pamix-1.6-r3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/patroclos/PAmix.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/patroclos/PAmix/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 x86"
+	S="${WORKDIR}/PAmix-${PV}"
+fi
+
+DESCRIPTION="PulseAudio NCurses mixer"
+HOMEPAGE="https://github.com/patroclos/PAmix"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+unicode"
+
+RDEPEND="
+	media-libs/libpulse
+	sys-libs/ncurses:=[unicode(+)?]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-ncurses_pkgconfig.patch"
+	"${FILESDIR}/${P}-xdgconfigdir.patch"
+	"${FILESDIR}/${P}-fix-output-scrolling.patch"
+	"${FILESDIR}/${P}-fix-ncurses-freezing.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	if [[ ${PV} != 9999 ]] ; then
+		sed -e "/^include(CMakeGitDefines.cmake)/d" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_UNICODE="$(usex unicode)"
+	)
+	[[ ${PV} != 9999 ]] && mycmakeargs+=( -DGIT_VERSION=${PV} )
+	cmake_src_configure
+}
diff --git a/media-sound/pamix/pamix-9999.ebuild b/media-sound/pamix/pamix-9999.ebuild
index a8baa4c57b38..e1631975ab6e 100644
--- a/media-sound/pamix/pamix-9999.ebuild
+++ b/media-sound/pamix/pamix-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit cmake
 
@@ -14,7 +14,7 @@ else
 	S="${WORKDIR}/PAmix-${PV}"
 fi
 
-DESCRIPTION="A PulseAudio NCurses mixer"
+DESCRIPTION="PulseAudio NCurses mixer"
 HOMEPAGE="https://github.com/patroclos/PAmix"
 
 LICENSE="MIT"
@@ -22,13 +22,11 @@ SLOT="0"
 IUSE="+unicode"
 
 RDEPEND="
-	media-sound/pulseaudio
+	media-libs/libpulse
 	sys-libs/ncurses:=[unicode(+)?]
 "
 DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-"
+BDEPEND="virtual/pkgconfig"
 
 src_prepare() {
 	cmake_src_prepare