net-misc/rclone: 1.62.0 version bump.

Signed-off-by: Piotr Karbowski <slashbeast@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/net-misc/rclone/rclone-1.62.0.ebuild b/net-misc/rclone/rclone-1.62.0.ebuild
new file mode 100644
index 000000000000..649ec2384a36
--- /dev/null
+++ b/net-misc/rclone/rclone-1.62.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit bash-completion-r1 go-module
+
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+SRC_URI="
+	https://github.com/rclone/rclone/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~slashbeast/distfiles/${PN}/${P}-deps.tar.xz
+"
+
+DESCRIPTION="A program to sync files to and from various cloud storage providers"
+HOMEPAGE="https://rclone.org/"
+
+LICENSE="Apache-2.0 BSD BSD-2 ISC MIT MPL-2.0"
+SLOT="0"
+IUSE=""
+
+src_compile() {
+	go build -mod=readonly . || die "compile failed"
+}
+
+src_test() {
+	# Setting CI skips unreliable tests, see fstest/testy/testy.go
+	# TestAddPlugin and TestRemovePlugin fail
+	RCLONE_CONFIG="/notfound" CI="true" go test -mod=readonly -v -run "!Test.*Plugin" ./... || die "test failed"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dodoc README.md
+
+	./rclone genautocomplete bash ${PN}.bash || die
+	newbashcomp ${PN}.bash ${PN}
+
+	./rclone genautocomplete zsh ${PN}.zsh || die
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+}