net-analyzer/wireshark: add 4.0.15, 4.2.5

Bug: https://bugs.gentoo.org/932563
Signed-off-by: Holger Hoffstätte <holger@applied-asynchrony.com>
Closes: https://github.com/gentoo/gentoo/pull/36790
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 696 insertions, 0 deletions

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 3959fedc5576..fe102e2510c8 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -2,5 +2,9 @@ DIST wireshark-4.0.11-signatures.txt 2521 BLAKE2B 3fce906f2050fb990d80b912919c46
 DIST wireshark-4.0.11.tar.xz 43153680 BLAKE2B 1a90b9c20773758dbcfad85ea9a5c180e846307701ce75a471699544507b6dcf7cab611b5d71056d68ec1646a951729d7df416ef1a9a473bf96d9bf5a7066ebc SHA512 c027b279f9bc761c5c701131df9e57d3f2568129f63c919cd744f6626843eb0e000caebc3e01c9a10eedad35874c01c880d2c736b62f8e841da35c375a37c53f
 DIST wireshark-4.0.14-signatures.txt 2521 BLAKE2B 371bf67dc0f36fe46848fef77194e221879db1ff422420949ba0fce4280fb9ee84ca18363046a0ce6fd1e7879ba336c1c16c9bdea13b8d14f14137f59d76212e SHA512 f084d454d1756be35e1e1ed4636cb994bd9c49bd4666d355ce3719d526bf71f9e3cc929b4dca311231d43b046711b223a379c6d915aa260966f0b7bab8a8e352
 DIST wireshark-4.0.14.tar.xz 43186416 BLAKE2B 1b67079cc0f9cdc33ce7e2fce0b49deb4d3016db79099a3bd2003099477a3bac43d4e31d4820c72a92135cca14572ac46406f41e477d794a63e96a6329d30199 SHA512 e88a4b2f41489f3ffe82c4c79c9c89ec521d931a716a5dacaede28c03b0625a0603935e723d5d869f801cfcab440a7d2f310c910707e15f9b0bca0c131398d73
+DIST wireshark-4.0.15-signatures.txt 2521 BLAKE2B 2ca4163fff33708288b355978220014707fa8ba84ea2237a9a4dcb9da8cd7986811ee3805416cd82d348968edc9d873fa63b5fd121f40e623f0099ab1fd01716 SHA512 e47ad252b260016d7cce60f53c6d308a36c1ae8c194359212fa38ec934d961bba6e1ace53d1ff3c909c5c5cad09ff8c1ded39d9ce7cac10b1b987eeee594c565
+DIST wireshark-4.0.15.tar.xz 43197644 BLAKE2B 6720ee6c879a0005c37452da32bc8e99051baf3eadd53d42b5e93a7f7e2c3cf63657393fd2d4e2d245f1b33ffc10b52c6e5af9fd527e78497dc8d1ad9405473b SHA512 6f1915c48860f79c25df8ac753aac4391393db9cf6d4b3d4ba11499fafb5cae8c1e56b7f735ea14b9f18560cb4156a3cbb65c567102db52b40e5d1f53e00be7a
 DIST wireshark-4.2.4-signatures.txt 2706 BLAKE2B 169c7eea2d89f4eedc58e833512cf813dfe76cbb76eb505d47153c1dc55f6d838b7a0187fdee4dae214ea04a3e062dd13f64df460fb16c042a889aac28e4428e SHA512 273182a2364b46bdbe89928e4776cf61ff70b91fcea9cc730ace6cd3501b51388ca9a85552b2ee26a68da42d033fdc8b2cfa279f0c52cc4cdd5278fbccaa8fb9
 DIST wireshark-4.2.4.tar.xz 44986232 BLAKE2B 03806a167a4b055409fadbc54ba338c9d2790df3ac2b9fb547c640c67d7bee6a3f8f19d30549228e494cabf8d303cef42ff098a9e1f45b092589643e568632f5 SHA512 963ac6938c08c6526240c270977057eeff7814686e11d1f3c6641a4838eb66f8d4349e48aa7373d25a8ca8911ad12eb8162f1c55af043f571d74979ddf4fd9a6
+DIST wireshark-4.2.5-signatures.txt 2706 BLAKE2B d10f6e9b4d8bcd8f0a30501bbbfee9ee696d82c7ca95957532f6614905e7836e5865d1b7093ca6aab2ebc1da5365648803f8b20508c95cdf5b42e8ac8e288f65 SHA512 050cb90e8958b73428fc7dc6c9801ba3b361f8cf4df8f22505789d759edf7967867915a0cbf351fa251d4d28b211920a3fb34e8fa209d475a10b4bcd2957fcc0
+DIST wireshark-4.2.5.tar.xz 45014156 BLAKE2B 536743a7e402f7a511d7612454d9770f0e67a0f2ebc1ab49912b12965e605f2082eff37f41f7642b89859257926ce13d88728194b79cbe5dcf6b15d72516c5fc SHA512 92a8fb08af5a1da30ca469fa45bd982638069907d289fa716068ac71141b7d9726ca0b01adc2910da4c928db23760da75a1c6a7c2eb795ac66ba003a90abb87b
diff --git a/net-analyzer/wireshark/wireshark-4.0.15.ebuild b/net-analyzer/wireshark/wireshark-4.0.15.ebuild
new file mode 100644
index 000000000000..808132d6248f
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-4.0.15.ebuild
@@ -0,0 +1,344 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..2} )
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit fcaps flag-o-matic readme.gentoo-r1 lua-single python-any-r1 qmake-utils xdg cmake
+
+DESCRIPTION="Network protocol analyzer (sniffer)"
+HOMEPAGE="https://www.wireshark.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
+	inherit git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
+	inherit verify-sig
+
+	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
+	S="${WORKDIR}/${P/_/}"
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~riscv ~x86"
+	fi
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
+IUSE+=" +dumpcap +editcap +gui http2 ilbc kerberos libxml2 lua lz4 maxminddb"
+IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap qt6 +randpkt"
+IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
+IUSE+=" sdjournal test +text2pcap tfshark +tshark +udpdump wifi zlib +zstd"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+"
+
+# Tests restricted for now because rely on pytest internals w/ >=3.11
+# See bug #897078 and https://gitlab.com/wireshark/wireshark/-/issues/18740.
+RESTRICT="!test? ( test ) test"
+
+# bug #753062 for speexdsp
+RDEPEND="
+	acct-group/pcap
+	>=dev-libs/glib-2.50.0:2
+	dev-libs/libpcre2
+	>=net-dns/c-ares-1.13.0:=
+	>=dev-libs/libgcrypt-1.8.0:=
+	media-libs/speexdsp
+	bcg729? ( media-libs/bcg729 )
+	brotli? ( app-arch/brotli:= )
+	ciscodump? ( >=net-libs/libssh-0.6:= )
+	filecaps? ( sys-libs/libcap )
+	http2? ( >=net-libs/nghttp2-1.11.0:= )
+	ilbc? ( media-libs/libilbc:= )
+	kerberos? ( virtual/krb5 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( ${LUA_DEPS} )
+	lz4? ( app-arch/lz4:= )
+	maxminddb? ( dev-libs/libmaxminddb:= )
+	minizip? ( sys-libs/zlib[minizip] )
+	netlink? ( dev-libs/libnl:3 )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	gui? (
+		x11-misc/xdg-utils
+		qt6? (
+			dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
+			dev-qt/qt5compat:6
+			dev-qt/qtmultimedia:6
+		)
+		!qt6? (
+			dev-qt/qtcore:5
+			dev-qt/qtconcurrent:5
+			dev-qt/qtgui:5
+			dev-qt/qtmultimedia:5
+			dev-qt/qtprintsupport:5
+			dev-qt/qtwidgets:5
+		)
+	)
+	sbc? ( media-libs/sbc )
+	sdjournal? ( sys-apps/systemd:= )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy:= )
+	spandsp? ( media-libs/spandsp:= )
+	sshdump? ( >=net-libs/libssh-0.6:= )
+	ssl? ( >=net-libs/gnutls-3.5.8:= )
+	wifi? ( >=net-libs/libssh-0.6:= )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	gui? (
+		!qt6? (
+			dev-qt/qtdeclarative:5
+		)
+	)
+"
+# TODO: 4.0.0_rc1 release notes say:
+# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	app-alternatives/lex
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-ruby/asciidoctor
+	)
+	gui? (
+		qt6? (
+			dev-qt/qttools:6[linguist]
+		)
+		!qt6? (
+			dev-qt/linguist-tools:5
+		)
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${RDEPEND}
+	gui? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
+fi
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.6.0-redhat.patch
+	"${FILESDIR}"/${PN}-3.4.2-cmake-lua-version.patch
+)
+
+python_check_deps() {
+	use test || return 0
+
+	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
+		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	else
+		if use verify-sig ; then
+			cd "${DISTDIR}" || die
+			verify-sig_verify_signed_checksums \
+				${P}-signatures.txt \
+				openssl-dgst \
+				${P}.tar.xz
+			cd "${WORKDIR}" || die
+		fi
+
+		default
+	fi
+}
+
+src_configure() {
+	local mycmakeargs
+
+	python_setup
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos ; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
+				;;
+		esac
+	fi
+
+	if use gui ; then
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# crashes at runtime
+	# https://bugs.gentoo.org/754021
+	filter-lto
+
+	mycmakeargs+=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
+
+		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
+		$(usex gui LRELEASE=$(qt5_get_bindir)/lrelease '')
+		$(usex gui MOC=$(qt5_get_bindir)/moc '')
+		$(usex gui RCC=$(qt5_get_bindir)/rcc '')
+		$(usex gui UIC=$(qt5_get_bindir)/uic '')
+
+		-DBUILD_androiddump=$(usex androiddump)
+		-DBUILD_capinfos=$(usex capinfos)
+		-DBUILD_captype=$(usex captype)
+		-DBUILD_ciscodump=$(usex ciscodump)
+		-DBUILD_dftest=$(usex dftest)
+		-DBUILD_dpauxmon=$(usex dpauxmon)
+		-DBUILD_dumpcap=$(usex dumpcap)
+		-DBUILD_editcap=$(usex editcap)
+		-DBUILD_mergecap=$(usex mergecap)
+		-DBUILD_mmdbresolve=$(usex maxminddb)
+		-DBUILD_randpkt=$(usex randpkt)
+		-DBUILD_randpktdump=$(usex randpktdump)
+		-DBUILD_reordercap=$(usex reordercap)
+		-DBUILD_sdjournal=$(usex sdjournal)
+		-DBUILD_sharkd=$(usex sharkd)
+		-DBUILD_sshdump=$(usex sshdump)
+		-DBUILD_text2pcap=$(usex text2pcap)
+		-DBUILD_tfshark=$(usex tfshark)
+		-DBUILD_tshark=$(usex tshark)
+		-DBUILD_udpdump=$(usex udpdump)
+
+		-DBUILD_wireshark=$(usex gui)
+		-DUSE_qt6=$(usex qt6)
+
+		-DENABLE_WERROR=OFF
+		-DENABLE_BCG729=$(usex bcg729)
+		-DENABLE_BROTLI=$(usex brotli)
+		-DENABLE_CAP=$(usex filecaps caps)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_ILBC=$(usex ilbc)
+		-DENABLE_KERBEROS=$(usex kerberos)
+		-DENABLE_LIBXML2=$(usex libxml2)
+		# only appends -flto
+		-DENABLE_LTO=OFF
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_LZ4=$(usex lz4)
+		-DENABLE_MINIZIP=$(usex minizip)
+		-DENABLE_NETLINK=$(usex netlink)
+		-DENABLE_NGHTTP2=$(usex http2)
+		-DENABLE_OPUS=$(usex opus)
+		-DENABLE_PCAP=$(usex pcap)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_PLUGIN_IFDEMO=OFF
+		-DENABLE_SBC=$(usex sbc)
+		-DENABLE_SMI=$(usex smi)
+		-DENABLE_SNAPPY=$(usex snappy)
+		-DENABLE_SPANDSP=$(usex spandsp)
+		-DBUILD_wifidump=$(usex wifi)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build test-programs
+
+	EPYTEST_DESELECT=(
+		# TODO: investigate
+		suite_follow_multistream.py::case_follow_multistream::test_follow_http2_multistream
+	)
+
+	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
+	epytest \
+		--disable-capture \
+		--skip-missing-programs=all \
+		--program-path "${BUILD_DIR}"/run
+}
+
+src_install() {
+	cmake_src_install
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README* doc/randpkt.txt doc/README*
+
+	# install headers
+	insinto /usr/include/wireshark
+	doins "${BUILD_DIR}"/config.h
+
+	# If trying to remove this, try build e.g. libvirt first!
+	# At last check, Fedora is still doing this too.
+	local dir dirs=(
+		epan
+		epan/crypt
+		epan/dfilter
+		epan/dissectors
+		epan/ftypes
+		wiretap
+		wsutil
+		wsutil/wmem
+	)
+
+	for dir in "${dirs[@]}" ; do
+		insinto /usr/include/wireshark/${dir}
+		doins ${dir}/*.h
+	done
+
+	if use gui ; then
+		local s
+
+		for s in 16 32 48 64 128 256 512 1024 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/apps
+			newins resources/icons/wsicon${s}.png wireshark.png
+		done
+
+		for s in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
+			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	if [[ -d "${ED}"/usr/share/appdata ]] ; then
+		rm -r "${ED}"/usr/share/appdata || die
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	# Add group for users allowed to sniff.
+	chgrp pcap "${EROOT}"/usr/bin/dumpcap
+
+	if use dumpcap && use pcap ; then
+		fcaps -o 0 -g pcap -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	readme.gentoo_print_elog
+}
diff --git a/net-analyzer/wireshark/wireshark-4.2.5.ebuild b/net-analyzer/wireshark/wireshark-4.2.5.ebuild
new file mode 100644
index 000000000000..0e0d86d74067
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-4.2.5.ebuild
@@ -0,0 +1,348 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..2} )
+# TODO: check cmake/modules/UseAsn2Wrs.cmake for 3.12
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit fcaps flag-o-matic lua-single python-any-r1 qmake-utils xdg cmake
+
+DESCRIPTION="Network protocol analyzer (sniffer)"
+HOMEPAGE="https://www.wireshark.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
+	inherit git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
+	inherit verify-sig
+
+	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
+	S="${WORKDIR}/${P/_/}"
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~amd64 ~arm64 ~hppa"
+	fi
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
+IUSE+=" +dumpcap +editcap +gui http2 http3 ilbc kerberos libxml2 lua lz4 maxminddb"
+IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap qt6 +randpkt"
+IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
+IUSE+=" sdjournal test +text2pcap tfshark +tshark +udpdump wifi zlib +zstd"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+"
+
+RESTRICT="!test? ( test )"
+
+# bug #753062 for speexdsp
+RDEPEND="
+	acct-group/pcap
+	>=dev-libs/glib-2.50.0:2
+	dev-libs/libpcre2
+	>=net-dns/c-ares-1.13.0:=
+	>=dev-libs/libgcrypt-1.8.0:=
+	media-libs/speexdsp
+	bcg729? ( media-libs/bcg729 )
+	brotli? ( app-arch/brotli:= )
+	ciscodump? ( >=net-libs/libssh-0.6:= )
+	filecaps? ( sys-libs/libcap )
+	http2? ( >=net-libs/nghttp2-1.11.0:= )
+	http3? ( net-libs/nghttp3 )
+	ilbc? ( media-libs/libilbc:= )
+	kerberos? ( virtual/krb5 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( ${LUA_DEPS} )
+	lz4? ( app-arch/lz4:= )
+	maxminddb? ( dev-libs/libmaxminddb:= )
+	minizip? ( sys-libs/zlib[minizip] )
+	netlink? ( dev-libs/libnl:3 )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	gui? (
+		x11-misc/xdg-utils
+		qt6? (
+			dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
+			dev-qt/qt5compat:6
+			dev-qt/qtmultimedia:6
+		)
+		!qt6? (
+			dev-qt/qtcore:5
+			dev-qt/qtconcurrent:5
+			dev-qt/qtgui:5
+			dev-qt/qtmultimedia:5
+			dev-qt/qtprintsupport:5
+			dev-qt/qtwidgets:5
+		)
+	)
+	sbc? ( media-libs/sbc )
+	sdjournal? ( sys-apps/systemd:= )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy:= )
+	spandsp? ( media-libs/spandsp:= )
+	sshdump? ( >=net-libs/libssh-0.6:= )
+	ssl? ( >=net-libs/gnutls-3.5.8:= )
+	wifi? ( >=net-libs/libssh-0.6:= )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	gui? (
+		!qt6? (
+			dev-qt/qtdeclarative:5
+		)
+	)
+"
+# TODO: 4.0.0_rc1 release notes say:
+# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	app-alternatives/lex
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-ruby/asciidoctor
+		dev-libs/libxslt
+	)
+	gui? (
+		qt6? (
+			dev-qt/qttools:6[linguist]
+		)
+		!qt6? (
+			dev-qt/linguist-tools:5
+		)
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${RDEPEND}
+	gui? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
+fi
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.6.0-redhat.patch
+)
+
+python_check_deps() {
+	use test || return 0
+
+	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
+		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	else
+		if use verify-sig ; then
+			cd "${DISTDIR}" || die
+			verify-sig_verify_signed_checksums \
+				${P}-signatures.txt \
+				openssl-dgst \
+				${P}.tar.xz
+			cd "${WORKDIR}" || die
+		fi
+
+		default
+	fi
+}
+
+src_configure() {
+	local mycmakeargs
+
+	python_setup
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos ; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
+				;;
+		esac
+	fi
+
+	if use gui ; then
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# crashes at runtime
+	# https://bugs.gentoo.org/754021
+	filter-lto
+
+	mycmakeargs+=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
+
+		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
+		$(usex gui LRELEASE=$(qt5_get_bindir)/lrelease '')
+		$(usex gui MOC=$(qt5_get_bindir)/moc '')
+		$(usex gui RCC=$(qt5_get_bindir)/rcc '')
+		$(usex gui UIC=$(qt5_get_bindir)/uic '')
+
+		-DBUILD_androiddump=$(usex androiddump)
+		-DBUILD_capinfos=$(usex capinfos)
+		-DBUILD_captype=$(usex captype)
+		-DBUILD_ciscodump=$(usex ciscodump)
+		-DBUILD_dftest=$(usex dftest)
+		-DBUILD_dpauxmon=$(usex dpauxmon)
+		-DBUILD_dumpcap=$(usex dumpcap)
+		-DBUILD_editcap=$(usex editcap)
+		-DBUILD_mergecap=$(usex mergecap)
+		-DBUILD_mmdbresolve=$(usex maxminddb)
+		-DBUILD_randpkt=$(usex randpkt)
+		-DBUILD_randpktdump=$(usex randpktdump)
+		-DBUILD_reordercap=$(usex reordercap)
+		-DBUILD_sdjournal=$(usex sdjournal)
+		-DBUILD_sharkd=$(usex sharkd)
+		-DBUILD_sshdump=$(usex sshdump)
+		-DBUILD_text2pcap=$(usex text2pcap)
+		-DBUILD_tfshark=$(usex tfshark)
+		-DBUILD_tshark=$(usex tshark)
+		-DBUILD_udpdump=$(usex udpdump)
+
+		-DBUILD_wireshark=$(usex gui)
+		-DUSE_qt6=$(usex qt6)
+
+		-DENABLE_WERROR=OFF
+		-DENABLE_BCG729=$(usex bcg729)
+		-DENABLE_BROTLI=$(usex brotli)
+		-DENABLE_CAP=$(usex filecaps caps)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_ILBC=$(usex ilbc)
+		-DENABLE_KERBEROS=$(usex kerberos)
+		-DENABLE_LIBXML2=$(usex libxml2)
+		# only appends -flto
+		-DENABLE_LTO=OFF
+		-DENABLE_LUA=$(usex lua)
+		-DLUA_FIND_VERSIONS="${ELUA#lua}"
+		-DENABLE_LZ4=$(usex lz4)
+		-DENABLE_MINIZIP=$(usex minizip)
+		-DENABLE_NETLINK=$(usex netlink)
+		-DENABLE_NGHTTP2=$(usex http2)
+		-DENABLE_NGHTTP3=$(usex http3)
+		-DENABLE_OPUS=$(usex opus)
+		-DENABLE_PCAP=$(usex pcap)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_PLUGIN_IFDEMO=OFF
+		-DENABLE_SBC=$(usex sbc)
+		-DENABLE_SMI=$(usex smi)
+		-DENABLE_SNAPPY=$(usex snappy)
+		-DENABLE_SPANDSP=$(usex spandsp)
+		-DBUILD_wifidump=$(usex wifi)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build test-programs
+
+	EPYTEST_DESELECT=(
+		# TODO: investigate
+		suite_follow_multistream.py::case_follow_multistream::test_follow_http2_multistream
+	)
+
+	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
+	epytest \
+		--disable-capture \
+		--skip-missing-programs=all \
+		--program-path "${BUILD_DIR}"/run
+}
+
+src_install() {
+	# bug #928577
+	# https://gitlab.com/wireshark/wireshark/-/commit/fe7bfdf6caac9204ab5f34eeba7b0f4a0314d3cd
+	cmake_src_install install-headers
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README* doc/randpkt.txt doc/README*
+
+	# install headers
+	insinto /usr/include/wireshark
+	doins "${BUILD_DIR}"/config.h
+
+	# If trying to remove this, try build e.g. libvirt first!
+	# At last check, Fedora is still doing this too.
+	local dir dirs=(
+		epan
+		epan/crypt
+		epan/dfilter
+		epan/dissectors
+		epan/ftypes
+		wiretap
+		wsutil
+		wsutil/wmem
+	)
+
+	for dir in "${dirs[@]}" ; do
+		insinto /usr/include/wireshark/${dir}
+		doins ${dir}/*.h
+	done
+
+	if use gui ; then
+		local s
+
+		for s in 16 32 48 64 128 256 512 1024 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/apps
+			newins resources/icons/wsicon${s}.png wireshark.png
+		done
+
+		for s in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
+			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	if [[ -d "${ED}"/usr/share/appdata ]] ; then
+		rm -r "${ED}"/usr/share/appdata || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	# Add group for users allowed to sniff.
+	chgrp pcap "${EROOT}"/usr/bin/dumpcap
+
+	if use dumpcap && use pcap ; then
+		fcaps -o 0 -g pcap -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the pcap group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}