net-misc/x2goclient: Revbump to add more icons.

Permission kindly granted by voyageur.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 104 insertions, 0 deletions

diff --git a/net-misc/x2goclient/x2goclient-4.1.0.0-r1.ebuild b/net-misc/x2goclient/x2goclient-4.1.0.0-r1.ebuild
new file mode 100644
index 000000000000..4774046e76f9
--- /dev/null
+++ b/net-misc/x2goclient/x2goclient-4.1.0.0-r1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit nsplugins qmake-utils
+
+DESCRIPTION="The X2Go Qt client"
+HOMEPAGE="http://www.x2go.org"
+SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ldap nsplugin qt5"
+
+REQUIRED_USE="nsplugin? ( !qt5 )"
+
+DEPEND=">=net-libs/libssh-0.6.0_rc1
+	net-print/cups
+	x11-libs/libXpm
+	ldap? ( net-nds/openldap )
+	!qt5? (
+		dev-qt/qtcore:4[ssl]
+		dev-qt/qtgui:4
+		dev-qt/qtsvg:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5[ssl]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+"
+RDEPEND="${DEPEND}
+	net-misc/nx"
+
+CLIENT_BUILD="${WORKDIR}"/${P}.client_build
+PLUGIN_BUILD="${WORKDIR}"/${P}.plugin_build
+
+src_prepare() {
+	default
+
+	if ! use ldap; then
+		sed -e "s/-lldap//" -i x2goclient.pro || die
+		sed -e "s/#define USELDAP//" -i src/x2goclientconfig.h || die
+	fi
+
+	mkdir -p "${CLIENT_BUILD}" || die
+	if use nsplugin; then
+		mkdir -p "${PLUGIN_BUILD}" || die
+	fi
+}
+
+src_configure() {
+	cd "${CLIENT_BUILD}" || die
+
+	if use qt5; then
+		eqmake5 "${S}"/x2goclient.pro
+	else
+		eqmake4 "${S}"/x2goclient.pro
+	fi
+
+	if use nsplugin; then
+		cd "${PLUGIN_BUILD}" || die
+		X2GO_CLIENT_TARGET=plugin eqmake4 "${S}"/x2goclient.pro
+	fi
+}
+
+src_compile() {
+	cd "${CLIENT_BUILD}" || die
+	emake
+
+	if use nsplugin; then
+		cd "${PLUGIN_BUILD}" || die
+		emake
+	fi
+}
+
+src_install() {
+	dobin "${CLIENT_BUILD}"/${PN}
+
+	local size
+	for size in 16 32 48 64 128 ; do
+		doicon -s ${size} res/img/icons/${size}x${size}/${PN}.png
+	done
+	newicon -s scalable res/img/icons/hildon/${PN}_hildon.svg ${PN}.svg
+
+	insinto /usr/share/pixmaps
+	doins res/img/icons/${PN}.xpm
+
+	domenu desktop/${PN}.desktop
+	doman man/man?/*
+
+	if use nsplugin; then
+		# PLUGINS_DIR comes from nsplugins.eclass
+		exeinto /usr/$(get_libdir)/${PLUGINS_DIR}
+		doexe "${PLUGIN_BUILD}"/libx2goplugin.so
+	fi
+
+	emake DESTDIR="${D}" PREFIX=/usr install_pluginprovider
+}