net-misc/i2pd: version bump to 2.6.0

Package-Manager: portage-2.2.26

2 files changed, 89 insertions, 0 deletions

diff --git a/net-misc/i2pd/Manifest b/net-misc/i2pd/Manifest
index 34387a1ae514..2db6355ebb41 100644
--- a/net-misc/i2pd/Manifest
+++ b/net-misc/i2pd/Manifest
@@ -1,2 +1,3 @@
 DIST i2pd-2.5.0.tar.gz 391637 SHA256 ea01cc99c443f838ab8faf3440da45dd2ca666ab627aa54b17c565c37782b01d SHA512 77be4f2b3baf86bcf0c8f4aebd7c5fbef80654d99ff332aafcf1cd717271d80fcfe717047ac47599cb0ecfdf32347cf1c0e0be2b79759f5194c1a7e7910a42ca WHIRLPOOL 929cb33849a51c5c214c64bef0e431c62738a6584fe63aa6ebcbd2febeb854135e5e16ed0f95c64bdfc241b15faaf45226347d3851a64421dd53e53932e03456
 DIST i2pd-2.5.1.tar.gz 394332 SHA256 4cdc98676eb1d020dc11c8f2c7c5d0e739bf8c858c97eab235449cea98ca9d2c SHA512 33293e96a2715696a8cb7bcabe995ffc9a5b374e4fa4b72eebf878a8b4603600a910ded1dc775d08d89eb881f0492118ef837a0432664f4a492008b31dafec92 WHIRLPOOL c9b02580d4e6af8430e7ca0d90ad45653df700b4e955f9fcd852301129801ded284b7583c8a9a1398457caa04c8ca5080655c6bbb94686ee56af9547752c753b
+DIST i2pd-2.6.0.tar.gz 669220 SHA256 3af3edfd5def3504cbda59aa737a47f9852f844a2f5a1b47659e138acdd614c4 SHA512 73761737a50283ed78e59263ff91bb21a41147d85de62f2e27742f4f90d8e2441c20ec329b78f88e2255d837ed4584564396caee04df44b5cf5d7c1110508aa5 WHIRLPOOL 94821e65d05eba9e61ee353cc2318f0182c69393cdcf34bb3af818c54720fff76259532855689355453eb917639dcfd4e5d1e8d894f857bfc853728c11b1c71e
diff --git a/net-misc/i2pd/i2pd-2.6.0.ebuild b/net-misc/i2pd/i2pd-2.6.0.ebuild
new file mode 100644
index 000000000000..d5e9a7d388c8
--- /dev/null
+++ b/net-misc/i2pd/i2pd-2.6.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils systemd user cmake-utils
+
+DESCRIPTION="A C++ daemon for accessing the I2P anonymous network"
+HOMEPAGE="https://github.com/PurpleI2P/i2pd"
+SRC_URI="https://github.com/PurpleI2P/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cpu_flags_x86_aes i2p-hardening libressl pch static +upnp"
+
+RDEPEND="!static? ( >=dev-libs/boost-1.46[threads]
+			dev-libs/crypto++
+			!libressl? ( dev-libs/openssl:0 )
+			libressl? ( dev-libs/libressl )
+			upnp? ( net-libs/miniupnpc )
+		)"
+DEPEND="${RDEPEND}
+	static? ( >=dev-libs/boost-1.46[static-libs,threads]
+		dev-libs/crypto++[static-libs]
+		!libressl? ( dev-libs/openssl:0[-bindist,static-libs] )
+		libressl? ( dev-libs/libressl[static-libs] )
+		upnp? ( net-libs/miniupnpc[static-libs] ) )
+	i2p-hardening? ( >=sys-devel/gcc-4.7 )
+	|| ( >=sys-devel/gcc-4.7 >=sys-devel/clang-3.3 )"
+
+I2PD_USER="${I2PD_USER:-i2pd}"
+I2PD_GROUP="${I2PD_GROUP:-i2pd}"
+
+CMAKE_USE_DIR="${S}/build"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-2.5.1-fix_installed_components.patch"
+	eapply "${FILESDIR}/${PN}-2.5.1-disable_ipv6_in_i2pd_conf.patch"
+	eapply_user
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_AESNI=$(usex cpu_flags_x86_aes ON OFF)
+		-DWITH_HARDENING=$(usex i2p-hardening ON OFF)
+		-DWITH_PCH=$(usex pch ON OFF)
+		-DWITH_STATIC=$(usex static ON OFF)
+		-DWITH_UPNP=$(usex upnp ON OFF)
+		-DWITH_LIBRARY=ON
+		-DWITH_BINARY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc README.md
+	doman "${FILESDIR}/${PN}.1"
+	keepdir /var/lib/i2pd/
+	insinto "/var/lib/i2pd"
+	doins -r "${S}/contrib/certificates"
+	dosym /etc/i2pd/subscriptions.txt /var/lib/i2pd/subscriptions.txt
+	fowners "${I2PD_USER}:${I2PD_GROUP}" /var/lib/i2pd/
+	fperms 700 /var/lib/i2pd/
+	dodir "/etc/${PN}"
+	insinto "/etc/${PN}"
+	doins "${S}/debian/${PN}.conf"
+	doins "${S}/debian/subscriptions.txt"
+	doins "${FILESDIR}/tunnels.cfg"
+	dodir /usr/share/i2pd
+	newconfd "${FILESDIR}/${PN}-2.5.1.confd" "${PN}"
+	newinitd "${FILESDIR}/${PN}-2.5.1.initd" "${PN}"
+	systemd_newunit "${FILESDIR}/${PN}-2.5.1.service" "${PN}.service"
+	doenvd "${FILESDIR}/99${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}-2.5.0.logrotate" "${PN}"
+	fowners "${I2PD_USER}:${I2PD_GROUP}" "/etc/${PN}/${PN}.conf" \
+		"/etc/${PN}/subscriptions.txt" \
+		"/etc/${PN}/tunnels.cfg"
+	fperms 600 "/etc/${PN}/${PN}.conf" \
+		"/etc/${PN}/subscriptions.txt" \
+		"/etc/${PN}/tunnels.cfg"
+}
+
+pkg_setup() {
+	enewgroup "${I2PD_GROUP}"
+	enewuser "${I2PD_USER}" -1 -1 "/var/lib/run/${PN}" "${I2PD_GROUP}"
+}